CameraRoll  - AS3

Определяет, предоставлено или нет приложению разрешение на доступ к программе «Фотопленка».

Связанные элементы API

Поддерживается ли метод CameraRoll.addBitmapData(). В настоящий момент эта функция поддерживается только в приложениях AIR на мобильных устройствах.

Сообщает о наличии поддержки метода CameraRoll.browseForImage(). В настоящий момент эта функция поддерживается только в приложениях AIR на мобильных устройствах.

Создает объект CameraRoll.

В среде ActionScript поддерживается только одна библиотека мультимедиа. Все объекты CameraRoll сохраняются в одном хранилище изображений.

Добавляет изображение в альбом «Фотопленка» устройства.

Чтобы в среде выполнения узнать, поддерживает ли приложение метод CameraRoll.addBitmapData(), проверьте свойство CameraRoll.addBitmapData.

Параметры

Открывает диалоговое окно просмотра изображений, в котором пользователь может выбрать существующее изображение в альбоме «Фотопленка» устройства.

Когда пользователь выбирает изображение, этот экземпляр CameraRoll отправляет событие select, содержащее объект MediaEvent. Используйте свойство data объекта MediaEvent для загрузки изображения. Свойство data является объектом MediaPromise, который можно загрузить с помощью метода loadFilePromise() класса Loader. Обратите внимание, что объект MediaPromise содержит действительный объект файла на некоторых платформах (Blackberry Tablet OS), в отличие от других платформ (iOS и Android). При использовании метода loadFilePromise() изображение загружается правильно на всех платформах. Чтобы получить доступ к необработанным данным из объекта мультимедиа, можно открыть источник данных, предоставленный в предварительном образе мультимедиа, и прочитать данные с помощью методов интерфейса IDataInput.

Чтобы в cреде выполнения узнать, поддерживает ли программа метод CameraRoll.browseForImage(), проверьте свойство CameraRoll.supportsBrowseForImage.

В ОС iOS (только на устройстве iPad) можно запросить определенный размер диалогового окна просмотра изображения. Можно также указать область экрана, которую не должно закрывать диалоговое окно просмотра изображения. Этот запрос работает только на устройстве iPad, поскольку на этом устройстве браузер изображений не занимает весь экран.

Чтобы запросить параметры размера и размещения для окна просмотра изображений (для устройства iPad), передайте объект CameraRollBrowseOptions в метод browseForImage(). Без параметров этот метод размещает диалоговое окно в верхнем левом углу экрана с использованием параметров системы по умолчанию для установки размеров диалогового окна.

Параметры

Дополнительно

Связанные элементы API

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Запрашивает разрешение на доступ к системной медиатеке или программе «Фотопленка».

Отправляется, когда пользователь отменяет операцию просмотра изображений, не выбирая изображение.

Это событие имеет следующие свойства:

Сигнализирует о том, что операция addBitmapData() успешно завершена.

Это событие имеет следующие свойства:

Событие error отправляется при возникновении ошибки.

Источники ошибок:

• Невозможно открыть средство просмотра изображений.
• Средство просмотра изображений уже используется.
• Программа AIR, работающая в фоновом режиме, пытается выполнить просмотр изображения.
• Невозможно добавить изображение в библиотеку мультимедиа.
• Вызванный метод не поддерживается на устройстве.
• Приложение AIR пытается загрузить удаленное изображение без подключения к сети Интернет.

Это событие имеет следующие свойства:

Отправляется, когда приложение запрашивает разрешение на доступ к программе «Фотопленка». Проверяет значение свойства status, чтобы определить, предоставлено разрешение или нет

Связанные элементы API

Отправляется, когда пользователь выбирает изображение в библиотеке мультимедиа устройства.

Объект MediaEvent, отправленный для этого события, предоставляет доступ к выбранному мультимедийному содержимому.

Задает значение свойства type объекта события MediaEvent. Это событие имеет следующие свойства: