Geolocation

Package	flash.sensors
Classe	public class Geolocation
Héritage	Geolocation EventDispatcher Object

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

La classe Geolocation distribue des événements en réponse au capteur d’emplacement du périphérique.

Si un périphérique prend en charge la géolocalisation, vous pouvez utiliser cette classe pour connaître l’emplacement géographique actuel du périphérique. L’emplacement géographique s’affiche sur le périphérique sous forme de coordonnées de latitude et de longitude (au format standard WGS-84). Lorsque l’emplacement du périphérique change, vous pouvez recevoir des mises à jour sur ces changements. Si le périphérique prend en charge cette fonctionnalité, vous serez en mesure d’obtenir des informations sur l’altitude, la précision, la direction, la vitesse, et la date et l’heure de la dernière modification de l’emplacement.

Prise en charge du profil AIR : cette fonctionnalité est prise en charge uniquement sur les périphériques mobiles. Elle n’est pas prise en charge sur les périphériques de bureau ou sur les périphériques AIR pour TV. Vous pouvez tester la prise en charge lors de l’exécution à l’aide de la propriété Geolocation.isSupported. Voir Prise en charge du profil AIR pour plus d’informations sur la prise en charge de l’API dans plusieurs profils.

Remarque : pour activer la géolocalisation dans iOS, veillez à ajouter une paire clé-valeur à l’élément infoAdditions dans le fichier XML de l’application. Voir les paramètres iOS pour plus d’informations sur l’élément infoAdditions.

Consulter les exemples

Plus d’exemples

Détection des changements de géolocalisation

Informations complémentaires

Cristophe Coenraets : Collaboration multi-utilisateurs sur Google Maps

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		constructor : Object Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.	Object
		isSupported : Boolean [statique] [lecture seule] Indique si un capteur d’emplacement est disponible sur le périphérique (true) ou pas (false).	Geolocation
		locationAlwaysUsePermission : Boolean Cette propriété détermine l’utilisation du type d’autorisation d’accès de géolocalisation.	Geolocation
		muted : Boolean [lecture seule] Indique si l’utilisateur a refusé (true) ou autorisé (false) l’accès à la géolocalisation.	Geolocation
		permissionStatus : String [statique] [lecture seule]	Geolocation

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		Geolocation() Crée une nouvelle occurrence de Geolocation.	Geolocation
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement.	EventDispatcher
		dispatchEvent(event:Event):Boolean Distribue un événement dans le flux d’événements.	EventDispatcher
		hasEventListener(type:String):Boolean Vérifie si des écouteurs sont enregistrés auprès de l’objet EventDispatcher pour un type spécifique d’événement.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d’un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Supprime un écouteur de l’objet EventDispatcher.	EventDispatcher
		requestPermission():void	Geolocation
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.	Object
		setRequestedUpdateInterval(interval:Number):void Utilisée pour définir l’intervalle de mise à jour, en millisecondes.	Geolocation
		toLocaleString():String Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l’objet spécifié.	Object
		valueOf():Object Renvoie la valeur primitive de l’objet spécifié.	Object
		willTrigger(type:String):Boolean Vérifie si un écouteur d’événement est enregistré auprès de cet objet EventDispatcher ou de ses ancêtres pour le type d’événement spécifié.	EventDispatcher

Evénements

Cliquez pour plus d’informations sur les événements

Masquer les événements hérités

Afficher les événements hérités

	Synthèse	Défini par
activate	[Evénement de diffusion] Distribué lorsque l’application Flash Player obtient le focus du système d’exploitation et devient active.	EventDispatcher
deactivate	[Evénement de diffusion] Distribué lorsque l’application Flash Player ou AIR perd le focus du système d’exploitation et devient inactive.	EventDispatcher
permissionStatus		Geolocation
status	L’objet Geolocation distribue des événements status lorsque l’utilisateur modifie l’accès au capteur d’emplacement.	Geolocation
update	L’événement update est distribué en réponse à des mises à jour du capteur d’emplacement.	Geolocation

Détails de la propriété

isSupported

propriété

isSupported:Boolean [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

Indique si un capteur d’emplacement est disponible sur le périphérique (true) ou pas (false).

Implémentation
public static function get isSupported():Boolean

Plus d’exemples

Vérification de la prise en charge de la géolocalisation

locationAlwaysUsePermission

propriété

locationAlwaysUsePermission:Boolean

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 29

Cette propriété détermine l’utilisation du type d’autorisation d’accès de géolocalisation. Le type d’autorisation peut être Toujours ou Lors de l’utilisation. Si la propriété est définie sur false, elle demande une autorisation lors de l’utilisation, sinon elle demande une autorisation d’utilisation permanente. Définissez la propriété avant d’appeler requestPermission(). La valeur par défaut de la propriété est false.

Implémentation
public function get locationAlwaysUsePermission():Boolean
public function set locationAlwaysUsePermission(value:Boolean):void

muted

propriété

muted:Boolean [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Indique si l’utilisateur a refusé (true) ou autorisé (false) l’accès à la géolocalisation. Lorsque cette valeur change, un événement status est distribué.

Implémentation
public function get muted():Boolean

Eléments de l’API associés

status

permissionStatus

propriété

permissionStatus:String [lecture seule]

Implémentation
public static function get permissionStatus():String

Détails du constructeur

()

Constructeur

public function Geolocation()

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

Crée une nouvelle occurrence de Geolocation.

Détails de la méthode

requestPermission

()

méthode

public function requestPermission():void

setRequestedUpdateInterval

()

méthode

public function setRequestedUpdateInterval(interval:Number):void

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

Utilisée pour définir l’intervalle de mise à jour, en millisecondes. L’intervalle de mise à jour n’est qu’une suggestion pour préserver la charge de la batterie. L’intervalle réel entre les mises à jour d’emplacement peut être supérieur ou inférieur à cette valeur. Toute modification de l’intervalle de mise à jour à l’aide de cette méthode aura une incidence sur tous les écouteurs d’événement update. Il est possible d’utiliser la classe Geolocation sans appeler la méthode setRequestedUpdateInterval(). Dans ce cas, la plate-forme fournit des mises à jour en fonction de l’intervalle par défaut.

Remarque : les iPhone de première génération, qui n’incluent pas d’unité GPS, distribuent des événements update uniquement de manière occasionnelle. Sur ces dispositifs, un objet Geolocation distribue initialement un ou deux événements update. Il distribue ensuite des événements update lorsque les informations changent nettement.

Paramètres

interval:Number — Intervalle de mise à jour spécifié. Si la valeur du paramètre interval est <= 0, tout appel de cette méthode reste sans effet.

Valeur émise

ArgumentError — La valeur spécifiée du paramètre interval est inférieure à zéro.

Détails de l’événement

permissionStatus

Evénement

Type d’objet d’événement: flash.events.PermissionEvent

status

Evénement

Type d’objet d’événement: flash.events.StatusEvent
propriété StatusEvent.type = flash.events.StatusEvent.STATUS

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

L’objet Geolocation distribue des événements status lorsque l’utilisateur modifie l’accès au capteur d’emplacement. Par exemple, si l’utilisateur empêche l’application d’accéder aux données de localisation en réponse à une invite de périphérique, l’objet Geolocation distribue un événement status. Lorsque l’état bascule sur un état dans lequel le capteur d’emplacement n’est pas disponible, la propriété muted de l’occurrence de Geolocation est définie sur true.

Définit la valeur de la propriété type d’un objet événement status.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`code`	Description de l’état de l’objet.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`level`	Catégorie du message, telle que `"status"`, `"warning"` ou `"error"`.
`target`	Objet publiant son état.

Eléments de l’API associés

muted

update

Evénement

Type d’objet d’événement: flash.events.GeolocationEvent
propriété GeolocationEvent.type = flash.events.GeolocationEvent.UPDATE

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2, Flash Lite 4

L’événement update est distribué en réponse à des mises à jour du capteur d’emplacement. Cet événement est distribué dans les cas suivants :

Lorsqu’une nouvelle fonction d’écouteur est associée via la méthode addEventListener(), cet événement est distribué une seule fois pour tous les écouteurs enregistrés afin de fournir la valeur actuelle de l’emplacement. Remarque : AIR distribue immédiatement le premier événement si l’emplacement du périphérique est connu ; votre code doit indiquer que l’événement distribué initialement peut ne pas contenir l’emplacement actuel.
Chaque fois que la plate-forme fournit des mises à jours d’emplacement à des intervalles déterminés par le périphérique.
Chaque fois que l’application omet un changement d’emplacement (notamment lorsque l’application quitte le mode de veille).

Définit la valeur de la propriété type d’un objet d’événement tactile GeolocationEvent.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	Objet qui traite activement l’objet de l’événement avec un écouteur d’événement.
`target`	Objet GeolocationEvent recevant les données.

Exemples Comment utiliser cet exemple

GeolocationExample.as

Dans l’exemple suivant, l’application affiche la latitude, la longitude et la précision horizontale des événements update de géolocalisation au fur et à mesure qu’ils sont reçus.

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.GeolocationEvent;
    import flash.events.MouseEvent;
    import flash.events.StatusEvent;
    import flash.sensors.Geolocation;
    import flash.text.TextField;
    import flash.text.TextFormat;
    
    public class GeolocationTest extends Sprite
    {
        
        private var geo:Geolocation; 
        private var log:TextField;
        
        public function GeolocationTest()
        {            
            super();
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            setUpTextField();
            
            if (Geolocation.isSupported) 
            { 
                geo = new Geolocation(); 
                if (!geo.muted) 
                { 
                    geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler); 
                } 
                geo.addEventListener(StatusEvent.STATUS, geoStatusHandler);
            } 
            else 
            { 
                log.text = "Geolocation not supported"; 
            } 
        }
        
        public function geoUpdateHandler(event:GeolocationEvent):void 
        { 
            log.text = "latitude : " + event.latitude.toString() + "\n"; 
            log.appendText("longitude : " + event.longitude.toString() + "\n");
        } 
        
        public function geoStatusHandler(event:StatusEvent):void 
        { 
            if (geo.muted)
                geo.removeEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
            else
                geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
        }
        
        private function setUpTextField():void
        {
            log = new TextField();
            var format:TextFormat = new TextFormat("_sans", 24);
            log.defaultTextFormat = format;
            log.border = true;
            log.wordWrap = true;
            log.multiline = true;
            log.x = 10;
            log.y = 10;
            log.height = stage.stageHeight - 20;
            log.width = stage.stageWidth - 20;
            log.addEventListener(MouseEvent.CLICK, clearLog);
            addChild(log);
        }
        private function clearLog(event:MouseEvent):void
        {
            log.text = "";
        }
    }
}

Informations juridiques | Politique de confidentialité en ligne

Geolocation - AS3

Classes x

isSupported

locationAlwaysUsePermission

muted

permissionStatus

Geolocation

requestPermission

setRequestedUpdateInterval

permissionStatus

status

update