| Пакет | flash.filesystem |
| Класс | public class StorageVolume |
| Наследование | StorageVolume  Object |
| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
- Свойство
storageVolumeобъекта StorageVolumeChangeEvent представляет собой объект StorageVolume. Этот объект представляет установленный или извлеченный том хранения. - Статический метод
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes()возвращает вектор с объектами StorageVolume. Каждый из этих объектов StorageVolume представляет установленный том хранения.
Связанные элементы API
flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume
flash.events.StorageVolumeChangeEvent.storageVolume
Общедоступные свойства
Скрыть унаследованные общедоступные свойства
Показать унаследованные общедоступные свойства| Свойство | Определено | ||
|---|---|---|---|
 | constructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта. | Object | |
| drive : String [только для чтения]
Имя диска тома в ОС Windows. | StorageVolume | ||
| fileSystemType : String [только для чтения]
Тип файловой системы на томе хранения (например, FAT, NTFS, HFS или UFS). | StorageVolume | ||
| isRemovable : Boolean [только для чтения]
Рассматривает ли операционная система том хранения как съемный: да (true) или нет (false). | StorageVolume | ||
| isWritable : Boolean [только для чтения]
Поддерживает ли том запись: да (true) или нет (false). | StorageVolume | ||
| name : String [только для чтения]
Имя тома. | StorageVolume | ||
| rootDirectory : File [только для чтения]
Объект File, соответствующий корневому каталогу тома. | StorageVolume | ||
Общедоступные методы
| Метод | Определено | ||
|---|---|---|---|
StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)
Функция конструктора. | StorageVolume | ||
|
Показывает, определено ли заданное свойство для объекта. | Object | |
|
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра. | Object | |
|
Показывает наличие заданного свойства и его перечисляемость. | Object | |
|
Задает доступность динамического свойства для операций цикла. | Object | |
|
Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали. | Object | |
|
Возвращает строковое представление заданного объекта. | Object | |
|
Возвращает элементарное значение заданного объекта. | Object | |
Сведения о свойстве
drive | свойство |
fileSystemType | свойство |
fileSystemType:String [только для чтения] | Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Тип файловой системы на томе хранения (например, FAT, NTFS, HFS или UFS).
Реализация
public function get fileSystemType():StringПример ( Использование этого примера )
Следующий код отображает собственный путь для корневого каталога и тип файловой системы каждого установленного тома хранения.
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}
isRemovable | свойство |
isRemovable:Boolean [только для чтения] | Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Рассматривает ли операционная система том хранения как съемный: да (true) или нет (false).
В следующем списке приводятся значения свойства StorageVolume.isRemovable для различных типов устройств.
| Тип устройства | Mac OS | Windows | Linux |
|---|---|---|---|
| Привод CD/DVD (внутренний) | true | true | true |
| Флэш-накопитель USB | true | true | true |
| Жесткий диск USB | false | false | true |
| Жесткий диск FireWire | false | false | true |
| Общедоступный том | true | false | - 1 |
| Сетевой диск | false | false | false |
| Устройство чтения карт памяти (пустое) | - 2 | false | - 2 |
| Устройство чтения карт памяти (с картой SD/CF) | true | true | true |
1 В ОС Linux нет понятия общедоступного тома.
2 В ОС Windows пустое устройство чтения карт памяти обозначается как несъемное устройство. В ОС Mac OS и Linux пустые устройства чтения карт не обозначаются как тома хранения.
Реализация
public function get isRemovable():BooleanПример ( Использование этого примера )
Следующий код выводит список несъемных томов хранения, за которым следует список съемных томов.
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
if (!volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
if (volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
isWritable | свойство |
isWritable:Boolean [только для чтения] | Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Поддерживает ли том запись: да (true) или нет (false).
Примечание. Можно определить объем свободного пространства в томе, вызвав свойство rootDirectory.spaceAvailble объекта StorageVolume.
Реализация
public function get isWritable():BooleanСвязанные элементы API
flash.fileSystem.File.spaceAvailable
Пример ( Использование этого примера )
Следующий код выводит список записываемых томов хранения и свободное пространство на каждом из них.
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
if(volumes[i].isWritable)
{
trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
}
}
name | свойство |
name:String [только для чтения] | Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Имя тома. Если имени нет, это свойство имеет значение null.
Реализация
public function get name():StringПример ( Использование этого примера )
Следующий код отображает собственный путь для корневого каталога и имя файловой системы (если оно есть) каждого установленного тома хранения.
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var name:String = new String();
if (volumes[i].name)
{
name = "(" + volumes[i].name + ")";
}
trace(volumes[i].rootDirectory.nativePath, name);
}
rootDirectory | свойство |
rootDirectory:File [только для чтения] | Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Объект File, соответствующий корневому каталогу тома.
Реализация
public function get rootDirectory():FileПример ( Использование этого примера )
Следующий код отображает собственный путь для корневого каталога каждого установленного тома хранения:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath);
}
Сведения о конструкторе
StorageVolume | () | Конструктор |
public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | AIR 2 |
Функция конструктора. Как правило, эта функция-конструктор не вызывается напрямую (для создания новых объектов StorageVolume). Вместо этого ссылка на объекты StorageVolume осуществляется путем обращения к свойству storageVolume объекта StorageVolumeChangeEvent или вызова метода StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().
rootDirPath:File | |
name:String | |
writable:Boolean | |
removable:Boolean | |
fileSysType:String | |
drive:String |
Примеры Использование этого примера
StorageVolumeExample.as
Следующий код перечисляет свойства каждого установленного тома хранения.
package
{
import flash.display.Sprite;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeExample extends Sprite
{
public function StorageVolumeExample()
{
var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var volume:StorageVolume = volumes[i];
trace("nativePath:", volume.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace("________________________________________________________");
}
}
}
}
StorageVolumeChangeEventExample.as
Следующий код перечисляет свойства каждого установленного или извлеченного тома хранения. Обратите внимание на то, что свойство
storageVolume объекта StorageVolumeChangeEvent задается только для события storageVolumeMount. Оно имеет значение null для события storageVolumeUnmount.
package
{
import flash.display.Sprite;
import flash.events.StorageVolumeChangeEvent;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeChangeEventExample extends Sprite
{
public function StorageVolumeChangeEventExample()
{
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
}
public function mountEventHandler(event:StorageVolumeChangeEvent):void
{
var volume:StorageVolume = event.storageVolume;
trace("VOLUME MOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace();
}
public function unmountEventHandler(event:StorageVolumeChangeEvent):void
{
trace("VOLUME UNMOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace();
}
}
}
Tue Jun 12 2018, 11:34 AM Z