ActionScript® 3.0 Referenzhandbuch für die Adobe® Flash®-Plattform
Home  |  Liste der Pakete und Klassen ausblenden |  Pakete  |  Klassen  |  Neue Funktionen  |  Stichwortverzeichnis  |  Anhänge  |  Warum auf Englisch?
Filter: Daten werden vom Server abgerufen...
Daten werden vom Server abgerufen...
flash.text.engine 

FontDescription  - AS3

Paketflash.text.engine
Klassepublic final class FontDescription
VererbungFontDescription Inheritance Object

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Die FontDescription-Klasse repräsentiert Informationen, mit denen eine Schriftart beschrieben wird.

Ein FontDescription-Objekt wird auf ein ElementFormat angewendet, was wiederum auf ein ContentElement in einem TextBlock angewendet wird. Nachdem ein FontDescription-Objekt auf ein ElementFormat angewendet wurde, wird seine lockedEigenschaft auf true eingestellt. Die Eigenschaften eines gesperrten FontDescription-Objekts können nicht geändert werden. Sie stattdessen mit der clone()-Methode eine nicht gesperrte Kopie des Objekts, die geändert und dem ElementFormat zugewiesen werden kann.

Hinweis: FTE (Flash Text Engine) unterstützt weder Type-1-Schriften noch Bitmapschriften wie Type 3, ATC, sfnt-wrapped CID oder Naked CID.

Beispiele anzeigen

Verwandte API-Elemente



Öffentliche Eigenschaften
 EigenschaftDefiniert von
  cffHinting : String
Die für diesen Text verwendete Art der CFF-Hinweise.
FontDescription
 Inheritedconstructor : Object
Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.
Object
  fontLookup : String
Gibt an, wie nach der Schriftart gesucht werden soll.
FontDescription
  fontName : String
Der Name der zu verwendenden Schriftart oder eine durch Kommas getrennte Liste mit Schriftartennamen.
FontDescription
  fontPosture : String
Gibt den Schriftschnitt an.
FontDescription
  fontWeight : String
Gibt die Schriftstärke an.
FontDescription
  locked : Boolean
Gibt an, ob FontDescription gesperrt ist.
FontDescription
  renderingMode : String
Der für diesen Text verwendete Wiedergabemodus.
FontDescription
Öffentliche Methoden
 MethodeDefiniert von
  
FontDescription(fontName:String = "_serif", fontWeight:String = "normal", fontPosture:String = "normal", fontLookup:String = "device", renderingMode:String = "cff", cffHinting:String = "horizontalStem")
Erstellt ein FontDescription-Objekt.
FontDescription
  
Erstellt eine nicht gesperrte geklonte Kopie von FontDescription.
FontDescription
 Inherited
Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.
Object
  
isDeviceFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean
[statisch] Gibt „true“ zurück, wenn eine verwendbare Geräteschriftart mit den angegebenen Werten für fontName, fontWeight und fontPosture verfügbar ist.
FontDescription
  
isFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean
[statisch] Gibt „true“ zurück, wenn eine eingebettete Schriftart mit dem angegebenen fontName, fontWeight und fontPosture verfügbar ist, wobei Font.fontType flash.text.FontType.EMBEDDED_CFF ist.
FontDescription
 Inherited
Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.
Object
 Inherited
Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.
Object
 Inherited
Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.
Object
 Inherited
Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.
Object
 Inherited
Gibt das angegebene Objekt als String zurück.
Object
 Inherited
Gibt den Grundwert des angegebenen Objekts zurück.
Object
Eigenschaftendetails

cffHinting

Eigenschaft
cffHinting:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Die für diesen Text verwendete Art des CFF-Hintings. Verwenden Sie CFFHinting-Konstanten für diese Eigenschaft. Diese Eigenschaft gilt nur dann, wenn die Eigenschaft RenderingMode des Texts auf RenderingMode.CFF gesetzt ist.

Der Typ der verwendeten CFF-Hinweise (Compact Font Format) bestimmt, ob die Flash-Laufzeitumgebung breite horizontale Striche in ein Subpixelraster einpasst oder nicht.

Gilt nur für eingebettete Schriftarten.

Der Standardwert ist CFFHinting.HORIZONTAL_STEM.

Für die CFFHinting-Eigenschaft können Sie die folgenden Konstanten aus der CFFHinting-Klasse verwenden:

StringwertBeschreibung
CFFHinting.NONEGibt an, dass kein CFF-Hinting erfolgt. Horizontale Striche in den Glyphen werden nicht am Subpixelraster ausgerichtet. Diese Einstellung eignet sich für Animationen oder für große Schriften.
CFFHinting.HORIZONTAL_STEMGibt an, dass CFF-Hinting erfolgt. Breite horizontale Striche werden am Subpixelraster auf dem Bildschirm ausgerichtet. Zur Verwendung dieser Einstellung muss die RenderingMode-Eigenschaft auf RenderingMode.CFF gesetzt sein.



Implementierung
    public function get cffHinting():String
    public function set cffHinting(value:String):void

Auslöser
ArgumentError — Falls ein Wert verwendet wird, der kein Mitglied von CFFHinting ist.
 
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

fontLookup

Eigenschaft 
fontLookup:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Gibt an, wie nach der Schriftart gesucht werden soll.

Der Standardwert lautet FontLookup.DEVICE.

Wenn Sie Werte für diese Eigenschaft definieren möchten, verwenden Sie die folgenden Stringwerte:

StringwertBeschreibung
FontLookup.DEVICEDie Laufzeitumgebung sucht nach einer Geräteschriftart mit dem angegebenen name auf dem lokalen System, mit der der Text wiedergegeben wird.
FontLookup.EMBEDDED_CFFDie Laufzeitumgebung sucht nach einer eingebetteten CFF-Schriftart mit dem angegebenen name, mit der der Text wiedergegeben wird. Nur Schriftarten des Typs flash.text.Font.fontType.EMBEDDED_CFF werden in Betracht gezogen. Wenn die angegebene CFF-Schriftart nicht in die Anwendung eingebettet ist, versucht die Laufzeitumgebung, für jede Glyphe eine Ersatzgeräteschriftart zu verwenden. Diese Methode ist weniger effizient als die Auswahl einer Geräteschriftart von Anfang an.



Implementierung
    public function get fontLookup():String
    public function set fontLookup(value:String):void

Auslöser
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

fontName

Eigenschaft 
fontName:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5

Der Name der zu verwendenden Schriftart oder eine durch Kommas getrennte Liste mit Schriftartnamen. Die Laufzeitumgebung gibt das Element mit der ersten verfügbaren Schriftart in der Liste wieder. Beispiel: Arial, Helvetica, _sans hat zur Folge, dass der Player nach Arial und dann nach Helvetica sucht, wenn Arial nicht gefunden wurde, anschließend nach _sans, wenn keine der beiden gefunden wurde.

Flash-Laufzeitumgebungen unterstützen drei allgemeine Geräteschriftartnamen: _sans (für Schriftarten ohne Serifen), _serif (für Serifenschriftarten) und _typewriter (für nichtproportionale Schriftarten). Diese werden je nach Plattform spezifischen Geräteschriftarten zugeordnet.

Der Standardwert ist "_serif".

Flash-Laufzeitumgebungen bieten Ersatzschriftarten für Glyphen, die in der ausgewählten Schriftart nicht zu finden sind. Unabhängig davon, ob eine eingebettete Schriftart oder eine Geräteschriftart verwendet wird, versucht die Laufzeitumgebung, die Glyphe mit einer ähnlichen Schriftart wiederzugeben, wenn diese nicht in der vorgesehenen Schriftart zu finden ist.



Implementierung
    public function get fontName():String
    public function set fontName(value:String):void

Auslöser
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

fontPosture

Eigenschaft 
fontPosture:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Gibt den Schriftschnitt an.

Der Standardwert lautet FontPosture.NORMAL.

Um Werte für diese Eigenschaft festzulegen, verwenden Sie die folgenden Konstanten der FontPosture-Klasse:

WertBeschreibung
FontPosture.NORMALNormaler Schriftschnitt.
FontPosture.ITALICKursiver Schriftschnitt.



Implementierung
    public function get fontPosture():String
    public function set fontPosture(value:String):void

Auslöser
ArgumentError — Falls ein Wert verwendet wird, der kein Mitglied von FontPosture ist.
 
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

fontWeight

Eigenschaft 
fontWeight:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Gibt die Schriftstärke an.

Der Standardwert lautet FontWeight.NORMAL.

Um Werte für diese Eigenschaft festzulegen, verwenden Sie die folgenden Konstanten der FontWeight-Klasse:

StringwertBeschreibung
FontWeight.NORMALNormale Schriftstärke.
FontWeight.BOLDFettformatierte Schriftstärke.



Implementierung
    public function get fontWeight():String
    public function set fontWeight(value:String):void

Auslöser
ArgumentError — Falls ein Wert verwendet wird, der kein Mitglied von FontWeight ist.
 
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

locked

Eigenschaft 
locked:Boolean

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5., Flash Lite 4

Gibt an, ob FontDescription gesperrt ist. Falls der Wert true lautet, kann FontDescription nicht geändert werden. Rufen Sie FontDescription.clone() auf, um eine nicht gesperrte Kopie des FontDescription-Objekts zu erstellen.



Implementierung
    public function get locked():Boolean
    public function set locked(value:Boolean):void

Auslöser
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

renderingMode

Eigenschaft 
renderingMode:String

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Der für diesen Text verwendete Wiedergabemodus. Verwenden Sie RenderingMode-Konstanten für diese Eigenschaft.

Gilt nur für eingebettete Schriftarten.

Der Standardwert lautet RenderingMode.CFF.

Um Werte für diese Eigenschaft festzulegen, verwenden Sie die folgenden Konstanten der RenderingMode-Klasse:

StringwertBeschreibung
RenderingMode.NORMALWendet das normale Text-Rendering an, das der in Flash Player 7 und früheren Versionen verwendeten Rendering-Art entspricht.
RenderingMode.CFFWendet die CFF-Darstellung (Compact Font Format) an, wodurch der Text besser lesbar wird. (Diese Funktion ist seit Flash Player 10 verfügbar.) Beim CFF-Rendering werden kleine Schriftarten in hoher Qualität wiedergegeben.



Implementierung
    public function get renderingMode():String
    public function set renderingMode(value:String):void

Auslöser
ArgumentError — Falls ein Wert verwendet wird, der kein Mitglied von RenderingMode ist.
 
IllegalOperationError — Falls die Einstellung erfolgt, nachdem das FontDescription-Objekt gesperrt wurde, hat locked den Wert true.

Verwandte API-Elemente

Konstruktordetails

FontDescription

()Konstruktor
public function FontDescription(fontName:String = "_serif", fontWeight:String = "normal", fontPosture:String = "normal", fontLookup:String = "device", renderingMode:String = "cff", cffHinting:String = "horizontalStem")

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Erstellt ein FontDescription-Objekt.

Parameter
fontName:String (default = "_serif") — Der Name der zu verwendenden Schriftart oder eine durch Kommas getrennte Liste mit Schriftartennamen.
 
fontWeight:String (default = "normal") — Gibt die Schriftstärke an.
 
fontPosture:String (default = "normal") — Gibt den Schriftschnitt an.
 
fontLookup:String (default = "device") — Gibt an, wie nach der Schriftart gesucht werden soll.
 
renderingMode:String (default = "cff") — Der für diesen Text verwendete Wiedergabemodus. Verwenden Sie RenderingMode-Konstanten für diese Eigenschaft.
 
cffHinting:String (default = "horizontalStem") — Die für diesen Text verwendeten CFF-Hinweise (Compact Font Format). Verwenden Sie CFFHinting-Konstanten für diese Eigenschaft.

Auslöser
ArgumentError — Das angegebene fontWeight ist kein Mitglied von FontWeight.
 
ArgumentError — Die angegebene fontPosture ist kein Mitglied von FontPosture.
 
ArgumentError — Das angegebene fontLookup ist kein Mitglied von FontLookup.
 
ArgumentError — Der angegebene renderingMode ist kein Mitglied von RenderingMode.
 
ArgumentError — Das angegebene cffHinting ist kein Mitglied von CFFHinting.
Methodendetails

clone

()Methode
public function clone():FontDescription

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Erstellt eine nicht gesperrte geklonte Kopie von FontDescription.

Rückgabewerte
FontDescription — Eine nicht gesperrte Kopie des FontDescription-Objekts.

Beispiel  ( Verwendung dieses Beispiels )

In diesem Beispiel wird ein FontDescriptionObjekt erstellt, diesem Objekt wird eine Geräteschriftart zugewiesen, es werden verschiedene Schrifteigenschaften festgelegt und das neue Objekt wird einem ElementFormat-Objekt zugewiesen (wodurch es gesperrt wird). Ein neues TextElement wird mithilfe von ElementFormat erstellt und das TextElement wird als Inhalt für einen TextBlock verwendet. Im TextBlock wird eine Textzeile erstellt.

Bevor Sie einFontDescription-Objekt ändern, müssen Sie zuerst dessen locked-Eigenschaft überprüfen. Wenn dieser Wert „true“ lautet, erstellen Sie mithilfe der clone()-Methode eine nicht gesperrte Kopie des FontDescription-Objekts, ändern Sie seine Eigenschaften und weisen Sie es einem neuen ElementFormat-Objekt zu. Wenden Sie anschließend das neue ElementFormat auf den TextBlock an. Wenn die Zeilen neu umbrochen werden, weisen die neuen Zeilen die neuen Schrifteinstellungen auf.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescription_cloneExample extends Sprite {
        private var fd:FontDescription;
        private var fd2:FontDescription;
        
        public function FontDescription_cloneExample():void {
            fd = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            fd2 = (fd.locked) ? fd.clone() : fd;    
            fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
            var ef2:ElementFormat = new ElementFormat(fd2);

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

isDeviceFontCompatible

()Methode 
public static function isDeviceFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10.1, AIR 2

Gibt „true“ zurück, wenn eine verwendbare Geräteschriftart mit den angegebenen Werten für fontName, fontWeight und fontPostureverfügbar ist.

Die flash.text.engine-Klassen können nur OpenType- und TrueType-Geräteschriftarten verwenden. Wenn eine Schriftart verwendet wird, die auf einer älteren Schriftarttechnik basiert, verwendet die Laufzeitumgebung bekannte, gut funktionierende Geräteschriftarten auf einer Glyphe-für-Glyphe-Basis, um den Text darzustellen.

Parameter

fontName:String — Der Name der zu überprüfenden Geräteschriftart.
 
fontWeight:String — Gibt die Schriftstärke an. Verwenden Sie FontWeight.
 
fontPosture:String — Gibt den Schriftschnitt an. Verwenden Sie FontPosture.

Rückgabewerte
Booleantrue, wenn eine kompatible Gerätschriftart verfügbar ist, andernfalls false.

Auslöser
ArgumentError — Das angegebene fontWeight ist kein Mitglied von FontWeight.
 
ArgumentError — Die angegebene fontPosture ist kein Mitglied von FontPosture.

Verwandte API-Elemente

isFontCompatible

()Methode 
public static function isFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean

Sprachversion: ActionScript 3.0
Laufzeitversionen: Flash Player 10, AIR 1.5, Flash Lite 4

Gibt true zurück, wenn eine eingebettete Schriftart mit dem angegebenen fontName, fontWeight und fontPosture verfügbar ist, wobei Font.fontType flash.text.FontType.EMBEDDED_CFF ist. Ab Flash Player 10 können zwei Arten von eingebetteten Schriftarten in Anwendungsinhalten erscheinen. Normale eingebettete Schriftarten werden nur von TextField verwendet. CFF-Schriftarten werden nur von den flash.text.engine-Klassen verwendet. Die beiden Arten unterscheiden sich durch die fontType-Eigenschaft der Font-Klasse, die von der enumerateFonts()-Funktion zurückgegeben wird.

Die flash.text.engine-Klassen können keine Schriftart des Typs EMBEDDED verwenden. Wenn fontLookup auf FontLookup.EMBEDDED_CFF gesetzt wurde und die einzige zur Laufzeit verfügbare Schriftart mit dem angegebenen Namen, Gewicht und Schnitt dem Typ EMBEDDED angehört, ignoriert die Laufzeitumgebung diese Schriftart und greift stattdessen für jede einzelne Glyphe auf Geräteschriftarten zurück, um den Text wiederzugeben.

Sind Schriftarten beider Arten, also EMBEDDED und EMBEDDED_CFF, mit dem gleichen Namen, Gewicht und Schnitt verfügbar, wird die Schriftart EMBEDDED_CFF ausgewählt. Der Text wird mit der Schriftart EMBEDDED_CFF wiedergegeben.

Parameter

fontName:String — Der Name der zu überprüfenden eingebetteten Schriftart.
 
fontWeight:String — Gibt die Schriftstärke an. Verwenden Sie FontWeight.
 
fontPosture:String — Gibt den Schriftschnitt an. Verwenden Sie FontPosture.

Rückgabewerte
Booleantrue, wenn eine kompatible eingebettete Schriftart verfügbar ist, wenn nicht, dann false.

Auslöser
ArgumentError — Das angegebene fontWeight ist kein Mitglied von FontWeight.
 
ArgumentError — Die angegebene fontPosture ist kein Mitglied von FontPosture.

Verwandte API-Elemente

FontDescriptionExample.as

In diesem Beispiel wird ein FontDescription-Objekt erstellt, diesem Objekt wird eine Geräteschriftart zugewiesen, es werden verschiedene Schrifteigenschaften festgelegt und das neue Objekt wird einem ElementFormat-Objekt zugewiesen. Zusätzliche Schriftformatierung erfolgt in ElementFormat. Ein neues TextElement wird mithilfe von ElementFormat erstellt und das TextElement wird als Inhalt für einen TextBlock verwendet. Im TextBlock wird eine Textzeile erstellt.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescriptionExample extends Sprite {
        
        public function FontDescriptionExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
        }
    }    
}




[ X ]Warum auf Englisch?
Inhalt des ActionScript 3.0-Referenzhandbuchs wird in englischer Sprache angezeigt

Nicht alle Teile des ActionScript 3.0-Referenzhandbuchs wurden in alle Sprachen übersetzt. Wenn der Text zu einem Sprachelement nicht übersetzt wurde, wird er auf Englisch angezeigt. Zum Beispiel wurden die Informationen zur ga.controls.HelpBox-Klasse nicht in andere Sprachen übersetzt. In der deutschen Version des Referenzhandbuchs erscheint der Abschnitt zur ga.controls.HelpBox-Klasse deshalb auf Englisch.