ProgressBarMode - Adobe ActionScript® 3 (AS3 Flash) API-Referenz

Paket	fl.controls
Klasse	public class ProgressBarMode
Vererbung	ProgressBarMode Object

Sprachversion:

ActionScript 3.0

Produktversion:

Flash CS3

Laufzeitversionen:

Flash Player 9.0.28.0, AIR 1.0

Die ProgressBarMode-Klasse definiert die Werte für die mode-Eigenschaft der ProgressBar-Klasse.

Verwandte API-Elemente

ProgressBar.mode

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

Öffentliche Konstanten

	Konstante		Definiert von
		EVENT : String = "event" [statisch] Die von der source-Eigenschaft angegebene Komponente muss progress- und complete-Ereignisse auslösen.	ProgressBarMode
		MANUAL : String = "manual" [statisch] Aktualisieren SIe den Status der ProgressBar-Komponente manuell.	ProgressBarMode
		POLLED : String = "polled" [statisch] Der Fortschritt wird durch Abrufen der Quelle aktualisiert.	ProgressBarMode

Konstantendetails

EVENT

Konstante

public static const EVENT:String = "event"

Sprachversion:

ActionScript 3.0

Produktversion:

Flash CS3

Laufzeitversionen:

Flash Player 9.0.28.0, AIR 1.0

Die von der Eigenschaft source angegebene Komponente muss progress und complete-Ereignisse auslösen. Die Fortschrittsleiste verwendet diese Ereignisse, um ihren Status zu aktualisieren.

Verwandte API-Elemente

Ereignis "ScrollPane complete"
Ereignis "ScrollPane progress"
Ereignis "UILoader complete"
Ereignis "UILoader progress"
Ereignis "LoaderInfo complete"
Ereignis "LoaderInfo progress"
Ereignis "Sound complete"
Ereignis "Sound progress"
Ereignis "FileReference complete"
Ereignis "FileReference progress"
Ereignis "URLLoader complete"
Ereignis "URLLoader progress"
Ereignis "URLStream complete"
Ereignis "URLStream progress"

Beispiel ( Verwendung dieses Beispiels )

Im folgenden Beispiel werden ProgressBar-, Label- und UILoader-Komponenteninstanzen erstellt und der Ladefortschritt eines Bildes angezeigt:

import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;
import fl.events.ComponentEvent;

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";

var myUILoader:UILoader = new UILoader();
myUILoader.visible = false;
myUILoader.scaleContent = false;
myUILoader.autoLoad = false;
myUILoader.source = url;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.load();

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.EVENT;
myProgressBar.indeterminate = false;
myProgressBar.source = myUILoader;
myProgressBar.setSize(320, 12);
myProgressBar.move((stage.stageWidth - myProgressBar.width) / 2, (stage.stageHeight - myProgressBar.height) / 2);
myProgressBar.addEventListener(Event.COMPLETE, completeHandler);
myProgressBar.addEventListener(ProgressEvent.PROGRESS, progressHandler);
addChild(myProgressBar);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myProgressBar.x, myProgressBar.y + myProgressBar.height);
addChild(myLabel);

function progressHandler(event:ProgressEvent):void {
    trace("progress:", event.bytesLoaded, "of", event.bytesTotal, "bytes");
    myLabel.text = event.bytesLoaded + " of " + event.bytesTotal + " (" + event.currentTarget.percentComplete.toFixed(1) + "%)";
}

function completeHandler(event:Event):void {
    trace("complete:");
    removeChild(myLabel);
    removeChild(myProgressBar);
    myProgressBar.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myProgressBar.removeEventListener(Event.COMPLETE, completeHandler);
    addChild(myUILoader);
}

function resizeHandler(event:ComponentEvent):void {
    trace("resize:");
    var myUILdr:UILoader = event.currentTarget as UILoader;
    myUILdr.move((stage.stageWidth - myUILdr.width) / 2, (stage.stageHeight - myUILdr.height) / 2);
    myUILdr.visible = true;
}

MANUAL

Konstante

public static const MANUAL:String = "manual"

Sprachversion:

ActionScript 3.0

Produktversion:

Flash CS3

Laufzeitversionen:

Flash Player 9.0.28.0, AIR 1.0

Aktualisieren SIe den Status der ProgressBar-Komponente manuell. In diesem Modus geben Sie die Eigenschaften minimum und maximum an und verwenden die Methode setProgress(), um den Status festzulegen.

Verwandte API-Elemente

ProgressBar.maximum
ProgressBar.minimum
ProgressBar.setProgress()

Beispiel ( Verwendung dieses Beispiels )

Im folgenden Beispiel werden ProgressBar- und Label-Komponenteninstanzen erstellt, um den Status der Fortschrittsleiste anzuzeigen:

import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.indeterminate = false;
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.maximum = 256;
myProgressBar.setSize(320, 16);
myProgressBar.move(10, 10)
addChild(myProgressBar);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myProgressBar.x, myProgressBar.y + myProgressBar.height);
addChild(myLabel);

var t:Timer = new Timer(150);
t.addEventListener(TimerEvent.TIMER, timerHandler);
t.start();

function timerHandler(event:TimerEvent):void {
    myProgressBar.setProgress(myProgressBar.value + 1, myProgressBar.maximum);
    if (myProgressBar.percentComplete == 100) {
        myProgressBar.setProgress(0, myProgressBar.maximum);
    }
    myLabel.text = int(myProgressBar.value) + " of " + int(myProgressBar.maximum) + " (" + int(myProgressBar.percentComplete) + "%)";
}

POLLED

Konstante

public static const POLLED:String = "polled"

Sprachversion:

ActionScript 3.0

Produktversion:

Flash CS3

Laufzeitversionen:

Flash Player 9.0.28.0, AIR 1.0

Der Fortschritt wird durch Abrufen der Quelle aktualisiert. Die Eigenschaft source muss ein Objekt angeben, dass die Eigenschaften bytesLoaded und bytesTotal übergibt.

Verwandte API-Elemente

ScrollPane.bytesLoaded
ScrollPane.bytesTotal
UILoader.bytesLoaded
UILoader.bytesTotal
Sound.bytesLoaded
Sound.bytesTotal
NetStream.bytesLoaded
NetStream.bytesTotal
URLLoader.bytesLoaded
URLLoader.bytesTotal

Beispiel ( Verwendung dieses Beispiels )

Im folgenden Beispiel wird die ProgressBar-Komponente verwendet, um den Ladefortschritt einer FLV-Datei anzuzeigen:

import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/video/cuepoints.flv";

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
ns.client = {onMetaData:metaDataHandler};
ns.play(url);

var vid:Video = new Video();
vid.attachNetStream(ns);
vid.x = (stage.stageWidth - vid.width) / 2;
vid.y = (stage.stageHeight - vid.height) / 2;
addChild(vid);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.POLLED;
myProgressBar.indeterminate = false;
myProgressBar.source = ns;
myProgressBar.setSize(vid.width, myProgressBar.height);
myProgressBar.move(vid.x, vid.y + vid.height);
addChild(myProgressBar);

function metaDataHandler(meta:Object):void {
    try {
        trace("w:" + meta.width, "h:" + meta.height);
        vid.width = meta.width;
        vid.height = meta.height;
        vid.x = (stage.stageWidth - vid.width) / 2;
        vid.y = (stage.stageHeight - vid.height) / 2;
        myProgressBar.width = vid.width;
        myProgressBar.move(vid.x, vid.y + vid.height);
    } catch (error:*) {
        // 
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

ProgressBarMode - AS3 Flash

Klassen x

EVENT

MANUAL

POLLED