CellRenderer  - AS3 Flash

Определяет или задает объект, представляющий данные, связанные с компонентом. Когда это значение установлено, данные компонента сохраняются, а компонент, в котором они содержатся, аннулируется. Аннулированный компонент автоматически перерисовывается.

Это свойство данных представляет объект, содержащий элемент в DataProvider, который представляет ячейка. Как правило, это свойство данных содержит стандартные свойства в зависимости от типа компонента. Данные в разделе CellRenderer компонента List или ComboBox содержат метку, значок и свойства данных; в TileList указаны метка и свойство source; в ячейке DataGrid содержатся значения для каждого столбца. Свойство данных может также содержать данные, указанные пользователем в отношении определенной ячейки. Пользователи могут расширить CellRenderer, чтобы компонент получил возможность обратиться к различным свойствам данных при визуализации ячейки.

Кроме того, чтобы указать свойства, которые применяются для прорисовки метки, значка и источника, можно использовать соответственно элементы labelField, labelFunction, iconField, iconFunction, sourceField и sourceFunction.

Определяет или задает свойства списка, которые применяются к ячейке, например значения index и selected. Эти свойства списка автоматически обновляются после аннулирования ячейки.

Определяет или задает логическое значение, указывающее, выбрана ли данная ячейка. Значение true указывает, что текущая ячейка выбрана; значение false указывает на то, что она не выбрана.

Значением по умолчанию является false.

Создает новый экземпляр CellRenderer.

Возвращает карту стилей по умолчанию для текущего компонента. Карта стилей содержит тип, который подходит для компонента в зависимости от стиля, используемого компонентом. Например, стиль disabledTextFormat содержит значение null или объект TextFormat. Вы можете воспользоваться этими стилями и вызвать метод setStyle() по отношению к текущему компоненту. Следующий код переопределяет стиль disabledTextFormat, выбранный по умолчанию для указанного компонента:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Связанные элементы API

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Указывает размеры области, в которой должна производиться визуализация данных. Эти размеры относятся как к данным, так и к ячейке, в которой они содержатся. Средство визуализации учитывает их, чтобы убедиться в том, что данные умещаются в ячейку и не отображаются в соседних ячейках.

Параметры

Чтобы применить этот пример на практике, выполните следующие действия.

1. Добавьте компонент TileList в библиотеку.
2. Создайте новый символ BlueBackground («голубой фон») и в его свойствах установите флажок «Экспорт для ActionScript». Оставьте в качестве имени класса BlueBackground.
3. Создайте новый символ OrangeBackground («оранжевый фон») и в его свойствах установите флажок «Экспорт для ActionScript». Оставьте в качестве имени класса OrangeBackground.
4. Создайте новый символ GreenBackground («зеленый фон») и в его свойствах установите флажок «Экспорт для ActionScript». Оставьте в качестве имени класса GreenBackground.
5. В каждом символе создайте прямоугольник величиной 10 пикселов в ширину и 10 пикселов в высоту, выбрав цвета, указанные в названии символа. Он должен быть расположен в точке с нулевыми координатами x и y.
6. Сохраните этот код под именем CellRendererExample.as в том же каталоге, где и FLA-файл.
7. Присвойте классу Document в FLA-файле значение CellRendererExample.

package
{ 
    import fl.controls.TileList;
    import fl.core.UIComponent;
    import fl.data.DataProvider;
    import fl.events.ListEvent;
    import flash.display.Sprite;
    import flash.events.Event;
    
    public class CellRendererExample extends Sprite
    {
        public function CellRendererExample() {
            var dp:DataProvider = new DataProvider();
            var totalEntries:uint = 42;
            var i:uint;
            for(i=0; i<totalEntries; i++) {
                dp.addItem( { label:"Item "+i } );            
            }
            
            var myTileList = new TileList();
            myTileList.dataProvider = dp;
            myTileList.allowMultipleSelection = true;
            myTileList.columnWidth = 125;
            myTileList.rowHeight = 25;
            myTileList.columnCount = 3;
            myTileList.rowCount = 6;
            myTileList.move(10,10);
            myTileList.setStyle('cellRenderer', MyRenderer);    
            myTileList.addEventListener(ListEvent.ITEM_CLICK, onClick);
            addChild(myTileList);
        }
        private function onClick(e:ListEvent):void {
            var cr:MyRenderer = e.target.itemToCellRenderer(e.item) as MyRenderer;
            trace(cr.customProperty);    
        }
    }
}

import fl.controls.listClasses.CellRenderer;

class MyRenderer extends CellRenderer
{
    public var customProperty:String = "foo";
    
    public function MyRenderer() {
        var originalStyles:Object = CellRenderer.getStyleDefinition();
        setStyle("upSkin",BlueBackground);
        setStyle("downSkin",GreenBackground);
        setStyle("overSkin",OrangeBackground);
        setStyle("selectedUpSkin",originalStyles.selectedUpSkin);
        setStyle("selectedDownSkin",originalStyles.selectedDownSkin);
        setStyle("selectedOverSkin",originalStyles.selectedOverSkin);
    }
}