URLLoaderDataFormat - Adobe ActionScript® 3 (AS3 ) API-Referenz

Paket	flash.net
Klasse	public final class URLLoaderDataFormat
Vererbung	URLLoaderDataFormat Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Mit der URLLoaderDataFormat-Klasse wird angegeben, wie heruntergeladene Daten empfangen werden.

Beispiele anzeigen

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

Öffentliche Konstanten

	Konstante		Definiert von
		BINARY : String = "binary" [statisch] Gibt an, dass heruntergeladene Daten als unformatierte Binärdaten empfangen werden.	URLLoaderDataFormat
		TEXT : String = "text" [statisch] Gibt an, dass heruntergeladene Daten als Text empfangen werden.	URLLoaderDataFormat
		VARIABLES : String = "variables" [statisch] Gibt an, dass heruntergeladene Daten als URL-kodierte Variablen empfangen werden.	URLLoaderDataFormat

Konstantendetails

BINARY

Konstante

public static const BINARY:String = "binary"

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Gibt an, dass heruntergeladene Daten als unformatierte Binärdaten empfangen werden.

TEXT

Konstante

public static const TEXT:String = "text"

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Gibt an, dass heruntergeladene Daten als Text empfangen werden.

VARIABLES

Konstante

public static const VARIABLES:String = "variables"

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Gibt an, dass heruntergeladene Daten als URL-kodierte Variablen empfangen werden.

Beispiele Verwendung dieses Beispiels

URLLoaderDataFormatExample.as

Im folgenden Beispiel wird die URLLoaderDataFormatExample-Klasse verwendet, um Datenformat und Statusinformationen einer zur Laufzeit geladenen Datei anzuzeigen. Dies wird in den folgenden Schritten erreicht:

Der Klassenkonstruktor erstellt eine URLLoader-Instanz mit dem Namen loader und eine URLRequest-Instanz mit dem Namen request, wobei es sich um den Standort und den Namen der zu ladenden Datei handelt.
Das Objekt loader wird an die Methode configureListeners() übergeben, die für jedes unterstützte URLLoader-Ereignis Listener hinzufügt.
- completeHandler(): Listener für das Ereignis complete, das nach dem erfolgreichen Laden der Datei „TextFile.txt“ ausgelöst wird.
- openHandler(): Listener für das Ereignis open, das beim Start des Downloads der Datei „TextFile.txt“ (in den Player) ausgelöst wird.
- progressHandler(): Listener für das Ereignis progress, das beim Empfang von Daten während des Download-Vorgangs ausgelöst wird.
- securityErrorHandler(): Listener für securityError-Ereignisse, die ausgelöst werden, wenn mit der falschen Sicherheitseinstellung für die lokale Wiedergabe auf die Textdatei zugegriffen wird.
- httpStatusHandler(): Listener für httpStatusHandler-Ereignisse, die in diesem Fall nicht ausgelöst werden, da es sich bei „TextFile.txt“ um eine lokale Datei handelt.
- ioErrorHandler(): Listener für ioError-Ereignisse, die nur bei schwerwiegenden Fehlern ausgelöst werden, beispielsweise wenn die Datei nicht vorhanden ist.
Dann wird das Objekt request an die Methode loader.load() übergeben, die die Textdatei mit einem DisplayObject-Objekt in den Speicher lädt.

Hinweise:

Für die Kompilierung der SWF-Datei müssen Sie die Option „Sicherheit bei lokaler Wiedergabe“ auf „Nur auf lokale Dateien zugreifen“ einstellen.
Zur Ausführung dieses Beispiels müssen Sie eine Datei mit dem Namen „TextFile.txt“ in dem Verzeichnis ablegen, in dem sich die SWF-Datei befindet. Wenn Sie möchten, dass in diesem Beispiel Binär- oder URL-kodierte Datendateien ermittelt werden, müssen Sie die Datei im entsprechenden Datenformat bereitstellen und „TextFile.txt“ in den Namen und den Speicherort der neuen Datei ändern.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderDataFormatExample extends Sprite {
        private var source:String = "TextFile.txt";
        private var dataFormat:String = URLLoaderDataFormat.TEXT;
        private var loader:URLLoader;
        
        public function URLLoaderDataFormatExample () {
            loader = new URLLoader();
            loader.dataFormat = dataFormat;
            configureListeners(loader);
            var request:URLRequest = new URLRequest(source);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Error loading requested document: " + source);
            }
        }

        private function configureListeners(dispatcher:URLLoader):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            switch(loader.dataFormat) {
                case URLLoaderDataFormat.TEXT :
                    trace("completeHandler (text): " + loader.data);
                    break;
                case URLLoaderDataFormat.BINARY :
                    trace("completeHandler (binary): " + loader.data);
                    break;
                case URLLoaderDataFormat.VARIABLES :
                    trace("completeHandler (variables): " + loader.data);
                    break;
            }
        }

        private function httpStatusHandler(event:Event):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

URLLoaderDataFormat - AS3

Klassen x

BINARY

TEXT

VARIABLES