ContextMenuBuiltInItems  - AS3

Позволяет пользователю переходить на кадр вперед или назад в SWF-файле во время выполнения (недоступно для SWF-файла с одним кадром).

Позволяет пользователю задавать автоматический повторный запуск SWF-файла при достижении последнего кадра (недоступно для SWF-файла с одним кадром).

Позволяет пользователю запускать приостановленный SWF-файл (недоступно для SWF-файла с одним кадром).

Позволяет пользователю направлять изображение отображаемого кадра на принтер для печати.

Позволяет пользователю задавать разрешение SWF-файла во время выполнения.

При выборе позволяет пользователю запускать SWF-файл с первого кадра в любой момент (недоступно для SWF-файла с одним кадром).

Позволяет сохранять SWF-файлы на компьютере, на котором установлено приложение Shockmachine.

Позволяет пользователю масштабировать просмотр SWF-файла во время выполнения.

Создает новый объект ContextMenuBuiltInItems, что позволяет задать свойства для отображения или скрытия каждого элемента меню в проигрывателе Flash Player.

1. Объявляется свойство myContextMenu, а затем назначается объекту ContextMenu.
2. Вызывается метод removeDefaultItems(), который удаляет все встроенные элементы контекстного меню, кроме «Печать».
3. Вызывается метод addCustomMenuItems(), который помещает элемент меню Hello World в массив customItems с помощью метода push() объекта Array.
4. Затем элемент контекстного меню Hello World добавляется в список элементов контекстного меню монтажного стола.
5. В центр монтажного стола с помощью метода addChild(), вызванного через метод createLabel(), добавляется объект TextField с текстом «Щелкните правой кнопкой мыши».

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}