Справочник по ActionScript® 3.0 для платформы Adobe® Flash®
Домашняя страница  |  Скрыть список пакетов и классов |  Пакеты  |  Классы  |  Что нового  |  Указатель  |  Приложения  |  Почему по-английски?
Фильтры: Получение данных с сервера...
Получение данных с сервера...
flash.display 

CapsStyle  - AS3

Пакетflash.display
Классpublic final class CapsStyle
НаследованиеCapsStyle Inheritance Object

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9

Класс CapsStyle — это перечисление значений констант, задающих стили концов линий при рисовании линий. Константы предназначены для использования в качестве значений параметра caps метода flash.display.Graphics.lineStyle(). Можно задать концы линий трех типов:

Три типа концов линий: NONE (нет), ROUND (круглые) и SQUARE (квадратные).

Посмотреть примеры

Связанные элементы API



Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
Общедоступные методы
 МетодОпределено
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали.
Object
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Общедоступные константы
 КонстантаОпределено
  NONE : String = "none"
[статические] С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задается отсутствие концов линий.
CapsStyle
  ROUND : String = "round"
[статические] С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задаются круглые концы линий.
CapsStyle
  SQUARE : String = "square"
[статические] С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задаются квадратные концы линий.
CapsStyle
Сведения о константе

NONE

Константа
public static const NONE:String = "none"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9

С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задается отсутствие концов линий.

ROUND

Константа 
public static const ROUND:String = "round"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9

С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задаются круглые концы линий.

SQUARE

Константа 
public static const SQUARE:String = "square"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9

С его помощью в параметре caps метода flash.display.Graphics.lineStyle() задаются квадратные концы линий.

CapsStyleExample.as

В следующем примере класс CapsStyleExample используется для рисования трех параллельных линий с разными типами концов.
  1. Для каждой линии заданы следующие свойства.
    • Длина линии — 80 пикселей.
    • Цвет рамки — оранжевый.
    • Размер рамки — 30 пикселей.
    • Цвет подсветки — серый.
    • Размер подсветки — 0 пикселей.
    • Значение альфа-канала — 1 для получения сплошного цвета.
    • Хинтинг пикселей имеет значение false (не выполняется хинтинг до полных пикселей).
    • Режим масштабирования линий - обычный: масштабирование по ширине.
    • Стиль стыка концов рамки - MITER (уголок).
    • Длина уголка - 1, то есть, уголок обрезается близко к линии.
  2. Конструктор класса создает три вертикальные линии, начиная с координат x = 0, y = 0, путем троекратного вызова метода drawLine() с использованием разных стилей концов линий (нет, круглые, квадратные). В каждом из трех вызовов метода drawLine() используются перечисленные выше стиль концов и свойства для рисования вертикальной линии и соответствующей подсветки. Первый вызов создает новый объект Shape child, а затем с помощью методов класса Graphics задается стиль линии и рисуются линии с подсветкой. Каждый экземпляр child добавляется в список отображения и отрисовывается в рабочей области.
  3. Соединенные сегменты линии перерисовываются с использованием метода refreshLayout() на пикселях y = 80, начиная с пикселей x = 80, где сегменты линии разделены 25 пикселями.
package {
    import flash.display.CapsStyle;
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class CapsStyleExample extends Sprite {
        private var lineLength:uint            = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderJointStyle:String    = JointStyle.MITER;
        private var borderMiterLimit:uint      = 1;

        public function CapsStyleExample() {
            drawLine(CapsStyle.NONE);
            drawLine(CapsStyle.ROUND);
            drawLine(CapsStyle.SQUARE);
            refreshLayout();
        }

        private function drawLine(capsStyle:String):void {
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     capsStyle,
                                     borderJointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = lineLength;
            lastChild.y = lineLength;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = lineLength;
                lastChild = child;
            }
        }
    }
}




[ X ]Почему по-английски?
Содержимое Справочника ActionScript 3.0 отображается на английском языке

Не все части Справочника ActionScript 3.0 переводятся на все языки. Если какой-то текстовый элемент не переведен, он отображается на английском языке. Например, компонент ga.controls.HelpBox не переведен ни на один из языков. Это значит, что в русской версии справки компонент ga.controls.HelpBox будет отображаться на английском языке.