DNSResolver

Paket	flash.net.dns
Klasse	public class DNSResolver
Vererbung	DNSResolver EventDispatcher Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Mit der DNSResolver-Klasse können Sie DNS-Ressourcen-Datensätze nachschlagen.

Unterstützung von AIR-Profilen: Diese Funktion wird auf allen Desktopbetriebssystemen unterstützt, jedoch nicht auf mobilen Geräten. Auf Geräten mit AIR für TV wird sie teilweise unterstützt. Mit der DNSResolver.isSupported-Eigenschaft können Sie testen, ob zur Laufzeit Unterstützung gegeben ist. Weitere Informationen zum AIR-Support über mehrere Profile finden Sie unter Unterstützung von AIR-Profilen.

Sie können die folgenden Typen von Ressourcendatensätzen nachschlagen:

ARecord: IPv4-Adresse für einen Host.
AAAARecord: IPv6-Adresse für einen Host.
MXRecord: Mail-Exchange-Datensatz für einen Host.
PTRRecord: Hostname für eine IP-Adresse.
SRVRecord: Servicedatensatz für einen Service

In der folgende Tabelle ist die DNS-Lookup-Unterstützung auf Geräten mit AIR für TV aufgeführt. Nicht unterstützte Anfragen führen dazu, dass das DNSResolver-Objekt ein flash.events.ErrorEvent-Objekt absetzt.

Datensatztyp, der in `DNSResolver.lookup()` angegeben ist	Unterstützung
ARecord	Volle Unterstützung
AAAARecord	Volle Unterstützung
MXRecord	Nicht unterstützt
PTRRecord	Unterstützung nur für IPv4-Adressen, nicht für IPv6-Adressen
SRVRecord	Nicht unterstützt

Beispiele anzeigen

Verwandte API-Elemente

ARecord
AAAARecord
MXRecord
PTRRecord
SRVRecord

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		isSupported : Boolean [statisch] [schreibgeschützt] Gibt an, ob das Clientsystem DNS-Nachschlageoperationen unterstützt.	DNSResolver

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		DNSResolver() Erstellt ein DNSResolver-Objekt.	DNSResolver
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registriert ein Ereignis-Listener-Objekt bei einem EventDispatcher-Objekt, sodass der Listener über ein Ereignis benachrichtigt wird.	EventDispatcher
		dispatchEvent(event:Event):Boolean Sendet ein Ereignis in den Ereignisablauf.	EventDispatcher
		hasEventListener(type:String):Boolean Überprüft, ob das EventDispatcher-Objekt Listener für einen bestimmten Ereignistyp registriert hat.	EventDispatcher
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		lookup(host:String, recordType:Class):void Schlägt einen DNS-Ressourcendatensatz basierend auf einem Abfragestring nach.	DNSResolver
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Entfernt einen Listener aus dem EventDispatcher-Objekt.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object
		willTrigger(type:String):Boolean Überprüft, ob bei diesem EventDispatcher-Objekt oder bei einem seiner Vorgänger ein Ereignis-Listener für einen bestimmten Ereignistyp registriert ist.	EventDispatcher

Ereignisse

Klicken Sie, um weitere Informationen zu Ereignissen zu erhalten.

Vererbte Ereignisse ausblenden

Vererbte Ereignisse anzeigen

	Übersicht	Definiert von
activate	[broadcast event] Wird ausgelöst, wenn Flash Player oder eine AIR-Anwendung den Betriebssystemfokus erhält und aktiv wird.	EventDispatcher
deactivate	[broadcast event] Wird ausgelöst, wenn Flash Player- oder die AIR-Anwendung den Fokus verliert und inaktiv wird.	EventDispatcher
error	Wird abgesetzt, wenn beim DNS-Nachschlagen ein Fehler aufgetreten ist.	DNSResolver
lookup	Wird abgesetzt, wenn ein DNS-Nachschlagevorgang abgeschlossen ist.	DNSResolver

Eigenschaftendetails

isSupported

Eigenschaft

isSupported:Boolean [schreibgeschützt]

Laufzeitversionen:

AIR 2

Gibt an, ob das Clientsystem DNS-Nachschlageoperationen unterstützt.

Implementierung
public static function get isSupported():Boolean

Konstruktordetails

()

Konstruktor

public function DNSResolver()

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Erstellt ein DNSResolver-Objekt.

Methodendetails

lookup

()

Methode

public function lookup(host:String, recordType:Class):void

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Schlägt einen DNS-Ressourcendatensatz basierend auf einem Abfragestring nach.

Die lookup()-Methode führt einen DNS-Nachschlagevorgang asynchron aus. Verwenden Sie einen Listener für das lookup-Ereignis, um die Ergebnisse des Nachschlagevorgangs zu erhalten. Verwenden Sie einen Listener für das error-Ereignis, um Fehler zu erhalten. Ergebnisse werden in einem DNSResolverEvent-Objekt abgesetzt.

Um den Typ des nachzuschlagenden Ressourcendatensatzes anzugeben, übergeben Sie die entsprechende Klasse im recordType-Parameter. (Übergeben Sie den Klassennamen selbst und nicht einen String, der den Klassennamen enthält.)

Der Inhalt des Abfragestrings, der an die Methode übergeben wird, ist vom Typ des Ressourcendatensatzes abhängig, der nachgeschlagen wird. Die folgende Liste zeigt den Abfragestring, der für die einzelnen Datensatztypen zu verwenden ist.

Datensatztyp	Abfragestring	Beispiel
ARecord	Hostname	"example.com"
AAAARecord	Hostname	"example.com"
MXRecord	Hostname	"example.com"
PTRRecord	IP-Adresse	"208.77.188.166"
SRVRecord	_service._protocol.host.	"_sip._tcp.example.com."

Parameter

	`host:String` — der Abfragestring, zum Beispiel ein Hostname, eine IP-Adresse oder ein Servicelocator.

	`recordType:Class` — Die Klasse, die den Typ des DNS-Ressourcendatensatzes angibt, der nachgeschlagen werden soll.

Ereignisse

	`lookup:DNSResolverEvent` — wird abgesetzt, wenn der Nachschlagevorgang erfolgreich abgeschlossen wurde.

	`error:ErrorEvent` — wird abgesetzt, wenn der Nachschlagevorgang fehlschlägt (auch, wenn kein Datensatz vorhanden ist).

Auslöser

ArgumentError — Der host-Parameterwert ist kein geeigneter Abfragestring oder die recordType-Klasse wird nicht erkannt.

Verwandte API-Elemente

DNSResolverEvent

Ereignisdetails

error

Ereignis

Ereignisobjekttyp: flash.events.ErrorEvent
Eigenschaft ErrorEvent.type = flash.events.ErrorEvent.ERROR

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Wird abgesetzt, wenn beim DNS-Nachschlagen ein Fehler aufgetreten ist.

Definiert den Wert der Eigenschaft type eines error-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt, bei dem der Netzwerkvorgang fehlschlägt.
`text`	Der als Fehlermeldung anzuzeigende Text.

lookup

Ereignis

Ereignisobjekttyp: flash.events.DNSResolverEvent
Eigenschaft DNSResolverEvent.type = flash.events.DNSResolverEvent.LOOKUP

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Wird abgesetzt, wenn ein DNS-Nachschlagevorgang abgeschlossen ist.

Definiert den Wert der type-Eigenschaft eines lookup-Ereignisobjekts.

Beispiele Verwendung dieses Beispiels

DNSResolverExample.as

Das folgende Beispiel zeigt, wie die unterstützten DNS-Datensatztypen nachgeschlagen werden:

package
{
    import flash.desktop.NativeApplication;
    import flash.display.Sprite;
    import flash.events.DNSResolverEvent;
    import flash.events.ErrorEvent;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.dns.AAAARecord;
    import flash.net.dns.ARecord;
    import flash.net.dns.DNSResolver;
    import flash.net.dns.MXRecord;
    import flash.net.dns.PTRRecord;
    import flash.net.dns.SRVRecord;
    import flash.utils.getQualifiedClassName;
    
    public class DNSResolverExample extends Sprite
    {
        private var resolver:DNSResolver = new DNSResolver();
        
        public function DNSResolverExample()
        {
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete );
            resolver.addEventListener( ErrorEvent.ERROR, lookupError );
            
            //Look up records
            resolver.lookup( "www.example.com", ARecord );
            resolver.lookup( "example.com", AAAARecord );
            resolver.lookup( "example.com", MXRecord );
            resolver.lookup( "208.77.188.166", PTRRecord );
            resolver.lookup( "127.0.0.1", PTRRecord );
            resolver.lookup( "2001:1890:110b:1e19:f06b:72db:7026:3d7a", PTRRecord );
            resolver.lookup( "_sip._tcp.example.com.", SRVRecord );
            resolver.lookup( "www.example.com", ARecord );
            
            this.stage.nativeWindow.activate();
        }
        
        private function lookupComplete( event:DNSResolverEvent ):void
        {
            trace( "Query string: " + event.host );
            trace( "Record type: " +  flash.utils.getQualifiedClassName( event.resourceRecords[0] ) + 
                ", count: " + event.resourceRecords.length );
            for each( var record in event.resourceRecords )
            {
                if( record is ARecord ) trace( record.name + " : " + record.address );
                if( record is AAAARecord ) trace( record.name + " : " + record.address );
                if( record is MXRecord ) trace( record.name + " : " + record.exchange + ", " + record.preference );
                if( record is PTRRecord ) trace( record.name + " : " + record.ptrdName );
                if( record is SRVRecord ) trace( record.name + " : " + record.target + ", " + record.port +
                    ", " + record.priority + ", " + record.weight );
            }            
        }
        
        private function lookupError( error:ErrorEvent ):void
        {
            trace("Error: " + error.text );
        }
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

DNSResolver - AS3

Klassen x

isSupported

DNSResolver

lookup

error

lookup