RadioButtonGroup

Пакет	fl.controls
Класс	public class RadioButtonGroup
Наследование	RadioButtonGroup EventDispatcher Object

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Класс RadioButtonGroup определяет группу компонентов RadioButton, которые будут вести себя как один компонент. Если выделен один переключатель, то другие переключатели из той же группы выделить не удастся.

Посмотреть примеры

Связанные элементы API

RadioButton
RadioButton.group

Общедоступные свойства

Скрыть унаследованные общедоступные свойства

Показать унаследованные общедоступные свойства

	Свойство		Определено
		constructor : Object Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.	Object
		name : String [только для чтения] Определяет имя экземпляра кнопки-переключателя.	RadioButtonGroup
		numRadioButtons : int [только для чтения] Определяет число переключателей в данной группе.	RadioButtonGroup
		selectedData : Object Определяет или задает свойство value выделенного переключателя.	RadioButtonGroup
		selection : RadioButton Определяет или задает ссылку на переключатель, который в данный момент выбран в группе переключателей.	RadioButtonGroup

Общедоступные методы

Скрыть унаследованные общедоступные методы

Показать унаследованные общедоступные методы

	Метод		Определено
		RadioButtonGroup(name:String) Создает новый экземпляр класса RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Регистрирует объект прослушивателя события на объекте EventDispatcher для получения прослушивателем уведомления о событии.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Добавляет переключатель во внутренний массив для использования с индексированием группы кнопок-переключателей, что позволяет выбирать один переключатель в группе.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Посылает событие в поток событий.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [статические] Возвращает ссылку на указанную группу переключателей.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Возвращает компонент RadioButton в заданном положении указателя.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Возвращает положение индекса для заданного экземпляра RadioButton.	RadioButtonGroup
		hasEventListener(type:String):Boolean Проверяет, имеет ли объект EventDispatcher прослушиватели, зарегистрированные для определенного типа события.	EventDispatcher
		hasOwnProperty(name:String):Boolean Показывает, определено ли заданное свойство для объекта.	Object
		isPrototypeOf(theClass:Object):Boolean Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.	Object
		propertyIsEnumerable(name:String):Boolean Показывает наличие заданного свойства и его перечисляемость.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Удаляет прослушиватель из объекта EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Удаляет экземпляр RadioButton из внутреннего списка переключателей.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Задает доступность динамического свойства для операций цикла.	Object
		toLocaleString():String Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали.	Object
		toString():String Возвращает строковое представление заданного объекта.	Object
		valueOf():Object Возвращает элементарное значение заданного объекта.	Object
		willTrigger(type:String):Boolean Проверяет, зарегистрирован ли прослушиватель события для указанного типа события с данным объектом EventDispatcher или любым его предшественником.	EventDispatcher

События

Дополнительные сведения о событиях

Скрыть унаследованные события

Показать унаследованные события

	Сводка	Определено
activate	[многоадресное событие] Отправляется, когда проигрыватель Flash Player или приложение AIR перемещается в фокус операционной системы и становится активным.	EventDispatcher
change	Отправляется, когда изменяется выбранный экземпляр RadioButton в группе.	RadioButtonGroup
click	Отправляется, когда пользователь щелкает экземпляр RadioButton.	RadioButtonGroup
deactivate	[многоадресное событие] Отправляется, когда проигрыватель Flash Player или приложение AIR теряет фокус системы и становится неактивным.	EventDispatcher

Сведения о свойстве

name

свойство

name:String [только для чтения]

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Определяет имя экземпляра кнопки-переключателя.

Значением по умолчанию является "RadioButtonGroup".

Реализация
public function get name():String

numRadioButtons

свойство

numRadioButtons:int [только для чтения]

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Определяет число переключателей в данной группе.

Значением по умолчанию является 0.

Реализация
public function get numRadioButtons():int

selectedData

свойство

selectedData:Object

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Определяет или задает свойство value выделенного переключателя. Если в данный момент не выбран ни один переключатель, этому свойству присваивается значение null.

Реализация
public function get selectedData():Object
public function set selectedData(value:Object):void

Пример ( Использование этого примера )

В следующем примере создается новый компонент RadioButtonGroup и выполняется прослушивание события change:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

свойство

selection:RadioButton

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Определяет или задает ссылку на переключатель, который в данный момент выбран в группе переключателей.

Реализация
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Пример ( Использование этого примера )

В следующем примере создается новая группа переключателей, которая содержит два переключателя. Когда выделенный в данный момент переключатель изменяется, отслеживаются метка и значение выделенного переключателя:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Сведения о конструкторе

()

Конструктор

public function RadioButtonGroup(name:String)

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Создает новый экземпляр класса RadioButtonGroup. Обычно это происходит автоматически при создании экземпляра переключателя.

Параметры

name:String — Имя группы переключателей.

Сведения о методе

addRadioButton

()

метод

public function addRadioButton(radioButton:RadioButton):void

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Добавляет переключатель во внутренний массив для использования с индексированием группы кнопок-переключателей, что позволяет выбирать один переключатель в группе. Этот метод используется переключателями автоматически. Но им также можно воспользоваться и вручную, чтобы добавить переключатель в группу явным образом.

Параметры

radioButton:RadioButton — Экземпляр RadioButton, который необходимо добавить в группу переключателей.

getGroup

()

метод

public static function getGroup(name:String):RadioButtonGroup

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Возвращает ссылку на указанную группу переключателей.

Параметры

name:String — Имя группы, для которой извлекается ссылка.

Возвращает

RadioButtonGroup — Ссылка на указанный компонент RadioButtonGroup.

Пример ( Использование этого примера )

В следующем примере демонстрируется, как определить, какой переключатель в группе выделен:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

метод

public function getRadioButtonAt(index:int):RadioButton

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Возвращает компонент RadioButton в заданном положении указателя.

Параметры

index:int — Индекс компонента RadioButton в компоненте RadioButtonGroup, где индекс первого компонента равен 0.

Возвращает

RadioButton — Указанный компонент RadioButton.

Выдает

RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

getRadioButtonIndex

()

метод

public function getRadioButtonIndex(radioButton:RadioButton):int

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Возвращает положение индекса для заданного экземпляра RadioButton.

Параметры

radioButton:RadioButton — Экземпляр RadioButton, который необходимо найти в текущем компоненте RadioButtonGroup.

Возвращает

int — Индекс указанного компонента RadioButton, либо «-1», если указанный компонент не найден.

removeRadioButton

()

метод

public function removeRadioButton(radioButton:RadioButton):void

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Удаляет экземпляр RadioButton из внутреннего списка переключателей.

Параметры

radioButton:RadioButton — Удаляемый экземпляр RadioButton.

Сведения о событии

change

Событие

Тип объекта события: flash.events.Event
свойство Event.type = flash.events.Event.CHANGE

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Отправляется, когда изменяется выбранный экземпляр RadioButton в группе.

Константа Event.CHANGE определяет значение свойства type объекта события change.

Это событие имеет следующие свойства:

Свойство	Значение
`bubbles`	`true`
`cancelable`	`false`; поведение по умолчанию, подлежащее отмене, не определено.
`currentTarget`	Объект, активно обрабатывающий объект Event с помощью прослушивателя событий.
`target`	Объект, значение которого было изменено. Свойство `target` не всегда является объектом из списка отображения, для которого зарегистрирован прослушиватель событий. Используйте свойство `currentTarget` для обращения к объекту в списке отображения, обрабатывающему событие в данный момент.

Пример ( Использование этого примера )

В следующем примере создаются три переключателя и добавляется прослушиватель событий для события change группы переключателей:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Событие

Тип объекта события: flash.events.MouseEvent
свойство MouseEvent.type = flash.events.MouseEvent.CLICK

Язык версии:

ActionScript 3.0

Версия продукта:

Flash CS3

Версии среды выполнения:

Flash Player 9.0.28.0, AIR 1.0

Отправляется, когда пользователь щелкает экземпляр RadioButton.

Задает значение свойства type для объекта события click.

Это событие имеет следующие свойства:

Свойство	Значение
`altKey`	`true`, если клавиша Alt активна (Windows).
`bubbles`	`true`
`buttonDown`	Для событий щелчка всегда используется значение `false`.
`cancelable`	`false`; поведение по умолчанию, подлежащее отмене, не определено.
`commandKey`	`true` в Mac, если клавиша Command активна; `false`, если неактивна. Всегда `false` в Windows.
`controlKey`	`true`, если клавиша Ctrl или Control активна; `false`, если неактивна.
`ctrlKey`	`true` в Windows или Linux, если клавиша Ctrl активна. `true` в Mac, если клавиша Ctrl или Command активна. В противном случае `false`.
`currentTarget`	Объект, активно обрабатывающий объект Event с помощью прослушивателя событий.
`localX`	Горизонтальная координата, в которой произошло событие, относительно спрайта-контейнера, если блокировка мыши отключена.
`localY`	Вертикальная координата, в которой произошло событие, относительно спрайта-контейнера, если блокировка мыши отключена.
`movementX`	Изменение горизонтальных координат положения мыши с последнего события мыши, если блокировка мыши включена.
`movementY`	Изменение вертикальных координат положения мыши с последнего события мыши, если блокировка мыши включена.
`shiftKey`	`true`, если клавиша Shift активна; иначе — `false`.
`stageX`	Горизонтальная координата события в глобальных координатах рабочей области.
`stageY`	Вертикальная координата события в глобальных координатах рабочей области.
`target`	Объект InteractiveObject под указателем. Свойство `target` не всегда является объектом из списка отображения, для которого зарегистрирован прослушиватель событий. Используйте свойство `currentTarget` для обращения к объекту в списке отображения, обрабатывающему событие в данный момент.

Примеры Использование этого примера

RadioButtonGroupExample.as

В этом примере демонстрируется управление несколькими объектами RadioButton из более чем одной группы:

Добавьте компоненты RadioButton и Label в свою библиотеку.
Сохраните этот код под именем RadioButtonGroupExample.as в том же каталоге, где и FLA-файл.
Присвойте параметру DocumentClass в FLA-файле значение RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Юридическая информация | Политика конфиденциальности онлайн

RadioButtonGroup - AS3 Flash

Классы x

name

numRadioButtons

selectedData

selection