SoundMixer  - AS3

Указывает режим воспроизведения аудио для всех объектов Sound. На мобильных устройствах это свойство задает приоритеты звука и значения по умолчанию в соответствии с идиомами платформы. В компьютерных системах и средах телевизионных устройств режимы воспроизведения звука не имеют функциональных различий.

Действительные значения для этого свойства определены в классе AudioPlaybackMode.

Примечание. Если в ОС iOS одно приложение задает audioPlaybackMode=AudioPlaybackMode.VOICE, другие приложения не могут изменить его на AudioPlaybackMode.MEDIA.

Используйте режим AudioPlaybackMode.VOICE в течение минимально допустимого времени и после окончания голосового вызова попытайтесь переключиться в режим AudioPlaybackMode.MEDIA, как только это будет возможно, чтобы позволить другим программам воспроизведение в режиме мультимедиа.

При изменении режима воспроизведения аудиозаписей в ОС iOS работа встроенных приложений, воспроизводящих музыку, ненадолго приостанавливается.

Значением по умолчанию является AudioPlaybackMode.MEDIA.

Связанные элементы API

Число секунд для предварительной загрузки внедренного потокового звука в буфер перед началом передачи звука в поток. Данные в загруженном звуке, включая время буферизации, не могут быть получены SWF-файлом, находящимся в другом домене, если не используется файл междоменной политики. Дополнительные сведения о безопасности и звуке см. в описании класса Sound. Данные в загруженном звуке, включая время буферизации, не могут быть получены кодом файла, находящегося в другом домене, если не используется файл междоменной политики. Однако код в изолированной программной среде приложения AIR имеет доступ к данным звуковых файлов, полученных из любого источника. Дополнительные сведения о безопасности и звуке см. в описании класса Sound.

Свойство SoundMixer.bufferTime затрагивает только время буферизации для встроенных потоковых звуков в SWF-файле и не зависит от динамически созданных объектов Sound (т.е. объектов Sound, созданных в ActionScript). Значение свойства SoundMixer.bufferTime не может переопределять или задавать значение по умолчанию для времени буферизации, заданного объектом SoundLoaderContext, который передан методу Sound.load().

Связанные элементы API

Объект SoundTransform, управляющий глобальными свойствами звука. Объект SoundTransform включает свойства для настройки громкости, панорамы, назначения левого и правого динамиков. Объект SoundTransform, использованный в данном свойстве, передает окончательные параметры звука, которые применяются ко всем звукам после задания отдельных параметров звука.

Связанные элементы API

Включает или выключает громкоговоритель, когда устройство находится в режиме голосовой связи. По умолчанию на смартфонах для вывода аудио используется гарнитура, если значение SoundMixer.audioPlaybackMode равно AudioPlaybackMode.VOICE. Свойство useSpeakerphoneForVoice позволяет переопределить вывод по умолчанию, чтобы можно было реализовать кнопку громкоговорителя в приложении телефона. Это свойство не действует в режимах, отличных от AudioPlaybackMode.VOICE. В компьютерных системах и средах телевизионных устройств это свойство не работает.

Примечание Если в ОС iOS приложение задает audioPlaybackMode=VOICE, а другое приложение также воспроизводит содержимое в голосовом режиме, задать useSpeakerphoneForVoice=true невозможно.

Примечание. На платформе Android необходимо задать android.permission.MODIFY_AUDIO_SETTINGS в дескрипторе приложения AIR, или изменение этого значения не будет иметь эффекта. Кроме того, настройка является глобальной настройкой устройства. Другие приложения, выполняющиеся на устройстве, могут изменять настройку базового устройства в любое время.

Значением по умолчанию является false.

Связанные элементы API

Определяет, являются ли какие-либо звуки недоступными из-за ограничений безопасности. Например, звук, загруженный не с того же домена, в котором находится вызывающее этот метод содержимое, будет недоступен, если на его сервере нет файла политики URL-адресов, предоставляющего доступ к домену этого содержимого. Звук будет загружен и воспроизведен, но для недоступных звуков не выполняются операции более низкого уровня, такие как получение метаданных ID3 для звука.

В отношении содержимого приложений AIR, находящегося в изолированной программной среде безопасности приложения, вызов этого метода всегда возвращает значение false. Все звуки, включая те, что загружены с других доменов, доступны для содержимого в изолированной программной среде безопасности приложения.

Связанные элементы API

Создает снимок текущей звуковой волны и помещает его в заданный объект ByteArray. Значения форматируются как нормализованные значения с плавающей запятой в диапазоне от -1 до 1. Объект ByteArray, передаваемый параметру outputArray, перезаписывается новыми значениями. Размер созданного объекта ByteArray фиксируется на 512 значениях с плавающей запятой, где первые 256 значений представляют левый канал, а следующие 256 значений — правый.

Примечание. Этот метод учитывает ограничения безопасности для локального файла и для междоменной загрузки. При работе с локальными файлами или звуками, загруженными с сервера, находящегося не в том же домене, что и вызывающее содержимое, возможно, потребуется создать файл междоменной политики, чтобы преодолеть ограничения изолированной программной среды. Дополнительные сведения см. в описании класса Sound. Более того, этот метод нельзя использовать для извлечения данных из потоков RTMP, даже если он вызывается содержимым, находящимся в том же домене, что и сервер RTMP.

Этот метод поддерживается через протокол RTMP в Flash Player 9.0.115.0 и более поздних версиях и в Adobe AIR. Можно контролировать потоки на сервере Flash Media Server в сценарии, выполняемом на стороне сервера. Дополнительные сведения см. в разделах о свойствах Client.audioSampleAccess и Client.videoSampleAccess в документе Справочник по языку ActionScript на стороне сервера для Adobe Flash Media Server.

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Останавливает воспроизведение всех звуков, воспроизводимых в данный момент.

> Во Flash Professional этот метод не останавливает воспроизведение. Звуки, настроенные для потоковой передачи, снова будут воспроизводиться по мере перехода точки воспроизведения к кадрам, в которых они находятся.

При использовании данного свойства необходимо учесть следующую модель безопасности:

• По умолчанию вызов метода SoundMixer.stopAll() прекращает воспроизведение только тех звуков, которые находятся в той же изолированной программной среде безопасности, что и вызывающий его объект. Все звуки, воспроизведение которых было начато из другой изолированной программной среды, продолжают воспроизводиться.
• При загрузке звука с помощью метода load() класса Sound можно задать параметр context, представленный объектом SoundLoaderContext. Если задать свойству checkPolicyFile объекта SoundLoaderContext значение true, проигрыватель Flash Player или Adobe AIR проверяет наличие файла междоменной политики на сервере, с которого загружается звук. Если на сервере есть файл междоменной политики, который допускает домен вызывающего содержимого, то файл может остановить загруженный звук с помощью метода SoundMixer.stopAll(); если же нет, то этого сделать нельзя.

Однако в Adobe AIR эти ограничения по безопасности не распространяются на содержимое в изолированной программной среде безопасности application (содержимое, установленное с приложением AIR).

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}