HTMLHost

Paket	flash.html
Klasse	public class HTMLHost
Vererbung	HTMLHost Object

Laufzeitversionen:

AIR 1.0

Ein HTMLHost-Objekt definiert das Verhalten eines HTMLLoader-Objekts für Benutzeroberflächenelemente, die durch die Einstellung verschiedener Eigenschaften oder durch das Aufrufen verschiedener Methoden des window-Objekts der HTML-Seite gesteuert werden. Diese Methoden und Eigenschaften sind:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

Die Methoden in der HTMLHost-Klasse bieten Möglichkeiten, mit Änderungen in diesen window-Einstellungen umzugehen. Um diese Klasse zu verwenden, erstellen Sie eine neue Klasse, die die HTMLHost-Klasse erweitert (eine Unterklasse), und überschreiben Sie damit die Methoden, für die Sie Verhalten definieren möchten. Die Methoden der HTMLHost-Klasse gehen wie folgt mit JavaScript-Eigenschaften und -Methoden vor:

JavaScript-Eigenschaft oder Methode	HTMLHost-Methode
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

Um auf Änderungen in den Methoden window.moveBy(), window.moveTo(), window.resizeBy() und window.resizeTo() zu reagieren, überschreiben Sie die set windowRect()-Methode in der Unterklasse von HTMLHost.

Jedes HTMLHost-Objekt kann höchstens mit einem HTMLLoader-Objekt verknüpft sein. Mit diesem Zuweisen einer HTMLHost-Instanz zur htmlHost-Eigenschaft des HTMLLoader-Objekts wird die Beziehung aufgebaut. Das Zuweisen von null zur htmlHost-Eigenschaft des HTMLLoader-Objekts oder das Festlegen des HTMLHost-Objekts als htmlHost-Eigenschaft eines anderen HTMLLoader-Objekts entfernt den HTMLHost vom ersten HTMLLoader-Objekts.

Beispiele anzeigen

Verwandte API-Elemente

HTMLLoader
HTMLWindowCreateOptions

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		htmlLoader : flash.html:HTMLLoader [schreibgeschützt] Das HTMLLoader-Objekt, auf das dieses HostControl-Objekt angewendet wird.	HTMLHost
		windowRect : Rectangle Die Eigenschaft, die geändert wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.moveBy(), window.moveTo(), window.resizeBy() oder window.resizeTo()-Methode aufruft.	HTMLHost

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		HTMLHost(defaultBehaviors:Boolean = true) Erstellt ein neues HTMLHost-Objekt.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.open()-Methode aufruft.	HTMLHost
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		updateLocation(locationURL:String):void Die Funktion, die aufgerufen wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.location-Eigenschaft einstellt.	HTMLHost
		updateStatus(status:String):void Die Funktion, die aufgerufen wird, wenn das HTMLLoader-Objekt die window.status-Eigenschaft festlegt.	HTMLHost
		updateTitle(title:String):void Die Funktion, die aufgerufen wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.document.title-Eigenschaft festlegt oder wenn das Titelelement über das DOM oder wegen einer neu geladenen Seite geändert wird.	HTMLHost
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object
		windowBlur():void Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.blur()-Methode aufruft.	HTMLHost
		windowClose():void Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.close()-Methode aufruft.	HTMLHost
		windowFocus():void Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.focus()-Methode aufruft.	HTMLHost

Eigenschaftendetails

htmlLoader

Eigenschaft

htmlLoader:flash.html:HTMLLoader [schreibgeschützt]

Laufzeitversionen:

AIR 1.0

Das HTMLLoader-Objekt, auf das dieses HostControl-Objekt angewendet wird. Die htmlHost-Eigenschaft des HTMLLoader-Objekts ist auf dieses HostControl-Objekt eingestellt.

Implementierung
public function get htmlLoader():flash.html:HTMLLoader

Verwandte API-Elemente

HTMLLoader.htmlHost

windowRect

Eigenschaft

windowRect:Rectangle

Laufzeitversionen:

AIR 1.0

Die Eigenschaft, die geändert wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.moveBy(), window.moveTo(), window.resizeBy() oder window.resizeTo()-Methode aufruft.

Überschreiben Sie in der Unterklasse von HTMLHost die set windowRect()-Methode, um die neuen Fenstergrenzen wie gewünscht zu verarbeiten.

Implementierung
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Konstruktordetails

()

Konstruktor

public function HTMLHost(defaultBehaviors:Boolean = true)

Laufzeitversionen:

AIR 1.0

Erstellt ein neues HTMLHost-Objekt.

Parameter

defaultBehaviors:Boolean (default = true) — Gibt an, ob die Verhaltensweisen des Stamminhalts standardmäßig bereitgestellt werden sollen.

Methodendetails

createWindow

()

Methode

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.open()-Methode aufruft.

Standardmäßig öffnet ein JavaScript-Aufruf von window.open() auf der HTML-Seite eines HTMLLoader kein neues NativeWindow-Objekt zur Laufzeit. Sie können ein neues NativeWindow-Objekt zur Laufzeit öffnen, indem Sie ein neues NativeWindow-Objekt in der createWindow-Methode erstellen und damit die Unterklasse der HTMLHost-Klasse überschreiben.

Parameter

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Ein Objekt mit Eigenschaften im String, die als features-Parameter des Aufrufs von window.open() übergeben werden.

Rückgabewerte

flash.html:HTMLLoader — Ein HTMLLoader-Objekt, das die neue HTML-Seite enthält. Normalerweise erstellen Sie ein neues HTMLLoader-Objekt in dieser Methode, fügen es der Bühne eines neuen NativeWindow-Objekts hinzu und geben es dann zurück.

updateLocation

()

Methode

public function updateLocation(locationURL:String):void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.location-Eigenschaft einstellt.

Parameter

locationURL:String — Der Wert, auf den die location-Eigenschaft der window-Eigenschaft des HTMLLoader-Objekts eingestellt ist.

updateStatus

()

Methode

public function updateStatus(status:String):void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.status-Eigenschaft festlegt.

Parameter

status:String — Der Wert, auf den die status-Eigenschaft der window-Eigenschaft des HTMLLoader-Objekts eingestellt ist.

updateTitle

()

Methode

public function updateTitle(title:String):void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn JavaScript-Code im HTMLLoader-Objekt die window.document.title-Eigenschaft festlegt oder wenn das title-Element über das DOM oder wegen einer neu geladenen Seite geändert wird.

Parameter

title:String — Der Wert, auf den die window.document.title-Eigenschaft des HTMLLoader-Objekts eingestellt ist.

windowBlur

()

Methode

public function windowBlur():void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.blur()-Methode aufruft.

windowClose

()

Methode

public function windowClose():void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.close()-Methode aufruft.

Standardmäßig schließt ein JavaScript-Aufruf von window.close() auf der HTML-Seite eines HTMLLoader-Objekts die Fenster mit dem HTMLLoader-Objekt.

windowFocus

()

Methode

public function windowFocus():void

Laufzeitversionen:

AIR 1.0

Die Funktion, die aufgerufen wird, wenn der JavaScript-Code im HTMLLoader-Objekt die window.focus()-Methode aufruft.

Beispiele Verwendung dieses Beispiels

HTMLHost.1.as

Der folgende Code definiert CustomHost, eine Unterklasse von HTMLHost. Methoden der CustomHost-Klasse überschreiben die vererbten Methoden in der HTMLHost-Klasse, um Aktionen zu definieren, die ausgeführt werden, wenn JavaScript-Code in der HTMLLoader-Seite verschiedene Eigenschaften festlegt oder verschiedene Methoden des window-Objekts aufruft:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Erstellen Sie die folgende Klasse, die der Bühne ein HTMLLoader-Objekt hinzufügt, sowie ein TextField-Objekt mit dem Namen statusBar. Das HTMLLoader-Objekt definiert ein CustomHost-Objekt als seine htmlHost-Eigenschaft:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Erstellen Sie eine AIR-Anwendung, die der Bühne des Hauptfensters ein von dieser Klasse definiertes Objekt hinzufügt.

Erstellen Sie eine HTML-Seite mit dem Namen Test.html im Ressourcenverzeichnis der Anwendung (das Verzeichnis, das die Anwendungsdeskriptordatei enthält) und fügen Sie den folgenden Inhalt hinzu:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

Wenn Sie die Anwendung testen, verarbeitet die CustomHost-Klasse die JavaScript-Einstellungen für die Benutzeroberfläche auf der HTML-Seite.

Rechtliche Hinweise | Onlinedatenschutzerklärung

HTMLHost - AS3

Klassen x

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus