NetStatusEvent  - AS3

Объект со свойствами, описывающими состояние объекта или условие ошибки.

Информационный объект может иметь свойство code, содержащее строку, представляющую конкретное событие, или свойство level, содержащее строку, являющуюсяstatus или error.

Информационный объект может быть и другим. Свойства code и level могут не поддерживаться для некоторых реализаций, также некоторые серверы могут отправлять другие объекты.

Подключения P2P отправляют сообщения для NetConnection с параметром stream в информационном объекте, который указывает, к какому объекту NetStream относится сообщение.

Например, система Flex Data Services отправляет объекты Message, которые являются причиной ошибок поведения типа данных, при попытке доступа к свойству code или level.

В следующей таблице описываются возможные строковые значения свойств code и level.

Если постоянно появляются ошибки, связанные с буфером, попробуйте изменить его с помощью свойства NetStream.bufferTime.

Связанные элементы API

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Создает объект Event, содержащий сведения о событиях netStatus. Объекты Event передаются прослушивателям событий в качестве параметров.

Связанные элементы API

Создает копию объекта NetStatusEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта NetStatusEvent. Строка имеет следующий формат:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Задает значение свойства type для объекта события netStatus.

Это событие имеет следующие свойства:

Связанные элементы API

Здесь метод netStatusHandler регистрируется в качестве прослушивателя события NetStatusEvent — NetConnection.netStatus. Когда определяется состояние (успешно или неуспешно) попытки выполнить NetConnection.connect(), событие netStatus запускает этот метод. Если попытка подключиться к объекту NetConnection успешная (другими словами, если свойство info объекта NetStatusEvent, отправленного событием netStatus, имеет свойство code с указанием успешного выполнения), код создает объекты Video и NetStream и вызывает методы Video.attachNetStream() и NetStream.play().

Примечание. Чтобы запустить данный пример, вам потребуется FLV-файл, имя и место расположения которого совпадают с переменной, переданной videoURL. В данном случае, FLV-файл Video.flv находится в том же каталоге, где размещается SWF-файл.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }