Справочник по ActionScript® 3.0 для платформы Adobe® Flash®
Домашняя страница  |  Скрыть список пакетов и классов |  Пакеты  |  Классы  |  Что нового  |  Указатель  |  Приложения  |  Почему по-английски?
Фильтры: Получение данных с сервера...
Получение данных с сервера...
flash.events 

ProgressEvent  - AS3

Пакетflash.events
Классpublic class ProgressEvent
НаследованиеProgressEvent Inheritance Event Inheritance Object
Подклассы ModuleEvent, ResourceEvent, RSLEvent, StyleEvent, VideoProgressEvent

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Объект ProgressEvent отправляется, если началась операция загрузки или сокет получил данные. Эти события обычно генерируются, когда SWF-файлы, изображения или данные загружаются в приложение. Существует два типа событий прогресса: ProgressEvent.PROGRESS и ProgressEvent.SOCKET_DATA. Кроме того, в среде AIR объекты ProgressEvent отправляются, когда данные передаются или получаются дочерним процессом с помощью класса NativeProcess.

Посмотреть примеры

Связанные элементы API



Общедоступные свойства
 СвойствоОпределено
 Inheritedbubbles : Boolean
[только для чтения] Определяет, является ли событие событием восходящей цепочки.
Event
  bytesLoaded : Number
Число элементов или байтов, загруженных на момент обработки события прослушивателем.
ProgressEvent
  bytesTotal : Number
Общее число элементов или байтов, которые будут получены в случае успешного завершения загрузки.
ProgressEvent
 Inheritedcancelable : Boolean
[только для чтения] Указывает, можно ли предотвратить поведение, связанное с событием.
Event
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
 InheritedcurrentTarget : Object
[только для чтения] Объект, активно обрабатывающий объект Event с помощью прослушивателя событий.
Event
 InheritedeventPhase : uint
[только для чтения] Текущая фаза в потоке событий.
Event
 Inheritedtarget : Object
[только для чтения] Целевой объект события.
Event
 Inheritedtype : String
[только для чтения] Тип события.
Event
Общедоступные методы
 МетодОпределено
  
ProgressEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, bytesLoaded:Number = 0, bytesTotal:Number = 0)
Создает объект Event, содержащий данные о событиях в ходе работы.
ProgressEvent
  
[переопределить] Создает копию объекта ProgressEvent и задает значение каждого свойства, совпадающее с оригиналом.
ProgressEvent
 Inherited
formatToString(className:String, ... arguments):String
Служебная функция для реализации метода toString() в пользовательских классах ActionScript 3.0 Event.
Event
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Проверяет, выполнялся ли для события вызова метода preventDefault().
Event
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Отменяет поведение по умолчанию для события, если такое поведение можно отменить.
Event
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Отменяет обработку прослушивателей событий в текущем узле, а также во всех узлах, которые следуют в потоке событий за текущим узлом.
Event
 Inherited
Отменяет обработку прослушивателей событий в узлах, которые следуют в потоке событий за текущим узлом.
Event
 Inherited
Возвращает строковое представление этого объекта, отформатированного в соответствии со стандартами, принятыми для данной локали.
Object
  
[переопределить] Возвращает строку, содержащую все свойства объекта ProgressEvent.
ProgressEvent
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Общедоступные константы
 КонстантаОпределено
  PROGRESS : String = "progress"
[статические] Задает значение свойства type для объекта события progress.
ProgressEvent
  SOCKET_DATA : String = "socketData"
[статические] Задает значение свойства type для объекта события socketData.
ProgressEvent
  STANDARD_ERROR_DATA : String = "standardErrorData"
[статические] Задает значение свойства type для объекта события standardErrorData.
ProgressEvent
  STANDARD_INPUT_PROGRESS : String = "standardInputProgress"
[статические] Задает значение свойства type для объекта события standardInputProgress.
ProgressEvent
  STANDARD_OUTPUT_DATA : String = "standardOutputData"
[статические] Задает значение свойства type для объекта события standardOutputData.
ProgressEvent
Сведения о свойстве

bytesLoaded

свойство
bytesLoaded:Number

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Число элементов или байтов, загруженных на момент обработки события прослушивателем.



Реализация
    public function get bytesLoaded():Number
    public function set bytesLoaded(value:Number):void

bytesTotal

свойство 
bytesTotal:Number

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Общее число элементов или байтов, которые будут получены в случае успешного завершения загрузки. Если событие прогресса отправляется/присоединяется к объекту Socket, свойство bytesTotal будет всегда иметь значение 0, если значение не задано в параметре bytesTotal конструктора. Фактическое число байт, отправляемых в обоих направлениях, не задано и определяется разработчиком приложения.



Реализация
    public function get bytesTotal():Number
    public function set bytesTotal(value:Number):void
Сведения о конструкторе

ProgressEvent

()Конструктор
public function ProgressEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, bytesLoaded:Number = 0, bytesTotal:Number = 0)

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Создает объект Event, содержащий данные о событиях в ходе работы. Объекты Event передаются прослушивателям событий в качестве параметров.

Параметры
type:String — Тип события. Возможные значения: ProgressEvent.PROGRESS, ProgressEvent.SOCKET_DATA, ProgressEvent.STANDARD_ERROR_DATA, ProgressEvent.STANDARD_INPUT_PROGRESS и ProgressEvent.STANDARD_OUTPUT_DATA.
 
bubbles:Boolean (default = false) — Определяет, участвует ли объект Event в фазе восходящей цепочки потока событий.
 
cancelable:Boolean (default = false) — Определяет, можно ли отменить объект Event.
 
bytesLoaded:Number (default = 0) — Число элементов или байтов, загруженных на момент обработки события прослушивателем.
 
bytesTotal:Number (default = 0) — Общее число элементов или байтов, которые будут получены в случае успешного завершения загрузки.
Сведения о методе

clone

()метод
override public function clone():Event

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Создает копию объекта ProgressEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает
Event — Новый объект ProgressEvent, значения свойств которого соответствуют значениям оригинала.

toString

()метод 
override public function toString():String

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Возвращает строку, содержащую все свойства объекта ProgressEvent. Строка имеет следующий формат:

[ProgressEvent type=value bubbles=value cancelable=value bytesLoaded=value bytesTotal=value]

Возвращает
String — Строка, содержащая все свойства объекта ProgressEvent.
Сведения о константе

PROGRESS

Константа
public static const PROGRESS:String = "progress"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Задает значение свойства type для объекта события progress.

Это событие имеет следующие свойства:

СвойствоЗначение
bubblesfalse
bytesLoadedЧисло элементов или байтов, загруженных на момент обработки события прослушивателем.
bytesTotalОбщее число элементов или байтов, которые в итоге будут получены в случае успешного завершения загрузки.
cancelablefalse; поведение по умолчанию, подлежащее отмене, не определено.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
targetОбъект, сообщающий сведения о прогрессе.

Связанные элементы API

SOCKET_DATA

Константа 
public static const SOCKET_DATA:String = "socketData"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 1.0, Flash Player 9, Flash Lite 4

Задает значение свойства type для объекта события socketData.

Это событие имеет следующие свойства:

СвойствоЗначение
bubblesfalse
cancelablefalse; поведение по умолчанию, подлежащее отмене, не определено.
currentTargetОбъект, активно обрабатывающий событие.
bytesLoadedЧисло элементов или байтов, загруженных на момент обработки события прослушивателем.
bytesTotal0; это свойство не используется объектами события socketData.
targetСокет, сообщающий сведения о прогрессе.

Связанные элементы API

STANDARD_ERROR_DATA

Константа 
public static const STANDARD_ERROR_DATA:String = "standardErrorData"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 2, Flash Lite 4

Задает значение свойства type для объекта события standardErrorData.

Это событие имеет следующие свойства:

СвойствоЗначение
bubblesfalse
cancelablefalse; поведение по умолчанию, подлежащее отмене, не определено.
currentTargetОбъект, активно обрабатывающий событие.
bytesLoadedЧисло байт данных ошибок, сохраненных в буфере объектом NativeProcessObject.error в результате этого события.
bytesTotal0; это свойство не используется объектами события standardErrorData.
targetОбъект NativeProcess, сообщающий данные об ошибке.

Связанные элементы API

STANDARD_INPUT_PROGRESS

Константа 
public static const STANDARD_INPUT_PROGRESS:String = "standardInputProgress"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 2, Flash Lite 4

Задает значение свойства type для объекта события standardInputProgress.

Это событие имеет следующие свойства:

СвойствоЗначение
bubblesfalse
cancelablefalse; поведение по умолчанию, подлежащее отмене, не определено.
currentTargetОбъект, активно обрабатывающий событие.
bytesLoadedЧисло байт данных ошибок, сохраненных в буфере объектом NativeProcessObject.error в результате этого события.
bytesTotal0; это свойство не используется объектами события standardInputProgress.
targetОбъект NativeProcess, сообщающий данные об ошибке.

Связанные элементы API

STANDARD_OUTPUT_DATA

Константа 
public static const STANDARD_OUTPUT_DATA:String = "standardOutputData"

Язык версии: ActionScript 3.0
Версии среды выполнения: AIR 2, Flash Lite 4

Задает значение свойства type для объекта события standardOutputData.

Это событие имеет следующие свойства:

СвойствоЗначение
bubblesfalse
cancelablefalse; поведение по умолчанию, подлежащее отмене, не определено.
currentTargetОбъект, активно обрабатывающий событие.
bytesLoadedЧисло байт данных вывода, сохраненных в буфере объектом NativeProcessObject.output в результате этого события.
bytesTotal0; это свойство не используется объектами события standardOutputData.
targetОбъект NativeProcess, сообщающий данные вывода.

Связанные элементы API

ProgressEventExample.as

В следующем примере используется класс ProgressEventExample, чтобы продемонстрировать использование различных прослушивателей событий при загрузке файла. Для этого выполняются следующие задачи:
  1. Создаются свойства downloadURL и fileName, указывающие местоположение и имя загружаемого файла.
  2. В конструкторе ProgressEventExample создается новый объект FileReference с именем file и передается методу configureListeners().
  3. Затем свойства downloadURL и fileName передаются методу file.download(), который указывает местоположение для загрузки файла.
  4. Метод configureListeners() добавляет семь прослушивателей событий со связанными методами подписчиков:
    1. cancel/cancelHandler() отправляется в случае отмены загрузки;
    2. complete/complereHandler() отправляется по окончании загрузки файла;
    3. ioError/ioErrorHandler() отправляется, если загружаемый файл недоступен.
    4. open/openHandler() отправляется после начала операции загрузки;
    5. progress/progressHandler() отправляется два раза: когда процесс загрузки начинается и когда заканчивается;
    6. securityError/securityErrorHandler отправляется, если параметр безопасности локального воспроизведения не соответствует типу доступа к данным для загружаемого файла (локальный/сетевой); см. примечания ниже;
    7. select/selectHandler() отправляется, когда выбирается загружаемый файл.

Примечания.

  • SWF-файл требуется откомпилировать с установленным для параметра «Безопасность локального воспроизведения» режимом «Доступ только к сетевым файлам».
  • Для реализации данного примера требуется файл с именем SomeFile.pdf.
  • Хотя в этом примере используются все события, доступные для объекта FileReference, в большинстве случаев требуется только та или иная подгруппа..

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}




[ X ]Почему по-английски?
Содержимое Справочника ActionScript 3.0 отображается на английском языке

Не все части Справочника ActionScript 3.0 переводятся на все языки. Если какой-то текстовый элемент не переведен, он отображается на английском языке. Например, компонент ga.controls.HelpBox не переведен ни на один из языков. Это значит, что в русской версии справки компонент ga.controls.HelpBox будет отображаться на английском языке.