| Package | fl.managers |
| Classe | public class StyleManager |
| Héritage | StyleManager  Object |
| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Propriétés publiques
Masquer les propriétés publiques héritées
Afficher les propriétés publiques héritéesMéthodes publiques
| Méthode | Défini par | ||
|---|---|---|---|
Crée un nouvel objet StyleManager. | StyleManager | ||
[statique]
Retire un style du composant spécifié. | StyleManager | ||
[statique]
Supprime un style global de tous les composants d’interface utilisateur d’un document. | StyleManager | ||
[statique]
Récupère un style existant dans un certain composant. | StyleManager | ||
[statique]
Récupère le nom d'un style global. | StyleManager | ||
 |
Indique si la propriété spécifiée d’un objet est définie. | Object | |
|
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre. | Object | |
|
Indique si la propriété spécifiée existe et est énumérable. | Object | |
[statique]
Enregistre une occurrence de composant auprès du gestionnaire de style. | StyleManager | ||
[statique]
Définit un style pour toutes les occurrences d’un type de composant, par exemple, pour toutes les occurrences d’un composant Button ou d’un composant ComboBox. | StyleManager | ||
|
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle. | Object | |
[statique]
Définit un style global pour tous les composants d’interface utilisateur d’un document. | StyleManager | ||
|
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur. | Object | |
|
Renvoie la représentation sous forme de chaîne de l’objet spécifié. | Object | |
|
Renvoie la valeur primitive de l’objet spécifié. | Object | |
Détails du constructeur
StyleManager | () | Constructeur |
public function StyleManager()| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Crée un nouvel objet StyleManager.
Détails de la méthode
clearComponentStyle | () | méthode |
public static function clearComponentStyle(component:Object, name:String):void| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Retire un style du composant spécifié.
Paramètres
component:Object — Nom du composant dans lequel le style doit être supprimé.
| |
name:String — Nom du style à supprimer.
|
Eléments de l’API associés
clearStyle | () | méthode |
public static function clearStyle(name:String):void| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Supprime un style global de tous les composants d’interface utilisateur d’un document.
Paramètres
name:String — Nom du style global à supprimer.
|
Eléments de l’API associés
getComponentStyle | () | méthode |
public static function getComponentStyle(component:Object, name:String):Object| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Récupère un style existant dans un certain composant.
Paramètres
component:Object — Nom de l’occurrence du composant dans laquelle le style demandé doit être recherché.
| |
name:String — Nom du style à récupérer.
|
Object — Style demandé par le composant spécifié. Cette fonction renvoie la valeur null si le style spécifié est introuvable.
|
Eléments de l’API associés
getStyle | () | méthode |
public static function getStyle(name:String):Object| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Récupère le nom d'un style global.
Paramètres
name:String — Nom du style à récupérer.
|
Object — Valeur du style global qui a été récupéré.
|
Eléments de l’API associés
registerInstance | () | méthode |
public static function registerInstance(instance:UIComponent):void| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Enregistre une occurrence de composant auprès du gestionnaire de style. Dès lors qu’une occurrence de composant est instanciée, elle peut s’enregistrer auprès du gestionnaire de style pour être avertie des changements de style. Les occurrences de composant peuvent s’enregistrer afin de recevoir une notification à chaque changement de style dans un composant ou à un niveau global.
Paramètres
instance:UIComponent — Occurrence de composant à enregistrer pour la gestion des styles.
|
setComponentStyle | () | méthode |
public static function setComponentStyle(component:Object, name:String, style:Object):void| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Définit un style pour toutes les occurrences d’un type de composant, par exemple, pour toutes les occurrences d’un composant Button ou d’un composant ComboBox.
Paramètres
component:Object — Type de composant, par exemple, Button ou ComboBox. Ce paramètre accepte également une occurrence de composant ou une classe qui peut être utilisée pour identifier toutes les occurrences d’un type de composant.
| |
name:String — Nom du style à définir.
| |
style:Object — Objet style décrivant le style à définir.
|
Eléments de l’API associés
setStyle | () | méthode |
public static function setStyle(name:String, style:Object):void| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Définit un style global pour tous les composants d’interface utilisateur d’un document.
Paramètres
name:String — Valeur de type chaîne nommant le style à définir.
| |
style:Object — Objet style à définir. La valeur de cette propriété dépend du style défini par l’utilisateur. Par exemple, si le style défini est « textFormat », la propriété style doit être définie sur un objet TextFormat. Une incohérence entre le nom du style et la valeur de la propriété style peut perturber le comportement du composant.
|
Eléments de l’API associés
Exemples Comment utiliser cet exemple
StyleManagerExample.as
Cet exemple montre comment créer dynamiquement un composant DataGrid et écouter ses événements.
Pour exécuter l’exemple, suivez ces étapes :
- Ajoutez les composants DataGrid, Button, Label et TextArea à la bibliothèque.
- Enregistrez ce code sous le nom StyleManagerExample.as dans le même répertoire que votre fichier FLA.
- Dans le fichier FLA, définissez la classe Document sur StyleManagerExample.
package
{
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextArea;
import fl.core.UIComponent;
import fl.managers.FocusManager;
import fl.managers.StyleManager;
import flash.display.InteractiveObject;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
public class StyleManagerExample extends Sprite
{
private var btn:Button;
private var ta1:TextArea;
private var ta2:TextArea;
private var ta3:TextArea;
private var ta4:TextArea;
private var description:Label;
private var dg:DataGrid;
private var formatForInstance:TextFormat;
private var formatForGlobal:TextFormat;
private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
public function StyleManagerExample() {
setupComponents();
setupUI();
setupStyles();
}
private function setupUI():void {
var setInstanceStyleBtn:Button = new Button();
var clearInstanceStyleBtn:Button = new Button();
var setClassStyleBtn:Button = new Button();
var clearClassStyleBtn:Button = new Button();
var setGlobalStyleBtn:Button = new Button();
var clearGlobalStyleBtn:Button = new Button();
setInstanceStyleBtn.label = "Set Instance Style";
clearInstanceStyleBtn.label = "Clear Instance Style";
setClassStyleBtn.label = "Set Class Style";
clearClassStyleBtn.label = "Clear Class Style";
setGlobalStyleBtn.label = "Set Global Style";
clearGlobalStyleBtn.label = "Clear Global Style";
setInstanceStyleBtn.focusEnabled = false;
clearInstanceStyleBtn.focusEnabled = false;
setClassStyleBtn.focusEnabled = false;
clearClassStyleBtn.focusEnabled = false;
setGlobalStyleBtn.focusEnabled = false;
clearGlobalStyleBtn.focusEnabled = false;
setInstanceStyleBtn.move(10,310);
clearInstanceStyleBtn.move(10,340);
setClassStyleBtn.move(140,310);
clearClassStyleBtn.move(140,340);
setGlobalStyleBtn.move(270,310);
clearGlobalStyleBtn.move(270,340);
setInstanceStyleBtn.setSize(120,24);
clearInstanceStyleBtn.setSize(120,24);
setClassStyleBtn.setSize(120,24);
clearClassStyleBtn.setSize(120,24);
setGlobalStyleBtn.setSize(120,24);
clearGlobalStyleBtn.setSize(120,24);
setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);
description = new Label();
description.move(10, 370);
description.autoSize = TextFieldAutoSize.LEFT;
description.text = "";
addChild(setInstanceStyleBtn);
addChild(clearInstanceStyleBtn);
addChild(setClassStyleBtn);
addChild(clearClassStyleBtn);
addChild(setGlobalStyleBtn);
addChild(clearGlobalStyleBtn);
addChild(description);
}
private function setupComponents():void {
dg = new DataGrid();
dg.addItem( { Name:"John Alpha", Number:"555-123-0101" } );
dg.addItem( { Name:"Mary Bravo", Number:"555-372-3322" } );
dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
dg.addItem( { Name:"Susan Delta", Number:"555-987-3434" } );
dg.move(10,10);
dg.setSize(200,290);
dg.columns = ["Name","Number"];
addChild(dg);
ta1 = new TextArea();
ta1.move(220,10);
ta1.setSize(150,140);
ta1.text = testString;
ta1.tabEnabled = true;
addChild(ta1);
ta2 = new TextArea();
ta2.move(380,10);
ta2.setSize(150,140);
ta2.text = testString;
ta2.tabEnabled = true;
addChild(ta2);
ta3 = new TextArea();
ta3.move(220,160);
ta3.setSize(150,140);
ta3.text = testString;
ta3.tabEnabled = true;
addChild(ta3);
ta4 = new TextArea();
ta4.move(380,160);
ta4.setSize(150,140);
ta4.text = testString;
ta4.tabEnabled = true;
addChild(ta4);
}
private function setupStyles():void {
formatForGlobal = new TextFormat();
formatForGlobal.font = "Georgia";
formatForGlobal.size = 10;
formatForInstance = new TextFormat();
formatForInstance.underline = true;
}
private function setInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.setStyle("textFormat",formatForInstance);
description.text = "The TextArea object with focus is now underlined.";
}
}
private function clearInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.clearStyle("textFormat");
description.text = "The TextArea object with focus is no longer underlined.";
}
}
private function setClassStyle(e:MouseEvent):void {
var c:Class = TextArea;
var styleName:String = "textPadding";
var value:Number = 10;
StyleManager.setComponentStyle(c,styleName,value);
description.text = "Padding for all TextArea instances is now 10.";
}
private function clearClassStyle(e:MouseEvent):void {
var styleName:String = "textPadding";
var c:Class = TextArea;
StyleManager.clearComponentStyle(c,styleName);
description.text = "TextArea padding has been reset to the default.";
}
private function setGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
var value:Object = formatForGlobal;
StyleManager.setStyle(styleName,value);
description.text = "All components now use font Georgia size 10.";
}
private function clearGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
StyleManager.clearStyle(styleName);
description.text = "Font style for all components has been cleared.";
}
}
}
Tue Jun 12 2018, 09:30 AM Z