ContextMenuEvent  - AS3

Объект списка отображения, к которому присоединено меню. Это может быть цель мыши (mouseTarget) или один из его предков в списке отображения.

Указывает на то, было ли свойству mouseTarget присвоено значение null по соображениям безопасности. Если номинальным значением свойства menuTarget является ссылка на объект DisplayObject в другой изолированной программной среде, свойство menuTarget принимает значение null, пока не будут заданы двусторонние права в границах данной изолированной среды. Права задаются путем вызова метода Security.allowDomain() из SWF-файла или путем указания файла политики на сервере файла изображения и установки флага LoaderContext.checkPolicyFile при загрузке изображения.

Связанные элементы API

Объект списка отображения, который пользователь щелкает правой кнопкой мыши для отображения контекстного меню. Это может быть объект списка отображения, к которому прикреплено меню (contextMenuOwner), или один из его потомков в списке отображения.

Это свойство может принимать значение null по двум причинам: отсутствует целевой объект для мыши (например, курсор мыши находится над объектом фона) или существует целевой объект для мыши, но он находится в изолированной среде безопасности, доступ к которой запрещен. Используйте свойство isMouseTargetInaccessible() для определения причины.

Связанные элементы API

Создает объект Event, содержащий данные о событиях меню. Объекты Event передаются прослушивателям событий в качестве параметров.

Связанные элементы API

Создает копию объекта ContextMenuEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта ContextMenuEvent. Строка имеет следующий формат:

[ContextMenuEvent type=value bubbles=value cancelable=value ... contextMenuOwner=value]

Определяет значение свойства type объекта события menuItemSelect.

Это событие имеет следующие свойства:

Связанные элементы API

Определяет значение свойства type объекта события menuSelect.

Это событие имеет следующие свойства:

Связанные элементы API

1. Объявляется свойство myContextMenu, которое затем назначается новому объекту ContextMenu, и свойство redRectangle (типа Sprite).
2. Вызывается метод removeDefaultItems(). Этот метод удаляет все встройнные элементы контекстного меню, кроме «Печать».
3. Вызывается метод addCustomMenuItems(). Этот метод помещает элемент меню Противоположные цвета в массиве defaultItems с помощью метода push() объекта Array. Для объекта ContextMenuItem добавляется прослушиватель событий menuItemSelect и вызывается соответствующий метод menuItemSelectHandler(). Этот метод печатает несколько выписок trace() при каждом выборе позиции «Противоположные цвета» из контекстного меню. Помимо этого, красный квадрат становится черным, а черный текст - красным.
4. В конструкторе добавляется прослушиватель событий menuSelect и соответствующий метод menuSelectHandler(), который просто распечатывает три выписки trace() при каждом выборе элемента в контекстном меню.
5. Конструктор вызывает метод addChildren(), который рисует красный квадрат и добавляет его в список отображения, который сразу показывает квадрат.
6. В завершение, myContextMenu назначается контекстному меню свойства redRectangle, чтобы пользовательское контекстное меню отображалось, только когда указатель мыши находится над квадратом.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}