Sprite  - AS3

Задает режим кнопки данного спрайта. При значении true этот спрайт ведет себя как кнопка, то есть запускает отображение курсора в виде руки, когда над ним проходит указатель, и может получать событие click при нажатии клавиш Enter и «Пробел», когда спрайт находится в фокусе. Можно отменить отображение курсора в виде руки, задав свойству useHandCursor значение false, в этом случае будет отображаться указатель.

В целом, для создания кнопок лучше использовать класс SimpleButton, однако свойство buttonMode можно использовать для придания спрайту некоторых функций кнопок. Чтобы включить спрайт в последовательность перехода посредством клавиши Tab, задайте свойству tabEnabled (унаследованному от класса InteractiveObject и имеющему по умолчанию значение false) значение true. Кроме того, подумайте, должны ли дочерние элементы спрайта реагировать на пользовательский ввод. Большинство кнопок блокируют воздействие пользовательского ввода на дочерние объекты, так как это препятствует нормальному потоку событий. Чтобы отключить воздействие пользовательского ввода на дочерние объекты, необходимо задать свойству mouseChildren (унаследованному от класса DisplayObjectContainer) значение false.

Если свойство buttonMode используется с классом MovieClip (подклассом класса Sprite), кнопка может получить дополнительные функции. Если включить кадры с подписями _up, _over и _down, проигрыватель Flash Player передает автоматические изменения состояния (функция, подобная возможностям фрагментов роликов, используемых в качестве кнопок, в предыдущих версиях ActionScript). Эти автоматические изменения состояния недоступны для спрайтов, так как у них нет временной шкалы и, следовательно, кадров для добавления подписей.

Связанные элементы API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Определяет экранный объект, над которым перетаскивается спрайт либо на котором спрайт был отпущен.

Связанные элементы API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Задает объект Graphics, принадлежащий данному спрайту, в котором могут выполняться команды векторного рисования.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Определяет другой спрайт в качестве области щелчка для спрайта. Если свойство hitArea не существует или ему задано значение null или undefined, то в качестве области щелчка используется сам спрайт. Значение свойства hitArea может быть ссылкой на объект Sprite.

Свойство hitArea можно изменить в любой момент; модифицированный спрайт немедленно начинает использовать новое поведение области щелчка. Спрайт, настроенный в качестве области щелчка не обязательно должен быть видимым; его графическая форма, оставаясь невидимой, все равно обнаруживается в качестве области щелчка.

Примечание. Необходимо задать значение false свойству mouseEnabled спрайта, настроенного в качестве области щелчка. В противном случае кнопка спрайта может не работать, так как спрайт, настроенный в качестве области щелчка, получает события пользовательского ввода вместо кнопки спрайта.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Управляет звуком в данном спрайте.

Примечание. Это свойство не затрагивает содержимое HTML объекта HTMLControl (в Adobe AIR).

Связанные элементы API

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Логическое значение, определяющее, должен ли отображаться курсор в виде руки при наведении указателя мыши на спрайт, в котором свойство buttonMode имеет значение true. Свойство useHandCursor по умолчанию имеет значение true. Когда useHandCursor имеет значение true, курсор в виде руки, используемый для кнопок, появляется при наведении указателя на спрайт-кнопку. Если же useHandCursor имеет значение false, используется указатель «стрелка».

Свойство useHandCursor можно изменить в любое время; модифицированный спрайт немедленно принимает новый вид курсора.

Примечание. Если во Flex или Flash Builder спрайт имеет дочерние спрайты, может потребоваться задание для свойства mouseChildren значения false. Например, если необходимо, чтобы курсор в виде руки отображался над элементом управления Flex <mx:Label>, задайте для свойств useHandCursor и buttonMode значение true, а для свойства mouseChildren значение false.

Связанные элементы API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Создает новый экземпляр Sprite. Создав экземпляр Sprite вызовите метод DisplayObjectContainer.addChild() или DisplayObjectContainer.addChildAt(), чтобы добавить Sprite в родительский объект DisplayObjectContainer.

Позволяет пользователю перетаскивать заданный спрайт (растровый графический объект, легко перемещаемый по экрану). Спрайт можно перетаскивать до явной остановки через вызов метода Sprite.stopDrag() или до того, как можно будет перетаскивать другой спрайт. Одновременно можно перетаскивать только один спрайт.

Трехмерные объекты отображения управляются указателем, а метод Sprite.startDrag() позволяет перемещать объект в трехмерной плоскости, определенной экранным объектом. Или, если экранный объект является двумерным объектом и дочерним элементом трехмерного объекта, двумерный объект перемещается в трехмерной плоскости, определенной трехмерным родительским объектом.

Параметры

Связанные элементы API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Позволяет перетаскивать указанный спрайт на устройстве с сенсорным экраном. Спрайт можно перетаскивать до явной остановки через вызов метода Sprite.stopTouchDrag() или до того, как можно будет перетаскивать другой спрайт. Одновременно можно перетаскивать только один спрайт.

Трехмерные объекты отображения управляются указателем, а метод Sprite.stopTouchDrag() позволяет перемещать объект в трехмерной плоскости, определенной экранным объектом. Или, если экранный объект является двумерным объектом и дочерним элементом трехмерного объекта, двумерный объект перемещается в трехмерной плоскости, определенной трехмерным родительским объектом.

Параметры

Связанные элементы API

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Завершает метод startDrag(). Спрайт, созданный перетаскиваемым с помощью метода startDrag(), остается таковым до добавления метода stopDrag() или до того, как другой спрайт станет перетаскиваемым. Одновременно можно перетаскивать только один спрайт.

Связанные элементы API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Завершает выполнение метода startTouchDrag(), используется для устройств с сенсорным экраном. Спрайт, сделанный перетаскиваемым с помощью метода startTouchDrag(), остается таковым до добавления метода stopTouchDrag() или до того, как другой спрайт станет перетаскиваемым. Одновременно можно перетаскивать только один спрайт.

Параметры

Связанные элементы API

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Объявите свойство size (100 x 100 пикселей) и цвет фона (оранжевый) для дальнейшего использования при рисовании квадрата.
2. После этого конструктор создает новый объект Sprite child и использует его для добавления двух прослушивателей событий и связанных с ними методов: mouseDownHandler() и mouseUpHandler().
3. Затем объект Sprite child передается методу draw(), который рисует оранжевый квадрат.
4. После этого дочерний объект помещается в список отображения через вызов метода addChild().
5. Прослушиватели событий работают следующим образом.
   • mouseDownHandler(): когда пользователь щелкает объект Sprite, этот метод добавляет прослушиватель события mouseMove, метод mouseMoveHandler(), обрабатывающий перемещение мыши. Затем вызывается метод startDrag(), позволяющий перетаскивать объект Sprite.
   • mouseUpHandler(): когда кнопка мыши отпускается, прослушиватель события mouseMove удаляется и вызывается метод stopDrag(), фиксирующий оранжевый квадрат на месте.
   • mouseMoveHandler: пока удерживается левая кнопка мыши, этот метод предписывает проигрывателю непрерывное перерисовывание оранжевого квадрата.

Примечание. Каждый метод прослушивателя событий объявляет локальную переменную sprite, которая назначается свойству target события.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}