HTMLHost

Пакет	flash.html
Класс	public class HTMLHost
Наследование	HTMLHost Object

Версии среды выполнения:

AIR 1.0

Объект HTMLHost определяет поведение объекта HTMLLoader для элементов пользовательского интерфейса, которыми можно управлять путем задания различных свойств или вызова методов объекта window страницы HTML. Учитываются следующие методы и свойства:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

Методы в классе HTMLHost предоставляют способы обработки изменений в каждом из этих параметров window. Для использования этого класса необходимо создать новый класс (подкласс), расширяющий класс HTMLHost и перезаписывающий методы, для которых необходимо определить поведение. Методы класса HTMLHost обрабатывают следующие свойства и методы JavaScript:

Свойство или метод JavaScript	Метод HTMLHost
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

При изменении методов window.moveBy(), window.moveTo(), window.resizeBy() и window.resizeTo() перезаписывается метод set windowRect() в подклассе HTMLHost.

Каждый объект HTMLHost можно связать только с одним объектом HTMLLoader. Эта взаимосвязь устанавливается путем назначения экземпляра HTMLHost свойству htmlHost объекта HTMLLoader. При присвоении значения null свойству htmlHost объекта HTMLLoader или объекта HTMLHost в качестве свойства htmlHost другого объекта HTMLLoader выполняется удаление HTMLHost из первого объекта HTMLLoader.

Посмотреть примеры

Связанные элементы API

HTMLLoader
HTMLWindowCreateOptions

Общедоступные свойства

Скрыть унаследованные общедоступные свойства

Показать унаследованные общедоступные свойства

	Свойство		Определено
		constructor : Object Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.	Object
		htmlLoader : flash.html:HTMLLoader [только для чтения] Объект HTMLLoader, к которому применяется данный объект HostControl.	HTMLHost
		windowRect : Rectangle Свойство, изменяющееся, когда код JavaScript в объекте HTMLLoader вызывает метод window.moveBy(), window.moveTo(), window.resizeBy() или window.resizeTo().	HTMLHost

Общедоступные методы

Скрыть унаследованные общедоступные методы

Показать унаследованные общедоступные методы

	Метод		Определено
		HTMLHost(defaultBehaviors:Boolean = true) Создает объект HTMLHost.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.open().	HTMLHost
		hasOwnProperty(name:String):Boolean Показывает, определено ли заданное свойство для объекта.	Object
		isPrototypeOf(theClass:Object):Boolean Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.	Object
		propertyIsEnumerable(name:String):Boolean Показывает наличие заданного свойства и его перечисляемость.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Задает доступность динамического свойства для операций цикла.	Object
		toLocaleString():String Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали.	Object
		toString():String Возвращает строковое представление заданного объекта.	Object
		updateLocation(locationURL:String):void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.location.	HTMLHost
		updateStatus(status:String):void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.status.	HTMLHost
		updateTitle(title:String):void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.document.title или изменяется элемент title с помощью элемента DOM или при загрузке новой страницы.	HTMLHost
		valueOf():Object Возвращает элементарное значение заданного объекта.	Object
		windowBlur():void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.blur().	HTMLHost
		windowClose():void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.close().	HTMLHost
		windowFocus():void Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.focus().	HTMLHost

Сведения о свойстве

htmlLoader

свойство

htmlLoader:flash.html:HTMLLoader [только для чтения]

Версии среды выполнения:

AIR 1.0

Объект HTMLLoader, к которому применяется данный объект HostControl. Свойство htmlHost этого объекта HTMLLoader настроено для данного объекта HostControl.

Реализация
public function get htmlLoader():flash.html:HTMLLoader

Связанные элементы API

HTMLLoader.htmlHost

windowRect

свойство

windowRect:Rectangle

Версии среды выполнения:

AIR 1.0

Свойство, изменяющееся, когда код JavaScript в объекте HTMLLoader вызывает метод window.moveBy(), window.moveTo(), window.resizeBy() или window.resizeTo().

В подклассе HTMLHost при необходимости перезапишите метод set windowRect() для обработки новых границ окна.

Реализация
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Сведения о конструкторе

()

Конструктор

public function HTMLHost(defaultBehaviors:Boolean = true)

Версии среды выполнения:

AIR 1.0

Создает объект HTMLHost.

Параметры

defaultBehaviors:Boolean (default = true) — Определяет необходимость предоставления вариантов поведения корневого содержимого по умолчанию.

Сведения о методе

createWindow

()

метод

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.open().

По умолчанию во время выполнения при вызове в сценарии JavaScript метода window.open() на странице HTML объекта HTMLLoader новый объект NativeWindow не открывается. Новый объект NativeWindow можно открыть во время выполнения путем создания нового объекта NativeWindow в перезаписи метода createWindow в подклассе класса HTMLHost.

Параметры

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Объект, содержащий свойства в строке, переданной в качестве параметра features при вызове метода window.open().

Возвращает

flash.html:HTMLLoader — Объект HTMLLoader, содержащий новую страницу HTML. Обычно новый объект HTMLLoader создается в этом методе, добавляется при создании нового объекта NativeWindow, а затем возвращается.

updateLocation

()

метод

public function updateLocation(locationURL:String):void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.location.

Параметры

locationURL:String — Значение, которое настроено для свойства location свойства window объекта HTMLLoader.

updateStatus

()

метод

public function updateStatus(status:String):void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.status.

Параметры

status:String — Значение, которое настроено для свойства status свойства window объекта HTMLLoader.

updateTitle

()

метод

public function updateTitle(title:String):void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader задает свойство window.document.title или изменяется элемент title с помощью элемента DOM или при загрузке новой страницы.

Параметры

title:String — Значение, которое настроено для свойства window.document.title объекта HTMLLoader.

windowBlur

()

метод

public function windowBlur():void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.blur().

windowClose

()

метод

public function windowClose():void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.close().

По умолчанию при вызове в сценарии JavaScript метода window.close() на странице HTML объекта HTMLLoader закрываются окна, в которых содержится объект HTMLLoader.

windowFocus

()

метод

public function windowFocus():void

Версии среды выполнения:

AIR 1.0

Обращение к функции происходит, когда код JavaScript в объекте HTMLLoader вызывает метод window.focus().

Примеры Использование этого примера

HTMLHost.1.as

Следующий код определяет CustomHost, подкласс класса HTMLHost. Методы класса CustomHost переопределяют наследованные методы класса HTMLHost при определении действий, предпринимаемых, когда код JavaScript страницы HTMLLoader задает различные свойства или вызывает различные методы объекта window:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Создайте следующий класс, который добавляет объект HTMLLoader в рабочую область, а также объект TextField с именем statusBar. Объект HTMLLoader определяет объект CustomHost в качестве своего свойства htmlHost:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Создайте приложение AIR, которое добавляет объект, определенный этим классом, в рабочую область основного окна.

Создайте страницу HTML с именем Test.html в каталоге ресурсов приложения (каталог, содержащий файл дескриптора приложения) и вставьте в нее следующее содержимое:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

При тестировании приложения класс CustomHost обрабатывает связанные с пользовательским интерфейсом настройки JavaScript страницы HTML.

Юридическая информация | Политика конфиденциальности онлайн

HTMLHost - AS3

Классы x

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus