URLRequestHeader

Пакет	flash.net
Класс	public final class URLRequestHeader
Наследование	URLRequestHeader Object

Язык версии:

ActionScript 3.0

Версии среды выполнения:

AIR 1.0, Flash Player 9, Flash Lite 4

Объект URLRequestHeader инкапсулирует одиночный заголовок запроса HTTP и состоит из имени и значения. Объекты URLRequestHeader используются в свойстве requestHeaders класса URLRequest.

В Adobe^® AIR^® содержимое в изолированной программной среде безопасности приложения (содержимое, установленное с приложением AIR) может использовать любые заголовки запросов, не вызывая ошибки. Однако в случае с содержимым, выполняющимся в Adobe AIR и находящимся в другой изолированной программной среде безопасности, или в случае с содержимым, выполняющимся в проигрывателе Flash^® Player, использование следующих заголовков запросов приводит к ошибке времени выполнения, причем запрещенные термины не зависят от регистра (например, варианты Get, get и GET в равной степени недопустимы):

В содержимом Flash Player и Adobe AIR за пределами изолированной программной среды безопасности приложения нельзя использовать следующие заголовки запросов, причем запрещенные термины не зависят от регистра (например, варианты Get, get и GET в равной степени недопустимы). Вдобавок, написанные через дефис термины применяются, если используется символ подчеркивания (например, Content-Length и Content_Length недопустимы):

Accept-Charset, Accept-Encoding, Accept-Ranges, Age, Allow, Allowed, Authorization, Charge-To, Connect, Connection, Content-Length, Content-Location, Content-Range, Cookie, Date, Delete, ETag, Expect, Get, Head, Host, If-Modified-Since, Keep-Alive, Last-Modified, Location, Max-Forwards, Options, Origin, Post, Proxy-Authenticate, Proxy-Authorization, Proxy-Connection, Public, Put, Range, Referer, Request-Range, Retry-After, Server, TE, Trace, Trailer, Transfer-Encoding, Upgrade, URI, User-Agent, Vary, Via, Warning, WWW-Authenticate, x-flash-version.

Объекты URLRequestHeader имеют ограниченную длину. Если суммарная длина объекта URLRequestHeader (длина свойства name плюс свойства value) или массива объектов URLRequestHeader, использованных в свойстве URLRequest.requestHeaders, превышает допустимую длину, выдается исключение.

Содержимое, выполняющееся в Adobe AIR, задает для заголовка ACCEPT следующее значение, если для заголовка ACCEPT в свойстве requestHeaders класса URLRequest не задано значение:

text/xml, application/xml, application/xhtml+xml, text/html;q=0.9, text/plain;q=0.8, image/png, application/x-shockwave-flash, video/mp4;q=0.9, flv-application/octet-stream;q=0.8, video/x-flv;q=0.7, audio/mp4, */*;q=0.5

Не все методы, принимающие параметры URLRequest, поддерживают свойство requestHeaders. Дополнительные сведения см. в описании вызываемого метода. Например, методы FileReference.upload() и FileReference.download() не поддерживают свойство URLRequest.requestHeaders.

Вследствие ограниченных возможностей обозревателей пользовательские заголовки запросов НТТР поддерживаются только для запросов POST, а для GET не поддерживаются.

Посмотреть примеры

Связанные элементы API

URLRequest
URLLoader

Общедоступные свойства

Скрыть унаследованные общедоступные свойства

Показать унаследованные общедоступные свойства

	Свойство		Определено
		constructor : Object Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.	Object
		name : String Имя заголовка HTTP-запроса (например, Content-Type или SOAPAction).	URLRequestHeader
		value : String Значение, связанное со свойством name (например, text/plain).	URLRequestHeader

Общедоступные методы

Скрыть унаследованные общедоступные методы

Показать унаследованные общедоступные методы

	Метод		Определено
		URLRequestHeader(name:String = "", value:String = "") Создает новый объект URLRequestHeader, инкапсулирующий одиночный заголовок запроса HTTP.	URLRequestHeader
		hasOwnProperty(name:String):Boolean Показывает, определено ли заданное свойство для объекта.	Object
		isPrototypeOf(theClass:Object):Boolean Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.	Object
		propertyIsEnumerable(name:String):Boolean Показывает наличие заданного свойства и его перечисляемость.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Задает доступность динамического свойства для операций цикла.	Object
		toLocaleString():String Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали.	Object
		toString():String Возвращает строковое представление заданного объекта.	Object
		valueOf():Object Возвращает элементарное значение заданного объекта.	Object

Сведения о свойстве

name

свойство

public var name:String

Язык версии:

ActionScript 3.0

Версии среды выполнения:

AIR 1.0, Flash Player 9, Flash Lite 4

Имя заголовка HTTP-запроса (например, Content-Type или SOAPAction).

value

свойство

public var value:String

Язык версии:

ActionScript 3.0

Версии среды выполнения:

AIR 1.0, Flash Player 9, Flash Lite 4

Значение, связанное со свойством name (например, text/plain).

Сведения о конструкторе

()

Конструктор

public function URLRequestHeader(name:String = "", value:String = "")

Язык версии:

ActionScript 3.0

Версии среды выполнения:

AIR 1.0, Flash Player 9, Flash Lite 4

Создает новый объект URLRequestHeader, инкапсулирующий одиночный заголовок запроса HTTP. Объекты URLRequestHeader используются в свойстве requestHeaders класса URLRequest.

Параметры

	`name:String` (default = "") — Имя заголовка HTTP-запроса (например, `Content-Type` или `SOAPAction`).

	`value:String` (default = "") — Значение, связанное со свойством `name` (например, `text/plain`).

Примеры Использование этого примера

URLRequestHeaderExample.as

В следующем примере отдельный заголовок HTTP-запроса header добавляется в массив для свойства requestHeaders. Заголовок указывает, что приложение должно переправить запрос на исходный сервер, даже если оно имеет кэшированную копию запрашиваемого объекта.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.net.URLRequestHeader;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequestHeaderExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestHeaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var header:URLRequestHeader = new URLRequestHeader("pragma", "no-cache");
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/greeting.cfm");
            request.data = new URLVariables("name=John+Doe");
            request.method = URLRequestMethod.POST;
            request.requestHeaders.push(header);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}

Юридическая информация | Политика конфиденциальности онлайн

URLRequestHeader - AS3

Классы x

name

value

URLRequestHeader