FontDescription  - AS3

Тип используемого для текста хинтинга CFF. Используйте константы CFFHinting для этого свойства. Это свойство применяется, только если свойство RenderingMode текста имеет значение RenderingMode.CFF.

Используемый тип хинтинга CFF (компактного формата шрифтов) определяет, должна ли среда выполнения Flash принудительно вписывать горизонтальные основы в подпискельную сетку ли время выполнения Flash сильные горизонтальные основы поместиться к подпиксельной сетке или нет.

Применяется только к встроенным шрифтам.

По умолчанию используется значение CFFHinting.HORIZONTAL_STEM.

Для свойства CFFHinting можно использовать следующие константы класса CFFHinting.

Связанные элементы API

Задает способ поиска шрифта.

По умолчанию используется значение FontLookup.DEVICE.

В качестве значений этого свойства используйте следующие строковые значения:

Связанные элементы API

Имя используемого шрифта или разделенный запятой список имен шрифтов. Среда выполнения визуализирует элемент с помощью первого доступного шрифта в списке. Например, если задать «Arial, Helvetica, _sans», то проигрыватель сначала выполняет поиск Arial, затем Helvetica, если Arial не обнаружен, а потом _sans, если не обнаружен ни тот, ни другой.

Среда выполнения Flash поддерживает три общих имени шрифтов устройства: _sans (для шрифтов sans serif), _serif (для шрифтов serif) и _typewriter (для моноширинных шрифтов). Они соотносятся с определенными шрифтами устройств в зависимости от платформы.

Значением по умолчанию является _serif.

Среда выполнения Flash обеспечивает резервные шрифты для глифов, которых нет в выбранном шрифте. Независимо от того, встроен используемый шрифт или нет, если глиф не найден в данном шрифте, среда выполнения пытается визуализировать его с использованием другого шрифта устройства, который может содержать нужный глиф.

Связанные элементы API

Задает начертание шрифта.

По умолчанию используется значение FontPosture.NORMAL.

Чтобы установить значения для этого свойства, используйте следующие константы класса FontPosture.

Связанные элементы API

Задает толщину шрифта.

По умолчанию используется значение FontWeight.NORMAL.

Чтобы установить значения для этого свойства, используйте следующие константы класса FontWeight.

Связанные элементы API

Определяет, является ли объект FontDescription заблокированным. Если задано значение true, изменение объекта FontDescription невозможно. Вызовите метод FontDescription.clone() для получения разблокированной копии объекта FontDescription.

Режим визуализации, используемый для данного текста. Используйте константы RenderingMode для этого свойства.

Применяется только к встроенным шрифтам.

По умолчанию используется значение RenderingMode.CFF.

Чтобы установить значения для этого свойства, используйте следующие константы класса RenderingMode.

Связанные элементы API

Создает объект FontDescription.

Создание разблокированной клонированной копии объекта FontDescription.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescription_cloneExample extends Sprite {
        private var fd:FontDescription;
        private var fd2:FontDescription;
        
        public function FontDescription_cloneExample():void {
            fd = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            fd2 = (fd.locked) ? fd.clone() : fd;    
            fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
            var ef2:ElementFormat = new ElementFormat(fd2);

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Возвращает true, если доступен применимый шрифт устройства с указанными значениями fontName, fontWeight и fontPosture.

Классы flash.text.engine могут использовать только шрифты устройства типа OpenType и TrueType. Если используется шрифт, созданный на базе более старой технологии шрифтов, среда выполнения выполняет визуализацию текста глиф за глифом, используя заведомо рабочие шрифты устройства.

Параметры

Связанные элементы API

Возвращает значение true, если доступен встроенный шрифт с указанными свойствами fontName, fontWeight и fontPosture, где Font.fontType — это flash.text.FontType.EMBEDDED_CFF. Начиная с Flash Player 10, в содержимом приложения могут отображаться два вида встроенных шрифтов. Обычные встроенные шрифты используются только объектами TextField. Встроенные шрифты CFF используются только классами flash.text.engine. Два типа различаются свойством fontType класса Font, возвращенным функцией enumerateFonts().

Классы flash.text.engine не могут использовать шрифты типа EMBEDDED. Если fontLookup имеет значение FontLookup.EMBEDDED_CFF в среде выполнения единственным доступным шрифтом с заданным именем и стилем является шрифт типа EMBEDDED, среда выполнения использует шрифты устройства и визуализирует текст глиф за глифом, как будто в файле нет встроенного шрифта с заданным именем и стилем.

Если имеются шрифты EMBEDDED и EMBEDDED_CFF с одинаковым именем и стилем, выбирается шрифт типа EMBEDDED_CFF, и для визуализации текста используется шрифт EMBEDDED_CFF.

Параметры

Связанные элементы API

В этом примере создается объект FontDescription, ему назначается шрифт устройства, задаются разные свойства шрифта и назначается новый объект объекту ElementFormat. Дополнительное форматирование шрифта выполняется с помощью ElementFormat. Создается новый объект TextElement с использованием ElementFormat, затем этотTextElement используется в качестве содержимого для объекта TextBlock. Из объекта TextBlock создается текстовая строка.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescriptionExample extends Sprite {
        
        public function FontDescriptionExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
        }
    }    
}