Loader  - AS3

Содержит корневой экранный объект SWF-файла или изображения (JPG, PNG или GIF), загруженного с помощью методов load() или loadBytes().

Связанные элементы API

Возвращает объект LoaderInfo, соответствующий загружаемому объекту. Объекты LoaderInfo совместно используются объектом Loader и загруженным объектом содержимого. Объект LoaderInfo предоставляет сведения о процессе загрузки и статистику по загружаемому файлу.

События, связанные с загрузкой, отправляются объектом LoaderInfo, на который ссылается свойство contentLoaderInfo объекта Loader. Свойство contentLoaderInfo задается для действительного объекта LoaderInfo, даже если содержимое еще не загружено, чтобы можно было добавить прослушиватели событий объекта перед загрузкой.

Чтобы обнаружить неперехваченные ошибки, которые происходят в загруженном SWF, используйте свойство Loader.uncaughtErrorEvents, а не Loader.contentLoaderInfo.uncaughtErrorEvents.

Связанные элементы API

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Объект, который отправляет событие uncaughtError при возникновении необработанной ошибки в SWF-файле, загруженном объектом Loader. Неперехваченные ошибки возникают, когда ошибка выдается за пределами блока try..catch или когда отправляется объект ErrorEvent, для которого не зарегистрирован прослушиватель.

Обратите внимание, что свойство uncaughtErrorEvents объекта Loader отправляет события, которые передаются по восходящей цепочке через него, а не создаются им непосредственно. Оно никогда не отправляет событие uncaughtErrorEvent в фазе цели. Оно только отправляет события в фазах захвата и восхождения по цепочке. Чтобы обнаружить неперехваченную ошибку в текущем SWF (SWF-файле, в котором определен объект Loader), используйте свойство LoaderInfo.uncaughtErrorEvents.

Если содержимое, загруженное объектом Loader, является SWF-файлом версии AVM1 (ActionScript 2), неперехваченные ошибки в этом файле не приводят к отправке события uncaughtError.

Связанные элементы API

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Создает объект Loader, с помощью которого можно загружать файлы, например: SWF, JPEG, GIF или PNG. Вызовите метод load(), чтобы загрузить ресурс в качестве дочернего объекта экземпляра Loader. После этого можно добавить объект Loader в список отображения (например, с помощью метода addChild() экземпляра DisplayObjectContainer). Ресурс отображается в рабочей области по мере загрузки.

Экземпляр Loader можно также использовать автономно, то есть без добавления в контейнер объекта в списке отображения. В этом режиме экземпляр Loader может использоваться для загрузки SWF-файла, содержащего дополнительные модули приложения.

О завершении загрузки SWF-файла можно узнать, используя события объекта LoaderInfo, связанные со свойством contentLoaderInfo объекта Loader. На этом этапе можно выполнить код в модуле SWF-файла, чтобы инициализировать и запустить модуль. В автономном режиме экземпляр Loader можно использовать для загрузки SWF-файла, содержащего компоненты и мультимедийные ресурсы. О завершении загрузки компонентов можно узнать с помощью оповещений о событиях объекта LoaderInfo. На этом этапе приложение может начать использовать компоненты и мультимедийные ресурсы в библиотеке SWF-файла, создав экземпляры классов ActionScript 3.0 для их представления.

Чтобы узнать состояние объекта Loader, отслеживайте следующие события, которые объект LoaderInfo связал со свойством contentLoaderInfo объекта Loader.

• Событие open передается после начала загрузки.
• Событие ioError или securityError передается, если загрузка файла невозможна или если в процессе загрузки произошла ошибка.
• Событие progress отправляется постоянно по ходу загрузки файла.
• Событие complete передается после завершения загрузки файла, но до того, как станут доступны методы и свойства загруженного фрагмента ролика.
• Событие init передается после того, как станут доступны свойства и методы загруженного SWF-файла, чтобы можно было приступать к работе с ним. Это событие передается перед обработчиком complete. В потоковых SWF-файлах событие init может происходить намного раньше, чем событие complete. Для большинства целей следует использовать обработчик init.

Примечания (только для iOS) В приложениях AIR для iOS SWF-файлы с кодом ActionScript можно загружать только из пакета приложения. Это ограничение относится ко всем элементам ActionScript, даже к ресурсам, имеющим имена классов для ActionScript. При загрузке любого SWF-файла необходимо указать тот же домен приложения, что и у родительского SWF.

В версиях среды, выпущенных до AIR 3.6, могут быть загружены только SWF-файлы, не содержащие байт-код ActionScript, независимо от того, загружаются ли они из пакета приложения или через сеть. В качестве альтернативы внешнему SWF-файлу с кодом ActionScript можно использовать библиотеку SWC, связав ее с основным SWF.

Эти ограничения не действуют при запуске приложения в эмуляторе iOS (ipa-test-interpreter-simulator или ipa-debug-interpreter-simulator) или в режиме интерпретатора (ipa-test-interpreter или ipa-debug-interpreter).

Связанные элементы API

Отменяет операцию выполняемого в данный момент метода load() для экземпляра класса Loader.

Связанные элементы API

Загружает SWF-, JPEG-, прогрессивные JPEG-, неанимированные GIF- или PNG-файлы в объект, являющийся дочерним для объекта Loader. Если загружается анимированный GIF-файл, отображается только первый кадр. Так как объект Loader может содержать только один дочерний объект, отправка последующего запроса load() прекращает обработку предыдущего, если он еще ожидает выполнения, и начинается новая загрузка.

Примечание. В AIR 1.5 и Flash Player 10 максимальный размер загруженного изображения составляет 8,191 пикселей в ширину или высоту, а общее количество пикселей не может превышать 16,777,215. (Т. е. если ширина загруженного изображения составляет 8,191 пикселей, его высота не может быть больше 2 048 пикселей.) В проигрывателе Flash Player 9 и более ранних версий, а также в AIR 1.1 и более ранних версий, это ограничение составляет 2 880 пикселей в высоту и 2 880 пикселей в ширину.

SWF-файл или изображение, загруженное в объект Loader наследует свойства положения, поворота и масштаба родительских экранных объектов объекта Loader.

Используйте метод unload() для удаления роликов или изображений, загруженных с помощью этого метода, или для отмены выполняемой операции загрузки.

Можно запретить использование SWF-файлом этого метода путем установки параметра allowNetworking для тегов object и embed на странице HTML, содержащей SWF-содержимое.

Замечания для iOS

В приложениях AIR для iOS SWF-файлы с кодом ActionScript можно загружать только из пакета приложения. Это ограничение относится ко всем элементам ActionScript, даже к ресурсам, имеющим имена классов для ActionScript. При загрузке любого SWF-файла необходимо указать тот же домен приложения, что и у родительского SWF, как показано в следующем примере:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Кроме того, в ОС iOS невозможно загрузить SWF-файл, который содержит один код ActionScript ByteCode (ABC), затем выгружает и не перезагружает его. При попытке сделать это среда выполнения выдает ошибку 3764.

В версиях среды, выпущенных до AIR 3.6, могут быть загружены только SWF-файлы, не содержащие байт-код ActionScript, независимо от того, загружаются ли они из пакета приложения или через сеть. В качестве альтернативы внешнему SWF-файлу с кодом ActionScript можно использовать библиотеку SWC, связав ее с основным SWF.

Эти ограничения не действуют при запуске приложения в эмуляторе iOS (ipa-test-interpreter-simulator или ipa-debug-interpreter-simulator) или в режиме интерпретатора (ipa-test-interpreter или ipa-debug-interpreter).

Loader и безопасность

При использовании данного метода необходимо учесть модель безопасности проигрывателя Flash Player, рассмотренную в описании класса Loader.

В приложении Flash Player 10 и более поздней версии при использовании типа содержимого multipart (например, multipart/form-data), в котором содержится загрузка (обозначена параметром filename в заголовке content-disposition в теле оператора POST), к операции POST применяются правила безопасности для загрузок:

• Операция POST должна быть выполнена в ответ на действие, инициированное пользователем, такое как щелчок мыши или нажатие клавиши.
• Если операция POST является междоменной (назначением операции POST не является сервер, на котором содержится SWF-файл, отправляющий запрос POST), целевой сервер должен предоставить файл политик URL, в котором разрешен междоменный доступ.

Кроме того, все объекты типа содержимого multipart должны иметь допустимый синтаксис (в соответствии со стандартом RFC2046). Если синтаксис является недопустимым, к операции POST применяются правила безопасности, действующие для загрузок.

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

Параметры

Связанные элементы API

Выполняет загрузку из двоичных данных, которые хранятся в объекте ByteArray.

Метод loadBytes() является асинхронным. Прежде чем обращаться к свойствам загруженного объекта, необходимо дождаться события инициации.

При использовании данного метода необходимо учесть модель безопасности проигрывателя Flash Player, рассмотренную в описании класса Loader.

Примечание (только для iOS) В приложениях AIR для iOS SWF-файлы с кодом ActionScript можно загружать только из пакета приложения. Это ограничение относится ко всем элементам ActionScript, даже к ресурсам, имеющим имена классов для ActionScript. При загрузке любого SWF-файла необходимо указать тот же домен приложения, что и у родительского SWF.

В средах ранее AIR 3.6 данный метод не действует на платформе iOS.

Параметры

Связанные элементы API

Загружает экземпляр IFilePromise.

Метод loadFilePromise принимает объект IFilePromise и загружает бинарные данные. Если данные являются последовательным потоком, например видео, дождитесь событий инициализации или хода выполнения перед доступом к свойствам загруженного объекта. Или дождитесь события завершения, чтобы убедиться, что данные полностью загружены.

При использовании данного метода необходимо учесть модель безопасности проигрывателя Flash Player, рассмотренную в описании класса Loader.

Параметры

Связанные элементы API

Удаляет дочерний объект этого объекта Loader, загруженный с помощью метода load(). Параметр property связанного объекта LoaderInfo сброшен до значения null. Дочерний объект не обязательно удаляется, так как на него могут ссылаться другие объекты. Однако он больше не является дочерним для объекта Loader.

При вызове метода unload() свойство contentLoaderInfo объекта Loader принимает значение null. Все визуальные ресурсы, загруженные вместе с этим SWF, выгружаются из памяти. Определения классов ActionScript из загруженного SWF остаются в памяти, поэтому код в том домене приложения, куда был загружен SWF, может и далее получать доступ к экземплярам этих классов и создавать новые экземпляры.

Примечание (только для iOS). В средах ранее AIR 3.6 данный метод не действует на платформе iOS.

Перед загрузкой дочернего SWF-файла лучше всего явно закрыть все потоки объектов дочернего SWF-файла, таких как LocalConnection, NetConnection, NetStream и Sound. В противном случае в дочернем SWF-файле может продолжаться воспроизведение звука, несмотря на его загрузку. Чтобы закрыть потоки в дочернем SWF-файле, добавьте для него прослушиватель события unload. Когда родительский объект вызывает Loader.unload(), дочернему объекту отправляется событие unload. Следующий код показывает, как это делается.

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Связанные элементы API

Пытается выгрузить содержимое дочернего SWF-файла и прекращает выполнение команд из загруженных SWF-файлов. Данный метод пытается выгрузить SWF-файлы, загруженные при помощи метода Loader.load() или Loader.loadBytes(), удалив ссылки на объекты EventDispatcher, NetConnection, Timer, Sound или Video дочернего SWF-файла. В результате для дочернего файла SWF и его списка отображения выполняются следующие действия:

• Останавливается воспроизведение звука.
• Удаляются прослушиватели событий рабочей области.
• Удаляются прослушиватели событий enterFrame, frameConstructed, exitFrame, activate и deactivate.
• Останавливаются таймеры.
• Отсоединяются экземпляры Camera и Microphone.
• Прекращается воспроизведение видеороликов.

При вызове метода unloadAndStop() свойство contentLoaderInfo объекта Loader принимает значение null. Все визуальные ресурсы, загруженные вместе с этим SWF, выгружаются из памяти. Определения классов ActionScript из загруженного SWF остаются в памяти, поэтому код в том домене приложения, куда был загружен SWF, может и далее получать доступ к экземплярам этих классов и создавать новые экземпляры.

Примечание (только для iOS). В средах ранее AIR 3.6 данный метод не действует на платформе iOS.

Параметры

Связанные элементы API

1. Создается свойство url, описывающее местоположение и имя файла изображения.
2. В конструкторе LoaderExample создается новый объект Loader с именем loader и затем передается методу configureListeners(), описанному в шаге 3.
3. Конструктор создает новый экземпляр объекта URLRequest, request, и передает url, чтобы сообщить имя и местоположение файла.
4. Объект request передается методу load() объекта loader для загрузки изображения в список отображения.
5. Прослушиватель событий clickHandler зарегистрировал событие click для средства загрузки. После щелчка мыши загруженное изображение выгружается.
6. Метод configureListeners() добавляет семь прослушивателей событий с помощью следующих методов:
   • Метод completeHandler() выполняется по завершении загрузки изображения.
   • Метод httpStatusHandler() выполняется, если изображение загружено не локально и только если доступен сетевой запрос и проигрыватель Flash Player может его обнаружить.
   • Метод initHandler() выполняется перед методом completeHandler() и после метода progressHandler(). Как правило, событие init более полезно при загрузке SWF-файлов.
   • Метод ioErrorHandler() выполняется, если файла изображения нет или он недоступен.
   • Метод openHandler() выполняется при первом открытии изображения.
   • Метод progressHandler() выполняется, когда начинается и когда заканчивается загрузка файла изображения.
   • Метод unLoadHandler() выполняется при выгрузке с использованием метода unload(), когда пользователь нажимает на изображение.

Необходимо учитывать следующие требования.

• В этом примере требуется поместить файл с именем Image.gif в тот же каталог, что и компилированный SWF-файл. Используйте изображение, область которого соответствует размерам основного SWF-файла.
• Хотя в этом примере используются все события, доступные для объекта LoaderInfo, в большинстве случаев требуется только та или иная подгруппа. В частности, при загрузке только файла изображения можно использовать только событие complete (и, возможно, событие ioError), если загружается локальное изображение.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}