Matrix  - AS3

Значение, от которого зависит размещение пикселей вдоль оси x при масштабировании или повороте изображения.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

Значение, от которого зависит размещение пикселей вдоль оси y при повороте или наклоне изображения.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

Значение, от которого зависит размещение пикселей вдоль оси x при повороте или наклоне изображения.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

Значение, от которого зависит размещение пикселей вдоль оси y при масштабировании или повороте изображения.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

Расстояние, на которое перемещается каждая точка вдоль оси x.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

Расстояние, на которое перемещается каждая точка вдоль оси y.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Создает новый объект Matrix с заданными параметрами. В матричном представлении свойства упорядочиваются следующим образом:

Если в конструкторе new Matrix() не указаны параметры, он создает единичную матрицу со следующими значениями:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

В матричном представлении единичная матрица имеет следующий вид:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Возвращает новый объект Matrix, который является клоном данной матрицы с точной копией содержащегося в ней объекта.

Сцепляет матрицу с текущей матрицей, фактически объединяя геометрические искажения двух матриц. В математическом представлении сцепление двух матриц равнозначно сложению матриц с использованием умножения.

Например, если матрица m1 масштабирует объект с использованием коэффициента, равного четырем, а матрица m2 поворачивает объект на 1,5707963267949 радиан (Math.PI/2), то m1.concat(m2) преобразует m1 в матрицу, которая выполняет масштабирование объекта с коэффициентом, равным четырем, и поворачивает объект на Math.PI/2 радиан.

Этот метод заменяет исходную матрицу сцепленной матрицей. Если необходимо выполнить сцепление двух матриц без изменения этих двух исходных матриц, сначала скопируйте исходную матрицу с помощью метода clone(), как показано в разделе примеров классов.

Параметры

Копирует объект Vector3D в определенный столбец вызывающего объекта Matrix3D.

Параметры

Копирует определенный столбец вызывающего объекта Matrix в объект Vector3D. Элемент w объекта Vector3D не будет изменен.

Параметры

Копирует все данные матрицы из исходного объекта Point в вызывающий объект Matrix.

Параметры

Копирует объект Vector3D в определенную строку вызывающего объекта Matrix.

Параметры

Копирует определенную строку вызывающего объекта Matrix в объект Vector3D. Элемент w объекта Vector3D не будет изменен.

Параметры

Включает параметры для масштабирования, поворота и перемещения. При применении к матрице задает матричные значения на основе этих параметров.

С помощью метода createBox() можно получить такую же матрицу, как и с помощью последовательного применения методов identity(), rotate(), scale() и translate(). Например, запись mat1.createBox(2,2,Math.PI/4, 100, 100) аналогичная следующей записи:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Параметры

Связанные элементы API

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Создает особый стиль матрицы, ожидаемый методом beginGradientFill() и lineGradientStyle класса Graphics. Ширина и высота масштабируются до пары scaleX/scaleY, а значения tx/ty являются коррекцией с половинными значениями ширины и высоты.

Например, рассмотрим градиент со следующими характеристиками:

• GradientType.LINEAR
• Два цвета (зеленый и синий) с массивом коэффициентов [0, 255]
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

В следующем примере показаны градиенты, в которых матрица была определена с помощью метода createGradientBox() с различными настройками параметров:

Параметры createGradientBox()	Итоговый градиент
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Параметры

Связанные элементы API

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Для точки в пространстве координат до преобразования возвращает ее координаты после преобразования. В отличие от стандартного преобразования, применяемого с помощью метода transformPoint(), в преобразовании методом deltaTransformPoint() не учитываются параметры перемещения tx и ty.

Параметры

Задает каждому свойству матрицы значение, приводящее к нулевому преобразованию. Объект, преобразованный с применением единичной матрицы, идентичен исходному объекту.

После вызова метода identity() в получившейся в результате матрице записаны следующие свойства: a=1, b=0, c=0, d=1, tx=0, ty=0.

В матричном представлении единичная матрица имеет следующий вид:

Выполняет обратное преобразование исходной матрицы. Можно применить обратную матрицу к объекту для отмены преобразования, выполненного при применении исходной матрицы.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Применяет преобразование поворотом к объекту Matrix.

Метод rotate() изменяет свойства a, b, c и d объекта Matrix. В матричном представлении это действие равнозначно сцеплению текущей матрицы со следующими значениями:

Параметры

Применяет преобразование масштабированием к объекту Matrix. Ось x умножается на значение sx, а ось y - на значение sy.

Метод scale() изменяет свойства a и d объекта Matrix. В матричном представлении это действие равнозначно сцеплению текущей матрицы со следующей матрицей:

Параметры

Задает для членов объекта Matrix определенные значения

Параметры

Возвращает текстовое значение, содержащее список свойств объекта Matrix.

Возвращает результат применения геометрического преобразования, представленного объектом Matrix в заданной точке.

Параметры

Перемещает матрицу вдоль осей x и y, как задано параметрами dx и dy.

Параметры

1. В приложении создается новый объект Matrix с именем myMatrix и используется метод trace() для вывода значений свойств по умолчанию для объекта myMatrix.
2. В приложении вызывается метод createGradientBox() с параметрами width и height, равными 200 пикселям, отсутствием вращения и расстоянием для перемещения вдоль осей x и y, равным 50 пикселям.
3. В приложении осуществляется повторная печать объекта myMatrix для отображения изменения после вызова метода createGradientBox().
4. Для управления процессом заливкой градиентного прямоугольника в приложении настраиваются три переменные:
   • colors: задает плавные цветовые переходы - от сплошного красного до сплошного синего.
   • alphas: задает непрозрачность сплошной заливки.
   • ratios: задает распределение цветов, равное для красного и синего цветов.
5. В приложении вызывается графический метод beginGradientFill(), который обрабатывает объект myMatrix и вызывает метод lineTo(), после выполнения которого создается прямоугольник с градиентной заливкой.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}