WorkerDomain  - AS3

Экземпляр WorkerDomain, в котором в настоящий момент выполняется код. Это единственный экземпляр WorkerDomain в приложении.

Указывает, поддерживает ли текущий контекст выполнения объекты WorkerDomain и Worker для организации параллельного выполнения кода.

Если параллельное выполнение доступно, это свойство имеет значение true.

Создает новый экземпляр Worker из байтового содержимого swf.

Каждый объект worker создается из изолированного приложения SWF и выполняется как изолированное приложение SWF. Для создания экземпляра Worker необходимо получить байтовое содержимое SWF-файла в виде экземпляра ByteArray и передать его в данный метод. Существует три способа получить доступ к байтовому содержимому SWF-файла для этой цели:

• Использовать метатег [Embed] для внедрения SWF-файла в приложение в виде байтового массива (ByteArray):

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Загрузить внешний SWF-файл с помощью загрузчика URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Использовать один SWF-файл и как первоначальный, и как фоновый объект worker:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Создание объекта Worker с помощью метода createWorker() не инициирует его выполнение. Чтобы запустить код объекта Worker на выполнение, вызовите метод start() этого объекта Worker.

Полезный эффект объектов Worker состоит в том, что они снижают вероятность пропуска кадров вследствие блокирования основного потока отрисовки другим кодом. Тем не менее, для объектов Worker требуется дополнительная системная память и ресурсы центрального процессора, что может влиять на итоговую производительность. Поскольку каждый объект Worker использует отдельный экземпляр виртуальной среды исполнения, накладные расходы могут быть велики даже для элементарных объектов worker. При использовании объектов Worker проверяйте работу кода на всех целевых платформах, чтобы убедиться, что нагрузка на систему является приемлемой. Adobe рекомендует не использовать в типовых сценариях более одного или двух фоновых объектов Worker.

Параметры

Предоставляет доступ к набору текущих выполняющихся объектов Worker в домене WorkerDomain (т. е. таких объектов Worker, у которых свойство state имеет значение WorkerState.RUNNING).