ActionScript® 3.0 Referenzhandbuch für die Adobe® Flash®-Plattform
Home  |  Liste der Pakete und Klassen ausblenden |  Pakete  |  Klassen  |  Neue Funktionen  |  Stichwortverzeichnis  |  Anhänge  |  Warum auf Englisch?
Filter: Daten werden vom Server abgerufen...
Daten werden vom Server abgerufen...
flash.media 

CameraRoll  - AS3

Paketflash.media
Klassepublic class CameraRoll
VererbungCameraRoll Inheritance EventDispatcher Inheritance Object

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Die CameraRoll-Klasse ermöglicht Ihnen, auf Bilddaten in der Medienbibliothek oder „Camera Roll“ des Systems zuzugreifen.

Unterstützung von AIR-Profilen: Diese Funktion wird auf mobilen Geräten unterstützt, nicht jedoch auf Desktopbetriebssystemen oder Geräten mit AIR für TV. Weitere Informationen zum API-Support über mehrere Profile finden Sie unter Unterstützung von AIR-Profilen.

Die CameraRoll.addBitmapData()-Methode fügt ein Bild dem dedizierten Medienarchiv des Geräts hinzu. Um zur Laufzeit festzustellen, ob Ihre Anwendung die CameraRoll.addBitmapData()-Methode unterstützt, überprüfen Sie die CameraRoll.supportsAddBitmapData-Eigenschaft.

Die CameraRoll.browseForImage()-Methode öffnet ein Dialogfeld zur Bildauswahl, in dem ein Benutzer ein Bild aus der Medienbibliothek auswählen kann. Wenn der Benutzer ein Bild auswählt, setzt das CameraRoll-Objekt ein select-Ereignis ab. Verwenden Sie das MediaEvent-Objekt, das für dieses Ereignis abgesetzt wird, um auf das ausgewählte Bild zuzugreifen. Um zur Laufzeit festzustellen, ob Ihre Anwendung die CameraRoll.browseForImage()-Methode unterstützt, überprüfen Sie die CameraRoll.supportsBrowseForImage-Eigenschaft.



Öffentliche Eigenschaften
 EigenschaftDefiniert von
 Inheritedconstructor : Object
Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.
Object
      permissionStatus : String
[statisch] [schreibgeschützt] Bestimmen Sie, ob der Anwendung die Berechtigung zum Zugriff auf die Camera Roll erteilt wurde.
CameraRoll
      supportsAddBitmapData : Boolean
[statisch] [schreibgeschützt] Ob die CameraRoll.addBitmapData()-Methode unterstützt wird.
CameraRoll
      supportsBrowseForImage : Boolean
[statisch] [schreibgeschützt] Gibt an, ob die CameraRoll.browseForImage()-Methode unterstützt wird.
CameraRoll
Öffentliche Methoden
 MethodeDefiniert von
  
    CameraRoll()
Erstellt ein CameraRoll-Objekt.
CameraRoll
  
    addBitmapData(bitmapData:BitmapData):void
Fügt ein Bild der Camera Roll des Geräts hinzu.
CameraRoll
 Inherited
addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Registriert ein Ereignis-Listener-Objekt bei einem EventDispatcher-Objekt, sodass der Listener über ein Ereignis benachrichtigt wird.
EventDispatcher
  
Öffnet ein Dialogfeld zur Bildauswahl, in dem der Benutzer ein vorhandenes Bild aus der Camera Roll des Geräts auswählen kann.
CameraRoll
 Inherited
Sendet ein Ereignis in den Ereignisablauf.
EventDispatcher
 Inherited
Überprüft, ob das EventDispatcher-Objekt Listener für einen bestimmten Ereignistyp registriert hat.
EventDispatcher
 Inherited
Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.
Object
 Inherited
Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.
Object
 Inherited
Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.
Object
 Inherited
removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void
Entfernt einen Listener aus dem EventDispatcher-Objekt.
EventDispatcher
  
Fordert die Berechtigung zum Zugriff auf die Medienbibliothek oder „Camera Roll“ des Systems an.
CameraRoll
 Inherited
Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.
Object
 Inherited
Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.
Object
 Inherited
Gibt das angegebene Objekt als String zurück.
Object
 Inherited
Gibt den Grundwert des angegebenen Objekts zurück.
Object
 Inherited
Überprüft, ob bei diesem EventDispatcher-Objekt oder bei einem seiner Vorgänger ein Ereignis-Listener für einen bestimmten Ereignistyp registriert ist.
EventDispatcher
Ereignisse
 Ereignis Übersicht Definiert von
 Inherited[broadcast event] Wird ausgelöst, wenn Flash Player oder eine AIR-Anwendung den Betriebssystemfokus erhält und aktiv wird.EventDispatcher
  
    cancel
Wird abgesetzt, wenn ein Benutzer einen Bildauswahlvorgang abbricht, ohne ein Bild auszuwählen.CameraRoll
  
    complete
Zeigt an, dass ein addBitmapData()-Vorgang erfolgreich abgeschlossen wurde.CameraRoll
 Inherited[broadcast event] Wird ausgelöst, wenn Flash Player- oder die AIR-Anwendung den Fokus verliert und inaktiv wird.EventDispatcher
  
    error
Das error-Ereignis wird abgesetzt, wenn ein Fehler auftritt.CameraRoll
  Wird abgesetzt, wenn die Anwendung die Berechtigung zum Zugriff auf die Camera Roll anfordert.CameraRoll
  
    select
Wird abgesetzt, wenn ein Benutzer ein Bild aus der Medienbibliothek des Geräts auswählt.CameraRoll
Eigenschaftendetails
    

permissionStatus

Eigenschaft
permissionStatus:String  [schreibgeschützt]

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 24.0

Bestimmen Sie, ob der Anwendung die Berechtigung zum Zugriff auf die Camera Roll erteilt wurde.



Implementierung
    public static function get permissionStatus():String

Verwandte API-Elemente

    

supportsAddBitmapData

Eigenschaft 
supportsAddBitmapData:Boolean  [schreibgeschützt]

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Ob die CameraRoll.addBitmapData()-Methode unterstützt wird. Zurzeit wird diese Funktion nur in AIR-Anwendungen auf mobilen Geräten unterstützt.



Implementierung
    public static function get supportsAddBitmapData():Boolean
    

supportsBrowseForImage

Eigenschaft 
supportsBrowseForImage:Boolean  [schreibgeschützt]

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2.5

Gibt an, ob die CameraRoll.browseForImage()-Methode unterstützt wird. Zurzeit wird diese Funktion nur in AIR-Anwendungen auf mobilen Geräten unterstützt.



Implementierung
    public static function get supportsBrowseForImage():Boolean
Konstruktordetails
    

CameraRoll

()Konstruktor
public function CameraRoll()

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Erstellt ein CameraRoll-Objekt.

Von ActionScript wird nur eine Medienbibliothek unterstützt. Alle CameraRoll-Objekte speichern in demselben Bildrepository.

Methodendetails

    addBitmapData

()Methode
public function addBitmapData(bitmapData:BitmapData):void

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Fügt ein Bild der Camera Roll des Geräts hinzu.

Um zur Laufzeit festzustellen, ob Ihre Anwendung die CameraRoll.addBitmapData()-Methode unterstützt, überprüfen Sie die CameraRoll.supportsAddBitmapData-Eigenschaft.

Parameter

bitmapData:BitmapData — ein BitmapData-Objekt, das das Bild enthält, das an die Camera Roll gesendet werden soll.


Auslöser
PermissionError — Die Anwendung verfügt nicht über die Berechtigung zur Verwendung der Kamera.

    browseForImage

()Methode 
public function browseForImage(value:CameraRollBrowseOptions = null):void

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2.5

Öffnet ein Dialogfeld zur Bildauswahl, in dem der Benutzer ein vorhandenes Bild aus der Camera Roll des Geräts auswählen kann.

Wenn der Benutzer ein Bild auswählt, setzt diese CameraRoll-Instanz ein select-Ereignis ab, das ein MediaEvent-Objekt enthält. Mit der data-Eigenschaft des MediaEvent-Objekts können Sie das Bild laden. Die data-Eigenschaft ist ein MediaPromise-Objekt, das Sie mit der loadFilePromise()-Methode der Loader-Klasse laden können. Beachten Sie, dass das MediaPromise-Objekt auf einigen Plattformen (Blackberry Tablet OS) ein gültiges Dateiobjekt enthält, auf anderen (iOS und Android) dagegen nicht. Wenn Sie die loadFilePromise()-Methode verwenden, wird das Bild auf allen Plattformen richtig geladen. Um auf die Grunddaten des Medienobjekts zuzugreifen, können Sie die von der Medienzusage bereitgestellte Datenquelle öffnen und die Daten mit den Methoden der IDataInput-Schnittstelle lesen.

Um zur Laufzeit festzustellen, ob Ihre Anwendung die CameraRoll.browseForImage()-Methode unterstützt, überprüfen Sie die CameraRoll.supportsBrowseForImage-Eigenschaft.

Unter iOS (nur auf dem iPad) können Sie eine bestimmte Größe für das Dialogfeld zur Bildauswahl anfordern. Sie können auch einen Bildschirmbereich angeben, der nicht vom Dialogfeld für die Bildauswahl verdeckt werden soll. Diese Anforderung funktioniert nur auf dem iPad, da das Dialogfeld für die Bildauswahl auf diesem Gerät nicht den gesamten Bildschirm ausfüllt.

Um Größen- und Platzierungsoptionen für das Dialogfeld für die Bildauswahl anzufordern (auf dem iPad), übergeben Sie ein CameraRollBrowseOptions-Objekt an browseForImage(). Ohne Parameter positioniert diese Methode das Dialogfeld in der oberen linken Ecke des Bildschirms und verwendet die Standardeinstellungen des Systems für die Größe des Dialogfelds.

Parameter

value:CameraRollBrowseOptions (default = null) — Ein CameraRollBrowseOptions-Objekt, mit dem Sie Optionen für die Anzeige der Camera Roll des Geräts festlegen. Dieser Parameter ist optional.


Ereignisse
select:MediaEvent — Wird abgesetzt, wenn der Benutzer ein Bild auswählt.
 
cancel:Event — Wird abgesetzt, wenn der Benutzer den Bildauswahlvorgang abbricht.
 
error:ErrorEvent — Wird abgesetzt, wenn die standardmäßige Bildauswahlanwendung bereits verwendet wird.
 
error:ErrorEvent — Wird abgesetzt, wenn sich die AIR-Anwendung beim Aufrufen dieser Funktion im Hintergrund befindet.

Auslöser
PermissionError — Die Anwendung verfügt nicht über die Berechtigung zur Verwendung der Kamera.

Weitere Informationen

Verwandte API-Elemente


Beispiel  ( Verwendung dieses Beispiels )

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

    requestPermission

()Methode 
public function requestPermission():void

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 24.0

Fordert die Berechtigung zum Zugriff auf die Medienbibliothek oder „Camera Roll“ des Systems an.


Ereignisse
PermissionStatus:PermissionEvent — wird abgesetzt, wenn die angeforderte Berechtigung vom Benutzer gewährt/abgelehnt wird.
Ereignisdetails
    

cancel

Ereignis
Ereignisobjekttyp: flash.events.Event
Eigenschaft Event.type = flash.events.Event.CANCEL

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2.5

Wird abgesetzt, wenn ein Benutzer einen Bildauswahlvorgang abbricht, ohne ein Bild auszuwählen.

Die Event.CANCEL-Konstante definiert den Wert der type-Eigenschaft eines cancel-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

EigenschaftWert
bubblesfalse
cancelablefalse. Es gibt kein Standardverhalten, das abgebrochen werden kann.
currentTargetDas Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
targetEin Verweis auf das Objekt, dessen Operation abgebrochen wurde.
    

complete

Ereignis  
Ereignisobjekttyp: flash.events.Event
Eigenschaft Event.type = flash.events.Event.COMPLETE

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Zeigt an, dass ein addBitmapData()-Vorgang erfolgreich abgeschlossen wurde.

Die Event.COMPLETE-Konstante definiert den Wert der type-Eigenschaft eines complete-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

EigenschaftWert
bubblesfalse
cancelablefalse. Es gibt kein Standardverhalten, das abgebrochen werden kann.
currentTargetDas Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
targetDas Netzwerkobjekt, dessen Ladevorgang beendet ist.
    

error

Ereignis  
Ereignisobjekttyp: flash.events.ErrorEvent
Eigenschaft ErrorEvent.type = flash.events.ErrorEvent.ERROR

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2

Das error-Ereignis wird abgesetzt, wenn ein Fehler auftritt.

Mögliche Fehlerquellen:

  • Es kann kein Bildauswahldialog geöffnet werden.
  • Es wird bereits ein Bildauswahldialogfeld verwendet.
  • Die AIR-Anwendung versucht, nach einem Bild zu suchen, während sie sich im Hintergrund befindet.
  • Ein Bild lässt sich nicht der Medienbibliothek hinzufügen.
  • Es wird eine Methode aufgerufen, die vom Gerät nicht unterstützt wird.
  • Die AIR-Anwendung versucht, ein Fernbild ohne Internetverbindung zu laden.

Definiert den Wert der Eigenschaft type eines error-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

EigenschaftWert
bubblesfalse
cancelablefalse. Es gibt kein Standardverhalten, das abgebrochen werden kann.
currentTargetDas Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
targetDas Objekt, bei dem der Netzwerkvorgang fehlschlägt.
textDer als Fehlermeldung anzuzeigende Text.
    

permissionStatus

Ereignis  
Ereignisobjekttyp: flash.events.PermissionEvent
Eigenschaft PermissionEvent.type = flash.events.PermissionEvent.PERMISSION_STATUS

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 24.0

Wird abgesetzt, wenn die Anwendung die Berechtigung zum Zugriff auf die Camera Roll anfordert. Überprüfen Sie den Wert der Eigenschaft Status, um festzustellen, ob die Berechtigung gewährt oder verweigert wurde.

Verwandte API-Elemente

    

select

Ereignis  
Ereignisobjekttyp: flash.events.MediaEvent
Eigenschaft MediaEvent.type = flash.events.MediaEvent.SELECT

Sprachversion: ActionScript 3.0
Laufzeitversionen: AIR 2.5

Wird abgesetzt, wenn ein Benutzer ein Bild aus der Medienbibliothek des Geräts auswählt.

Das MediaEvent-Objekt, das für dieses Ereignis abgesetzt wird, ermöglicht den Zugriff auf das ausgewählten Medium.

Eine Konstante für das select-MediaEvent.

Definiert den Wert der type-Eigenschaft eines MediaEvent-Ereignisobjekts. Dieses Ereignis verfügt über die folgenden Eigenschaften:

EigenschaftWert
bubblesfalse
cancelablefalse. Es gibt kein Standardverhalten, das abgebrochen werden kann.
currentTargetDas Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
dataDas MediaPromise-Objekt der verfügbaren Medieninstanz.




[ X ]Warum auf Englisch?
Inhalt des ActionScript 3.0-Referenzhandbuchs wird in englischer Sprache angezeigt

Nicht alle Teile des ActionScript 3.0-Referenzhandbuchs wurden in alle Sprachen übersetzt. Wenn der Text zu einem Sprachelement nicht übersetzt wurde, wird er auf Englisch angezeigt. Zum Beispiel wurden die Informationen zur ga.controls.HelpBox-Klasse nicht in andere Sprachen übersetzt. In der deutschen Version des Referenzhandbuchs erscheint der Abschnitt zur ga.controls.HelpBox-Klasse deshalb auf Englisch.