ContextMenuBuiltInItems  - AS3

Permet à l’utilisateur d’avancer ou de reculer d’une image dans un fichier SWF au moment de l’exécution (ne s’affiche pas pour un fichier SWF contenant une seule image).

Permet à l’utilisateur de configurer un fichier SWF de telle sorte qu’il redémarre automatiquement lorsqu’il atteint la dernière image (ne s’affiche pas pour un fichier SWF contenant une seule image).

Permet à l’utilisateur de démarrer un fichier SWF en pause (ne s’affiche pas pour un fichier SWF contenant une seule image).

Permet à l’utilisateur d’envoyer l’image affichée à une imprimante.

Permet à l’utilisateur de définir la résolution du fichier SWF au moment de l’exécution.

Permet à l’utilisateur de configurer un fichier SWF de telle sorte que la lecture commence à la première image lorsqu’il est sélectionné, et ceci à tout moment (ne s’affiche pas pour un fichier SWF contenant une seule image).

Permet à l’utilisateur qui a installé Shockmachine d’enregistrer un fichier SWF.

Permet à l’utilisateur d’effectuer un zoom avant/arrière sur un fichier SWF au moment de l’exécution.

Crée un objet ContextMenuBuiltInItems qui vous permet de définir les propriétés indiquant à Flash Player d’afficher ou de masquer chaque élément du menu.

1. Une propriété myContextMenu est déclarée, puis attribuée à un nouvel objet ContextMenu.
2. La méthode removeDefaultItems() est appelée, ce qui supprime tous les éléments de menu contextuel intégrés sauf Print.
3. La méthode addCustomMenuItems() est appelée, ce qui a pour effet de placer un élément de menu appelé Hello World dans le tableau customItems par le biais de la méthode push() de Array.
4. L’élément de menu Hello World est ensuite ajouté à la liste des éléments du menu contextuel de la scène.
5. Un objet TextField contenant le texte « Right Click » (Cliquez du bouton droit) est ajouté au centre de la scène en utilisant addChild() via createLabel().

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}