URLRequest  - AS3

Указывает, должны обрабатываться запросы с аутентификацией (true) или нет (false). Если задано значение false, при выполнении заданий аутентификации возвращается ошибка HTTP.

Поддерживаются следующие методы аутентификации:

• Windows—HTTP Basic/Digest, встроенная аутентификация Windows (включая NTLM и Kerberos), аутентификация с использованием сертификатов SSL;
• Mac—HTTP Basic/Digest, NTLM, аутентификация с использованием сертификатов SSL.

Примечание. Методы FileReference.upload(), FileReference.download() и HTMLLoader.load() не поддерживают свойство URLRequest.authenticate.

Значением по умолчанию является true.

Связанные элементы API

Указывает, должны ли сохраняться в кэше данные успешного ответа на этот запрос. При значении true приложение AIR использует кэш HTTP операционной системы.

Примечание. Метод HTMLLoader.load() не поддерживает свойство URLRequest.cacheResponse.

Значением по умолчанию является true.

Связанные элементы API

MIME-тип содержимого в свойстве data.

Значение по умолчанию: application/x-www-form-urlencoded.

Примечание. Методы FileReference.upload(), FileReference.download() и HTMLLoader.load() не поддерживают свойство URLRequest.contentType.

При отправке запроса POST значения свойств contentType и data должны быть надлежащим образом согласованы. Значение свойства contentType указывает серверам, как интерпретировать значение свойства data.

• Если значением свойства data является объект URLVariables, значением contentType должно быть application/x-www-form-urlencoded.
• Если свойство data имеет значение любого другого типа, значение contentType должно указывать тип отправляемых данных POST (двоичные или строковые данные, содержащиеся в значении свойства data).
• Для метода FileReference.upload() тип содержимого запроса автоматически получает значение multipart/form-data, при этом значение свойства contentType игнорируется.

В приложении Flash Player 10 и более поздней версии при использовании типа содержимого multipart (например, multipart/form-data), в котором содержится загрузка (обозначена параметром filename в заголовке content-disposition в теле оператора POST), к операции POST применяются правила безопасности для загрузок:

• Операция POST должна быть выполнена в ответ на действие, инициированное пользователем, такое как щелчок мыши или нажатие клавиши.
• Если операция POST является междоменной (назначением операции POST не является сервер, на котором содержится SWF-файл, отправляющий запрос POST), целевой сервер должен предоставить файл политик URL, в котором разрешен междоменный доступ.

Кроме того, все объекты multipart Content-Type должны иметь допустимый синтаксис (в соответствии со стандартами RFC2046). Если синтаксис является недопустимым, к операции POST применяются правила безопасности, действующие для загрузок.

Связанные элементы API

Объект, содержащий данные, которые должны быть переданы с запросом URL-адреса.

Данное свойство используется вместе со свойством method. Когда method имеет значение GET, значение data добавляется к значению URLRequest.url с использованием синтаксиса строки запроса HTTP. Когда method имеет значение POST (или любое другое, кроме GET), значение data передается в теле запроса HTTP.

API-интерфейс URLRequest поддерживает двоичный POST и переменные в кодировке URL-адреса, а также строки. Объект данных может быть следующего типа: ByteArray, URLVariables или String.

Способ применения данных зависит от типа используемого объекта:

• Если объект относится к типу ByteArray, то двоичные данные этого объекта используются в качестве данных POST. Данные типа ByteArray не поддерживаются для метода GET. Вдобавок, данные ByteArray не поддерживаются для FileReference.upload() и FileReference.download().
• Если используется объект URLVariables и метод POST, переменные кодируются с помощью формата x-www-form-urlencoded. Полученная в результате строка используется как данные POST. Исключением является вызов метода FileReference.upload(), в котором переменные отправляются как отдельные поля в формате multipart/form-data.
• При использовании объекта URLVariables и метода GET данный объект URLVariables определяет переменные, которые должны быть отправлены с объектом URLRequest.
• В противном случае, объект преобразуется в строку, которая используется в качестве данных POST или GET.

Эти данные не отправляются до тех пор, пока метод (например, navigateToURL() или FileReference.upload()) не будет использовать объект URLRequest.

Примечание. Значение contentType должно соответствовать типу данных в свойстве data. См. примечание в описании свойства contentType.

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Строка, уникальным образом идентифицирующая подписанный компонент платформы Adobe, который должен быть сохранен (или извлечен) в кэш-памяти проигрывателя Flash Player. Компонент платформы Adobe является подписанным файлом (SWZ-файл) с содержимым SWF, непрерывно кэшированным на компьютере пользователя. Все SWZ-файлы подписаны компанией Adobe. Дайджест соответствует одному кэшированному файлу. При внесении любых изменений в файл его дайджест изменится непредсказуемым образом. С помощью дайджеста можно проверять кэшированный файл по нескольким доменам. Если у двух файлов одинаковый дайджест, это один и тот же файл. Если же у двух файлов разные дайджесты, значит, это не один и тот же файл. Практически невозможно создать файл с фальшивым дайджестом, и выдать его за другой.

Дайджест основан на алгоритме дайджеста сообщения SHA-256 (с длиной 64 в шестнадцатеричном формате).

Например, компонент Flex SDK включает SWZ-файл для среды Flex (и предоставляет строку дайджеста для этого SWZ-файла). Можно опубликовать этот SWZ-файл на web-сервере и загрузить его в SWF-файл (с использованием метода load() объекта URLLoader). Если на компьютере конечного пользователя уже существует соответствующий кэшированный SWZ-файл, в приложении используется кэшированный SWZ-файл. (SWZ-файл соответствует, если его свойство digest соответствует свойству digest, указанному пользователем.) В противном случае в приложении выполняется загрузка SWZ-файла с использованием указанного URL-адреса.

Параметр digest необходимо задать только в объекте URLRequest, используемом в обращении к методу URLLoader.load() для загрузки SWZ-файла. Если свойство digest объекта URLRequest задается при использовании объекта в другом методе, в приложении создается исключение IOError.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Задает, следует выполнять перенаправления (true) или нет (false).

Примечание. Методы FileReference.upload(), FileReference.download() и HTMLLoader.load() не поддерживают свойство URLRequest.followRedirects.

Значением по умолчанию является true.

Связанные элементы API

Указывает время ожидания (в миллисекундах) для этого запроса.

Время ожидания покоя — это количество времени, в течение которого клиент ожидает ответ от сервера после установки подключения до прерывания обработки запроса.

Примечание. Метод HTMLLoader.load() не поддерживает свойство URLRequest.idleTimeout . Класс HTMLLoader определяет свое собственное свойство idleTimeout.

Значением по умолчанию является initialized from the URLRequestDefaults.idleTimeout property.

Связанные элементы API

Определяет, должен ли стек протокола НТТР управлять файлами cookie для данного запроса. При значении true файлы cookie добавляются в запрос и cookie ответа запоминаются. При значении false файлы cookie не добавляются в запрос и cookie ответа не запоминаются, однако пользователи могут самостоятельно управлять cookie путем непосредственных манипуляций с заголовком. Примечание. В Windows файлы cookie не могут быть вручную добавлены в запрос URL, когда для параметра manageCookies установлено значение true. В других операционных системах добавление файлов cookie к запросу разрешено независимо от того, установлено для параметра manageCookies значение true или false. Если это разрешено, файлы cookie можно добавлять в запрос вручную путем добавления объекта URLRequestHeader, содержащего данные cookie в массив requestHeaders.

В системе Mac OS файлы cookie используются совместно с Safari. Чтобы удалить файлы cookie в Mac OS, выполните следующие действия.

1. Откройте Safari.
2. Выберите Safari > Preferences и выберите панель Security.
3. Нажмите кнопку Show Cookies.
4. Нажмите кнопку Remove All.

Чтобы удалить файлы cookie в Windows, выполните следующие действия.

1. Откройте панель управления «Свойства браузера» и перейдите на вкладку «Общие».
2. Нажмите кнопку «Удалить Cookie».

Значением по умолчанию является true.

Связанные элементы API

Управляет методом отправки форм НТТР.

Для SWF-содержимого, выполняемого в Flash Player (в обозревателе), это свойство ограничено операциями GET и POST, поэтому действительными являются значения URLRequestMethod.GET и URLRequestMethod.POST.

Для содержимого, выполняемого в Adobe AIR, можно использовать любое строковое значение, если содержимое находится в изолированной программной среде приложения. Если нет, то можно использовать только операции GET или POST, как и для содержимого во Flash Player.

В случае с содержимым, выполняющимся в Adobe AIR, при использовании функции navigateToURL() среда выполнения воспринимает URLRequest, использующий метод POST (свойство method которого имеет значение URLRequestMethod.POST), как использование метода GET.

Примечание. Если в Flash Player указанная форма не имеет содержимого, проигрыватель автоматически использует операцию GET, даже если для метода установлено значение URLRequestMethod.POST. По этой причине рекомендуется всегда вставлять фиктивное содержимое, тем самым обеспечивая применение нужного метода.

Значением по умолчанию является URLRequestMethod.GET.

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

Массив заголовков запроса HTTP, который должен быть добавлен к запросу HTTP. Массив состоит из объектов URLRequestHeader. Каждый объект в массиве должен быть объектом URLRequestHeader, содержащим строку имени и строку значения, как показано ниже:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Среда выполнения Flash Player и AIR накладывают определенные ограничения за заголовки запросов. Дополнительные сведения см. в описании класса URLRequestHeader.

Не все методы, принимающие параметры URLRequest, поддерживают свойство requestHeaders. Дополнительные сведения см. в описании вызываемого метода. Например, методы FileReference.upload() и FileReference.download() не поддерживают свойство URLRequest.requestHeaders.

Вследствие ограниченных возможностей обозревателей пользовательские заголовки запросов НТТР поддерживаются только для запросов POST, а для GET не поддерживаются.

Связанные элементы API

URL-адрес, к которому будет выполнен запрос.

Обязательно закодируйте все символы, которые описаны как небезопасные в спецификации URL (см. http://www.faqs.org/rfcs/rfc1738.html) или зарезервированы в схеме URL объекта URLRequest (когда они не используются с указанной целью). Например, используйте %25 для символа процентов (%) и %23 для знака (#), как в http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25.

По умолчанию URL-адрес должен находиться в том же домене, что и вызывающий файл, если содержимое не выполняется в изолированной программной среде безопасности приложения Adobe AIR. Если требуется загрузить данные из другого домена, на сервере, на котором находятся данные, необходимо поместить файл политик для URL-адресов. Дополнительные сведения см. в описании класса URLRequest.

В Adobe AIR файлы, находящиеся в изолированной программной среде приложения, то есть установленные вместе с приложением AIR, могут обращаться к URL-адресам с использованием любой из следующих схем URL:

• http и https
• file
• app-storage
• app

Примечание. IPv6 (интернет-протокол версии 6) поддерживается в AIR и Flash Player 9.0.115.0 и более поздних версиях. IPv6 — это версия Интернет-протокола, поддерживающего 128-разрядные адреса (усовершенствование протокола IPv4, поддерживающего только 32-разрядные адреса). Вам может потребоваться активировать IPv6 на используемых интерфейсах сетевых соединений. Дополнительные сведения см. в справочных документах операционной системы, в которой размещены ваши данные. Если система хостинга поддерживает IPv6, можно указать цифровые адреса IPv6 в URL-адресах, заключенные в квадратные скобки ([ ]), как показано ниже.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Указывает, необходимо ли обращаться в локальный кэш перед получением данных этим запросом URLRequest.

Примечание. Метод HTMLLoader.load() не поддерживает свойство URLRequest.useCache.

Значением по умолчанию является true.

Связанные элементы API

Задает строку user-agent для запроса НТТР.

Значением по умолчанию является та же строка user-agent, которая используется Flash Player (она отличается для Mac, Linux и Windows).

Примечание. Это свойство не затрагивает строку user-agent, когда объект URLRequest используется с методом load() объекта HTMLLoader. Чтобы задать строку user-agent для объекта HTMLLoader, настройте свойство userAgent объекта HTMLLoader или статическое свойство URLRequestDefaults.userAgent.

Связанные элементы API

Создает объект URLRequest. Если параметр System.useCodePage имеет значение true, запрос кодируется с помощью не Unicode, а системной кодовой страницы. Если параметр System.useCodePage имеет значение false, запрос кодируется не с использованием системной кодовой страницы, а с помощью Unicode.

Связанные элементы API

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Позволяет заменить перенаправленный URL-адрес из исходного URLRequest на некоторую часть URL-адреса нового URLRequest. После перенаправления первоначального запроса это позволяет отправку последующих запросов непосредственно в местоположение сервера перенаправления.

После выполнения первоначального URL-запроса, если HTTPStatusEvent.redirected имеет значение true, то этот метод можно вызвать с помощью первоначального запроса в виде sourceRequest. По умолчанию домен из перенаправленного URL-адреса будет использоваться вместо домена в URL-адреса данного URLRequest. URLRequest.url необходимо установить до вызова этого метода. Метод необходимо вызвать перед загрузкой этого объекта URLRequest. А если параметр wholeURL имеет значение true, то весь URL-адрес минус имя файла из исходного URLRequest будет заменен на весь URL-адрес минус конечное имя файла в этом URLRequest. Кроме того, отправитель вызова может передать строку или регулярное выражение в параметре pattern. Выполняется поиск шаблона и, если он обнаруживается, его замена строкой из параметра replace. Поиск с заменой происходит после замены URL-адреса.

Параметры

Связанные элементы API

Чтобы запустить данный пример, поместите файл XMLFile.xml в тот каталог, где находится рассматриваемый SWF-файл.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}