FileReference  - AS3

Дата создания файла на локальном диске. Если объект не был заполнен, вызов с целью получения значения данного свойства возвращает значение null.

Примечание. Если операционная система не имеет свойства creationDate в таких случаях, CreationDate имеет значение lastModifiedDate.

Связанные элементы API

Тип создателя Macintosh для файла, который используется только в версиях OS, предшествующих Mac OS X. В Windows или Linux это свойство имеет значение null. Если объект FileReference не был заполнен, вызов с целью получения значения данного свойства возвращает значение null.

Связанные элементы API

Объект ByteArray, представляющий данные из файла, загруженного в результате успешного вызова метода load().

Связанные элементы API

Расширение имени файла.

Расширение файла — это часть имени после последней точки («.»), не включая ее. Если в имени файла нет точки, то расширение имеет значение null.

Примечание. Для определения типа файла следует использовать свойство extension, а не creator или type. Свойства creator и type в данном случае несущественны. Они применяются к устаревшим версиям Mac OS.

Дата последнего изменения файла на локальном диске. Если объект FileReference не был заполнен, вызов с целью получения значения данного свойства возвращает значение null.

Связанные элементы API

Имя файла на локальном диске. Если объект FileReference не был заполнен (путем допустимого вызова FileReference.download() или FileReference.browse()), то при запросе значения данного свойства проигрыватель Flash Player выдает ошибку.

Все свойства объекта FileReference заполняются путем вызова метода browse(). В отличие от других свойств FileReference, при вызове метода download() свойство name заполняется после отправления события select.

Связанные элементы API

Определяет, предоставлено или нет приложению разрешение на доступ к файловой системе.

Связанные элементы API

Размер файла на локальном диске в байтах.

Примечание. В исходной версии ActionScript 3.0 свойство size было определено как объект uint, поддерживавший файлы размером до 4 Гб. Сейчас он реализуется как объект Number для поддержки файлов большого размера.

Связанные элементы API

Тип файла.

В операционной системе Windows или Linux это свойство указывает расширение файла. В Macintosh это свойство представляет собой четырехзначный тип файла, используемый только в версиях Mac OS, предшествующих Mac OS X. Если объект FileReference не был заполнен, вызов с целью получения значения данного свойства возвращает значение null.

Для Windows, Linux и Mac OS X расширение файла (то есть, часть свойства name после последней точки (.)), определяет тип файла.

Связанные элементы API

Создает новый объект FileReference. В заполненном состоянии объект FileReference представляет собой файл на локальном диске пользователя.

Связанные элементы API

Отображает диалоговое окно выбора файлов, позволяющее пользователю выбрать файл для загрузки. Это диалоговое окно принадлежит операционной системе пользователя. Пользователь может выбрать файл на локальном компьютере или в других системах (например, с помощью UNC-пути в операционной системе Windows).

Примечание. Класс File, доступный в Adobe AIR, включает методы для вызова более специфических системных диалогов для выбора файлов. Это методы File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() и File.browseForSave().

Когда вы вызываете этот метод и пользователь успешно выбирает файл, свойства данного объекта FileReference заполняются свойствами выбранного файла. При каждом последующем вызове метода FileReference.browse() свойства объекта FileReference соотносятся с файлом, который пользователь выбирает в диалоговом окне. Единовременно может выполняться только один сеанс browse() или download() (так как в любой момент времени можно вызвать только одно диалоговое окно).

С помощью параметра typeFilter можно определить, какие файлы будут отображаться в диалоговом окне.

В приложении Flash Player 10 и Flash Player 9 Update 5 этот метод можно вызывать только в ответ на пользовательское событие (например, в обработчике событий щелчка мыши или нажатия клавиши). В противном случае в результате вызова этого метода в приложении Flash Player возникает исключение Error.

Примите во внимание эти особенности, поскольку в приложение Flash Player добавлены новые функции. При публикации в приложении Flash Player 10 одновременно может быть активна только одна из следующих операций: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). В противном случае в приложении Flash Player возникает ошибка выполнения (код 2174). Используйте метод FileReference.cancel() для остановки выполняющейся операции. Это ограничение применяется только в приложении Flash Player 10. В предыдущих версиях Flash Player ограничение на одновременное выполнение нескольких операций не действует.

В Adobe AIR диалоговое окно выбора файлов не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Параметры

Связанные элементы API

Отменяет любую текущую операцию загрузки в отношении данного объекта FileReference. Вызов данного метода не приводит к отправке события cancel. Оно отправляется только в тот момент, когда пользователь отменяет операцию путем закрытия диалогового окна загрузки файлов.

Открывает диалоговое окно, позволяющее пользователю загрузить файл с удаленного сервера. Несмотря на то, что Flash Player не имеет ограничений на размер загружаемых файлов, официально проигрыватель поддерживает обработку информации, объем которой не превышает 100 МБ.

Сначала метод download() открывает диалоговое окно операционной системы, в котором пользователь должен ввести имя файла и выбрать место на локальном компьютере для сохранения этого файла. После того как пользователь выберет нужное место и подтвердит операцию загрузки (например, путем нажатия кнопки «Сохранить»), начнется загрузка с удаленного сервера. Прослушиватели получают события для определения состояния, успешности или сбоя загрузки. Чтобы определить состояние диалогового окна и операции загрузки после вызова метода download(), ваш код должен предусматривать прослушивание таких событий как cancel, open, progress и complete.

Функции FileReference.upload() и FileReference.download() не являются блокирующими. Эти функции возвращаются после вызова до завершения операции передачи файла. Кроме этого, если объект FileReference покинет зону действия, любая незавершенная отправка или загрузка в отношении данного объекта будет отменена в момент его выхода из зоны действия. Следите за тем, чтобы объект FileReference оставался в области действия на всем протяжении операции загрузки.

После успешной загрузки файла свойства объекта FileReference заполняются свойствами локального файла. Событие complete отправляется при успешном завершении загрузки.

Единовременно может выполняться только один сеанс browse() или download() (так как в любой момент времени можно вызвать только одно диалоговое окно).

Данный метод поддерживает загрузку файла любого типа по протоколу HTTP или HTTPS.

Нельзя подключаться к общепринятым зарезервированным портам. Полный список заблокированных портов см. в разделе «Ограничение API-интерфейсов сетевого подключения» в руководстве ActionScript 3.0 Developer's Guide (руководстве разработчика по ActionScript 3.0).

Примечание. Если ваш сервер требует аутентификации пользователей, только Flash-приложения, запущенные в обозревателе (то есть с использованием дополнительного модуля обозревателя или элемента управления ActiveX), могут представить пользователю диалоговое окно для ввода имени пользователя и пароля (для аутентификации) и только потом перейти к загрузкам. При загрузке с помощью дополнительного модуля или элемента управления ActiveX, а также при загрузке данных посредством автономного или внешнего проигрывателя происходит сбой передачи файлов.

При использовании данного метода необходимо продумать модель безопасности проигрывателя Flash Player:

• Операции загрузки запрещены, если вызывающий SWF-файл находится в ненадежной локальной изолированной среде.
• По умолчанию, взаимодействие между изолированными средами запрещено. Чтобы обеспечить доступ к ресурсу, web-сайт может добавить файл политик для URL.
• Можно запретить использование SWF-файлом этого метода путем установки параметра allowNetworking для тегов object и embed на странице HTML, содержащей SWF-содержимое.
• В приложении Flash Player 10 и Flash Player 9 Update 5 этот метод можно вызывать только в ответ на пользовательское событие (например, в обработчике событий щелчка мыши или нажатия клавиши). В противном случае в результате вызова этого метода в приложении Flash Player возникает исключение Error.

Однако в Adobe AIR эти ограничения по безопасности не распространяются на содержимое в изолированной программной среде безопасности application (содержимое, установленное с приложением AIR).

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

При загрузке с помощью этого метода файл помечается как загруженный в тех операционных системах, которые поддерживают пометку.

• ОС Windows XP с пакетом обновления SP2 или более поздним и ОС Windows Vista
• ОС Mac OS 10.5 и более поздних версий

Некоторые операционные системы, такие как Linux, не помечают загруженные файлы.

Примите во внимание эти особенности, поскольку в приложение Flash Player добавлены новые функции. При публикации в приложении Flash Player 10 одновременно может быть активна только одна из следующих операций: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). В противном случае в приложении Flash Player возникает ошибка выполнения (код 2174). Используйте метод FileReference.cancel() для остановки выполняющейся операции. Это ограничение применяется только в приложении Flash Player 10. В предыдущих версиях Flash Player ограничение на одновременное выполнение нескольких операций не действует.

В Adobe AIR диалоговое окно загрузки не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Начинает загрузку локального файла, выбранного пользователем. Несмотря на то, что Flash Player не имеет ограничений в отношении размера передаваемых, загружаемых или сохраняемых файлов, гарантированно проигрыватель поддерживает обработку информации, объем которой не превышает 100 МБ. Для содержимого, воспроизводимого в проигрывателе Flash Player, необходимо вызвать метод FileReference.browse() или FileReferenceList.browse() перед вызовом метода load(). Однако содержимое, воспроизводимое в изолированной программной среде приложения AIR, может вызывать метод load() объекта File без необходимости предварительного вызова метода browse(). (Класс File в AIR является расширением класса FileReference.)

Прослушиватели получают события для определения состояния, успешности или сбоя загрузки. Несмотря на то, что с помощью объекта FileReferenceList можно предоставить пользователям возможность выбирать для загрузки сразу несколько файлов, загружать эти файлы следует по одному. Для этого надо выполнить итерации в отношении массива FileReferenceList.fileList объектов FileReference.

Adobe AIR также включает класс FileStream, который предоставляет больше возможностей для чтения файлов.

Функции FileReference.upload(), FileReference.download(), FileReference.load() и FileReference.save() не являются блокирующими. Эти функции возвращаются после вызова до завершения операции передачи файла. Кроме этого, если объект FileReference покинет область приложения, любая незавершенная операция в отношении данного объекта будет отменена в момент его выхода из области приложения. Следите за тем, чтобы объект FileReference оставался в области приложения на всем протяжении операции отправки, загрузки или сохранения.

При успешном завершении загрузки файла его содержимое сохраняется как массив байтов в свойстве data объекта FileReference.

Применяются следующие правила безопасности:

• Операции загрузки запрещены, если вызывающий SWF-файл находится в ненадежной локальной изолированной среде.
• По умолчанию, взаимодействие между изолированными средами запрещено. Чтобы обеспечить доступ к ресурсу, web-сайт может добавить файл междоменной политики.
• Можно запретить использование файлом этого метода путем установки параметра allowNetworking для тегов object и embed на странице HTML, содержащей SWF-содержимое.

Однако эти ограничения не применимы к содержимому AIR в изолированной программной среде приложения.

Обратите внимание, что при публикации в приложении Flash Player 10 или AIR 1.5 одновременно может быть активна только одна из следующих операций: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). В противном случае в приложении возникает ошибка времени выполнения (код 2174). Используйте метод FileReference.cancel() для остановки выполняющейся операции. Это ограничение применяется только к Flash Player 10 и AIR 1.5. В предыдущих версиях Flash Player или AIR отсутствует ограничение на одновременное выполнение нескольких операций.

В Adobe AIR диалоговое окно выбора файлов не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Связанные элементы API

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Запрашивает разрешение на доступ к файловой системе.

Открывает диалоговое окно, позволяющее пользователю сохранить файл в локальной файловой системе. Несмотря на то, что Flash Player не имеет ограничений на размер отправляемых, загружаемых или сохраняемых файлов, официально проигрыватель поддерживает обработку информации, объем которой не превышает 100 МБ.

Сначала метод save() открывает диалоговое окно операционной системы, в котором пользователь должен ввести имя файла и выбрать место на локальном компьютере для сохранения этого файла. После того как пользователь выберет нужное место и подтвердит операцию сохранения (например, путем нажатия кнопки «Сохранить»), начнется процесс сохранения. Прослушиватели получают события для определения состояния, успешности или сбоя операции сохранения. Для определения состояния диалогового окна и операции сохранения после вызова метода save(), ваш код должен предусматривать прослушивание таких событий как cancel, open, progress и complete.

Adobe AIR также включает класс FileStream, который предоставляет больше возможностей для сохранения файлов в локальной системе

Функции FileReference.upload(), FileReference.download(), FileReference.load() и FileReference.save() не являются блокирующими. Эти функции возвращаются после вызова до завершения операции передачи файла. Кроме этого, если объект FileReference покинет область приложения, любая незавершенная операция в отношении данного объекта будет отменена в момент его выхода из области приложения. Следите за тем, чтобы объект FileReference оставался в области приложения на всем протяжении операции отправки, загрузки или сохранения.

При успешном сохранении файла свойства объекта FileReference заполняются свойствами локального файла. Событие complete отправляется при успешном завершении операции сохранения.

Единовременно может выполняться только один сеанс browse() или save() (так как в любой момент времени можно вызвать только одно диалоговое окно).

В приложении Flash Player этот метод можно успешно вызвать только в ответ на пользовательское событие (например, в обработчике событий щелчка мыши или нажатия клавиши). В противном случае в результате вызова этого метода в приложении Flash Player возникает исключение Error. Это ограничение не применимо к содержимому AIR в изолированной программной среде приложения.

В Adobe AIR диалоговое окно сохранения не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Параметры

Связанные элементы API

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Запускает загрузку файла на удаленный сервер. Несмотря на то, что Flash Player не имеет ограничений на размер загружаемых файлов, официально проигрыватель поддерживает обработку информации, объем которой не превышает 100 МБ.Перед тем как вызвать данный метод, следует вызвать метод FileReference.browse() или FileReferenceList.browse().

В Adobe AIR для класса File, который расширяет класс FileReference, можно использовать метод upload() для загрузки любого файла. Для класса FileReference (во Flash Player), пользователь сначала должен выбрать файл.

Прослушиватели получают события для определения состояния, успешного выполнения или сбоя загрузки. Несмотря на то, что с помощью объекта FileReferenceList можно предоставить пользователям возможность выбирать для загрузки сразу несколько файлов, загружать эти файлы следует по одному. Для этого надо выполнить итерации в отношении массива FileReferenceList.fileList объектов FileReference.

Функции FileReference.upload() и FileReference.download() не являются блокирующими. Эти функции возвращаются после вызова до завершения операции передачи файла. Кроме этого, если объект FileReference покинет зону действия, любая незавершенная отправка или загрузка в отношении данного объекта будет отменена в момент его выхода из зоны действия. Следите за тем, чтобы объект FileReference оставался в области действия на всем протяжении операции загрузки.

Файл загружается на URL-адрес, указанный в параметре url. В качестве URL-адреса должен выступать сценарий сервера, сконфигурированный на принятие загружаемых данных. Проигрыватель Flash Player загружает файлы с помощью метода POST по протоколу HTTP. Сценарий сервера, обрабатывающий загрузку, должен ожидать запрос POST со следующими элементами:

• Content-Type со значением multipart/form-data
• Content-Disposition, у которого атрибут name имеет по умолчанию значение Filedata, а атрибут filename указывает имя исходного файла.
• Двоичное содержимое файла

Нельзя подключаться к общепринятым зарезервированным портам. Полный список заблокированных портов см. в разделе «Ограничение API-интерфейсов сетевого подключения» в руководстве ActionScript 3.0 Developer's Guide (руководстве разработчика по ActionScript 3.0).

Образец запроса POST представлен в описании параметра uploadDataFieldName. Параметры POST или GET можно загрузить на сервер вместе с методом upload() (см. описание параметра request).

Если параметр testUpload имеет значение true, а размер передаваемого файла превышает 10 Кб, то в ОС Windows проигрыватель Flash Player сначала отправляет операцию тестовой загрузки POST с нулевым содержимым. Это выполняется до загрузки фактического файла с целью проверки механизма передачи. Затем проигрыватель Flash Player отправляет вторую операцию POST, в которой находится фактическое содержимое файла. При обработке файлов, размер которых не превышает 10 КБ, проигрыватель Flash Player выполняет отдельную загрузку POST, используя при этом фактическое содержимое загружаемого файла. На компьютерах Macintosh проигрыватель Flash Player не выполняет операции тестовой передачи POST.

Примечание. Если ваш сервер требует аутентификации пользователей, только Flash-приложения, запущенные в браузере (то есть с использованием дополнительного модуля браузера или элемента управления ActiveX), могут представить пользователю диалоговое окно для ввода имени пользователя и пароля (для аутентификации) и только потом перейти к загрузкам. При загрузке с помощью дополнительного модуля или элемента управления ActiveX, а также при загрузке данных посредством автономного или внешнего проигрывателя происходит сбой передачи файлов.

При использовании данного метода необходимо продумать модель безопасности проигрывателя Flash Player:

• Операции загрузки запрещены, если вызывающий SWF-файл находится в ненадежной локальной изолированной среде.
• По умолчанию, взаимодействие между изолированными средами запрещено. Чтобы обеспечить доступ к ресурсу, web-сайт может добавить файл политик для URL.
• Можно запретить использование SWF-файлом этого метода путем установки параметра allowNetworking для тегов object и embed на странице HTML, содержащей SWF-содержимое.

Однако в Adobe AIR эти ограничения по безопасности не распространяются на содержимое в изолированной программной среде безопасности application (содержимое, установленное с приложением AIR).

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

Примите во внимание эти особенности, поскольку в приложение Flash Player добавлены новые функции. При публикации в приложении Flash Player 10 одновременно может быть активна только одна из следующих операций: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). В противном случае в приложении Flash Player возникает ошибка выполнения (код 2174). Используйте метод FileReference.cancel() для остановки выполняющейся операции. Это ограничение применяется только в приложении Flash Player 10. В предыдущих версиях Flash Player ограничение на одновременное выполнение нескольких операций не действует.

Параметры

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Связанные элементы API

Инициируют отправку файла в URL-адрес без кодировки. Тогда как метод upload() кодирует файл в виде пакета данных, метод uploadUnencoded() передает содержимое файла как есть в теле запроса НТТР. Используйте метод uploadUnencoded(), если отправляемые данные уже закодированы в формате, понятном для получающего сервера. Обычно метод uploadeUnencoded() используется вместе с методом HTTP/WebDAV PUT.

Параметры

Связанные элементы API

Отправляется, когда загрузка файла прервана пользователем в диалоговом окне обзора файлов. Проигрыватель Flash Player не отправляет это событие, если пользователь отменяет загрузку каким-либо другим способом (путем закрытия браузера или остановки текущего приложения).

Это событие имеет следующие свойства:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Отправляется, когда загрузка завершается или в ходе отправки создается код состояния HTTP со значением 200. При загрузке файла это событие отправляется в тот момент, когда Flash Player или Adobe AIR завершает загрузку всего файла на диск. При загрузке файла это событие отправляется после того, как Flash Player или Adobe AIR получает от принимающего сервера код состояния НТТР со значением 200.

Это событие имеет следующие свойства:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Связанные элементы API

Отправляется, если вызов метода upload() или uploadUnencoded() пытается обратиться к данным через HTTP, и Adobe AIR может обнаружить и вернуть код состояния для запроса.

Константа HTTPStatusEvent.HTTP_RESPONSE_STATUS определяет значение свойства type объекта события httpResponseStatus.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется, когда при загрузке происходит ошибка и доступен код состояния HTTP, описывающий ошибку. Отправляется событие httpStatus, а после него сразу же отправляется событие ioError.

Событие httpStatus отправляется только в случае сбоя операции загрузки. Для содержимого, запущенного в проигрывателе Flash Player, это событие не применимо для сбоя загрузки. Если сбой загрузки происходит по причине ошибки HTTP, данная ошибка представляется как ошибка ввода-вывода.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется в случае ошибки при загрузке. Сбой при передачи файла может возникнуть по одной из следующих причин:

• Ошибка ввода-вывода возникает в тот момент, когда проигрыватель считывает, записывает или передает файл.
• SWF-файл пытается загрузить файл на сервер, требующий проверки подлинности (имя пользователя и пароль). В процессе отправки Flash Player или Adobe AIR не дает пользователям возможности ввести пароли. Если SWF-файл попытается передать файл на сервер, требующий проверки подлинности, произойдет сбой отправки.
• SWF-файл пытается загрузить файл с сервера, требующего проверки подлинности, в рамках автономного или внешнего проигрывателя. Во время загрузки автономные и внешние проигрыватели не обеспечивают пользователей возможностью ввода паролей. Если SWF-файл в этих проигрывателях пытается загрузить файл с сервера, требующего проверки подлинности, то происходит сбой загрузки. Загрузка файла может быть успешно выполнена только в элементе управления ActiveX, дополнительных модулях обозревателей и в среде выполнения Adobe AIR.
• Значение, переданное параметру url в методе upload(), содержит недопустимый протокол. Допустимые протоколы: HTTP и HTTPS.

Важно! Только приложения, выполняемые в браузере (то есть использующие дополнительный модуль браузера или элемент управления ActiveX) и содержимое, выполняемое в Adobe AIR, могут сначала показывать диалоговое окно с запросом имени пользователя и пароля для проверки подлинности и только после этого открывать окно загрузки. Для отправки данных с помощью версии Flash Player, подключаемой к обозревателю или использующей элемент управления ActiveX, или для загрузки с помощью автономного или внешнего проигрывателя, отправка файлов заканчивается ошибкой.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется в начале операции отправки или загрузки.

Это событие имеет следующие свойства:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Связанные элементы API

Отправляется, когда приложение запрашивает разрешение на доступ к файловой системе. Проверяет значение свойства status, чтобы определить, предоставлено разрешение или нет

Связанные элементы API

Отправляется периодически в ходе операции загрузки или передачи файла. Событие progress отправляется в процессе передачи проигрывателем Flash Player байтов на сервер. Оно периодически отправляется в течение всей операции передачи, даже если эта операция в конечном итоге не становится успешной. Чтобы определить, когда произойдет фактическое успешное завершение передачи файла, следует ожидать появления события complete.

В некоторых случаях события progress не могут быть получены. Например, при отправке файла очень небольшого размера или при очень быстрой отправке или загрузке событие progress может быть не передано.

Невозможно определить состояние процесса загрузки файла на платформах Macintosh более ранней версии, чем OS X 10.3. Событие progress вызывается в течение операции загрузки, однако значением свойства bytesLoaded события progress является -1, что указывает на невозможность определения состояния.

Это событие имеет следующие свойства:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Связанные элементы API

Отправляется, когда путем вызова метода FileReference.upload() или FileReference.download() предпринимается попытка передать файл на сервер или получить файл с сервера, находящегося за пределами изолированной среды вызывающего объекта. Значением текстового свойства, описывающего возникшую специфическую ошибку, обычно является securitySandboxError. Возможно, вызывающий SWF-файл произвел попытку обращения к SWF-файлу за пределами своего домена, на что у него нет соответствующего разрешения. Для исправления данной ошибки можно использовать файл политики для URL.

В Adobe AIR эти ограничения по безопасности не применяются к содержимому в изолированной программной среде безопасности приложения.

В Adobe AIR эти ограничения по безопасности не применяются к содержимому в изолированной программной среде безопасности приложения.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется, когда пользователь выбирает файл для загрузки в диалоговом окне обзора файлов. (Это диалоговое окно открывается при вызове метода FileReference.browse(), FileReferenceList.browse() или FileReference.download().) Когда пользователь выбирает файл и подтверждает эту операцию (например, путем нажатия кнопки «ОК»), происходит заполнение свойств объекта FileReference.

Для содержимого, выполняемого в Flash Player или за пределами изолированной программной среды приложения в среде выполнения Adobe AIR, событие select ведет себя немного по-разному в зависимости от вызывающего его метода. Когда событие select отправляется после вызова метода browse(), Flash Player или приложение AIR получает возможность считывания всех свойств объекта FileReference, так как выбранный пользователем файл находится в локальной файловой системе. Когда событие select возникает после вызова download(), Flash Player или приложение AIR может считать только свойство name, так как на момент отправки события select файл еще не загружен в локальную файловую систему. После того как файл загружен и событие complete отправлено, Flash Player или приложение AIR может считывать все остальные свойства объекта FileReference.

Это событие имеет следующие свойства:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Отправляется после получения с сервера данных об успешном завершении загрузки. Это событие не отправляется, если сервер не возвращает данные.

Это событие имеет следующие свойства:

Примечание. Чтобы запустить данный пример, следует изменить свойство uploadURL.url, чтобы вместо фиктивного адреса в этом примере оно указывало фактический (действующий) URL-адрес. URL-адрес должен указывать на файл yourUploadHandlerScript.cfm в корневом web-каталоге указанного URL-адреса. В зависимости от вашей конфигурации, чтобы обеспечить сетевой доступ к этому файлу, может также потребоваться скомпилировать SWF-файл с установленным для параметра «Безопасность локального воспроизведения» режимом «Доступ только к сети» или обновить параметры безопасности проигрывателя Flash Player.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}