| Пакет | flash.ui |
| Класс | public final class MouseCursorData |
| Наследование | MouseCursorData  Object |
| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | Flash Player 10.2, AIR 2.6 |
Для отображения курсора используйте функцию Mouse.registerCursor(). Чтобы вернуть управление изображением курсора в операционную систему, вызовите функцию Mouse.unregisterCursor(). Вызовите функцию Mouse.supportsNativeCursor, чтобы проверить, поддерживаются ли собственные курсоры на текущем компьютере.
Максимальный размер курсора равен 32x32 пикселя. Прозрачность поддерживается в большинстве операционных систем.
Встроенный курсор внедрен непосредственно через механизм курсора операционной системы и является более эффективным средством для отображения пользовательского курсора, чем использование экранного объекта. Курсор можно анимировать, предоставив несколько изображений с помощью свойства data и установив частоту кадров.
Курсор отображается в рамках рабочей области. За пределами рабочей область управление изображением курсора возвращается к операционной системе.
Дополнительно
Связанные элементы API
Скрыть унаследованные общедоступные свойства
Показать унаследованные общедоступные свойства| Свойство | Определено | ||
|---|---|---|---|
 | constructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта. | Object | |
| data : Vector.<BitmapData>
Вектор объектов BitmapData, содержащий изображение курсора или несколько изображений. | MouseCursorData | ||
| frameRate : Number
Частота кадров для анимации курсора. | MouseCursorData | ||
| hotSpot : Point
Активная точка курсора в пикселях. | MouseCursorData | ||
| Метод | Определено | ||
|---|---|---|---|
Создает объект MouseCursorData. | MouseCursorData | ||
|
Показывает, определено ли заданное свойство для объекта. | Object | |
|
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра. | Object | |
|
Показывает наличие заданного свойства и его перечисляемость. | Object | |
|
Задает доступность динамического свойства для операций цикла. | Object | |
|
Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали. | Object | |
|
Возвращает строковое представление заданного объекта. | Object | |
|
Возвращает элементарное значение заданного объекта. | Object | |
data | свойство |
data:Vector.<BitmapData>| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | Flash Player 10.2, AIR 2.6 |
Вектор объектов BitmapData, содержащий изображение курсора или несколько изображений.
Для анимации курсора предоставьте несколько изображений и задайте значение свойства framerate.
Максимальный размер курсора равен 32x32 пикселя.
Реализация
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | свойство |
frameRate:Number| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | Flash Player 10.2, AIR 2.6 |
Частота кадров для анимации курсора.
Предоставьте несколько изображений в свойстве data и установите для частоты кадров значение больше 0, чтобы анимировать курсор. Частота кадров может отличаться от текущего числа кадров SWF.
Реализация
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | свойство |
hotSpot:Point| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | Flash Player 10.2, AIR 2.6 |
Активная точка курсора в пикселях.
Активная точка — это точка на курсоре, в которой регистрируется нажатие мыши. По умолчанию активная точка — это левый верхний угол (0,0).
Реализация
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Конструктор |
public function MouseCursorData()| Язык версии: | ActionScript 3.0 |
| Версии среды выполнения: | Flash Player 10.2, AIR 2.6 |
Создает объект MouseCursorData.
Чтобы отобразить курсор, вызовите функцию Mouse.registerCursor().
Связанные элементы API
В примере с помощью команд рисования, доступных через класс Graphics, создается восемь повернутых изображений стрелки. Эти изображения представлены в векторном формате и назначены для свойства data объекта MouseCursorData. (Обратите внимание, что для курсоров можно также использовать предварительно отрисованные растровые изображения.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 11:34 AM Z