ConflictDetector  - AS3 ADEP Data Services

 override public function checkCreate(remoteChange:IChangeObject,
                                      localChange:IChangeObject):void
 {
     // if we have created a local item that is the same item as the remote 
     // change then we have a conflict
     if (localChange != null && 
         ObjectUtil.compare(remoteChange.identity, localChange.identity) == 0)
     {
         remoteChange.conflict("Local created item is in conflict with remotely created item",
                               localChange.changedPropertyNames);
     }
 }
 
 override public function checkDelete(remoteChange:IChangeObject,
                                      localChange:IChangeObject):void
 {
     // if we have an update locally for an item that was deleted remotely
     // that is considered a conflict.
     if (localChange != null)
     {
         if (localChange.isUpdate())
         {
             remoteChange.conflict("Local item was updated and is in conflict with pushed delete.",
                                   localChange.changedPropertyNames);
         }
     }
 }
 
 override public function checkUpdate(remoteChange:IChangeObject,
                                      localChange:IChangeObject):void
 {
     // get a list of all of the changed properties
     var changes:Array = remoteChange.changedPropertyNames;
     // get the remote state of the item's properties
     var newVersion:Object = remoteChange.newVersion;
     var prevVersion:Object = localChange.previousVersion;
     // properties will be in conflict if the old value of a property on the 
     // local item is different from the same property value of the new version
     // of the remote item.
     var conflictingProps:Array = [];
     for (var i:int=0; i<changes.length; i++)
     {
         var prop:Object = changes[i]; // could be a String or QName
         if (ObjectUtil.compare(prevVersion[prop], newVersion[prop]) != 0)
         {
             conflictingProps.push(prop);
         }
     }
 
     if (conflictingProps.length > 0)
     {
         remoteChange.conflict("Local item has changes to properties that conflict with remote change.",
                               conflictingProps);
     }
 }