TextBlock  - AS3

Указывает, что требуется улучшить внешний вид экрана за счет качества печати WYSIWYG («получаешь то, что видишь»). Для платформ и шрифтов, которые не делают поддержки sub положение глифа пиксела во время рендеринга шрифта устройства, но делать поддержку нелинейный масштаб, устанавливая эти свойства в true активирует использование метрических в некоторой стоимости к точности печати WYSIWYG, особенно для маленьких размеров точки. Не линейный масштаб шрифта работает selectivly масштабом ширина отдельных глифов, чтобы скрыть неприглядные зазоры, причиненные привязыванием пиксела.

На платформах, которые делают положение глифа подпиксела поддержки, проигнорирован этот флаг.

Этот флаг не действует на рендеринге встроенного шрифта

По умолчанию используется значение true.

Шрифт, который используется для определения базовых линий для всех строк, созданных из блока, независимо от их содержимого. Базовые линии зависят от шрифта и его размера.

По умолчанию используется null. Когда шрифт базовой линии имеет значение null, размер шрифта базовой линии игнорируется, а базовая линия отдельно взятой строки определяется на основе шрифта и размера самого крупного текста в строке. Если заданы и baselineFontDescription и baselineFontSize, эти свойства определяют базовые линии для всех строк в текстовом блоке, независимо от их содержимого. Такая комбинация чаще всего используется в восточно-азиатской типографике.

Связанные элементы API

Размер шрифта, который используется для вычисления базовых линий для строк, создаваемых из блока. Базовые линии зависят от шрифта и его размера.

По умолчанию используется значение 12. Когда шрифт базовой линии имеет значение null, размер шрифта базовой линии игнорируется, а базовая линия отдельно взятой строки определяется на основе шрифта и размера самого крупного текста в строке.

Связанные элементы API

Задает, какая базовая линия находится в точке с координатой у=0 для строк, созданных из этого блока. Действительные значения для этого свойства находятся в членах класса TextBaseline.

Значение по умолчанию — TextBaseline.ROMAN.

В качестве значений этого свойства используйте следующие строковые значения:

Связанные элементы API

Указывает уровень встраивания двунаправленных абзацев для текстового блока. В общем случае следует использовать 0 для абзацев с направлением письма слева направо (английский, японский язык и т. д.) и 1 для абзацев с направлением письма справа налево (арабский, иврит и т. д.). Значения, отличные от 0 или 1, зарезервированы для особых случаев. Дополнительные сведения см. в документе UAX#9, Unicode Bidirectional Algorithm ("Двунаправленный алгоритм Юникод"), http://www.unicode.org/reports/tr9/.

Значением по умолчанию является 0.

При модификации bidiLevel валидность всех разбитых ранее строк меняется на TextLineValidity.INVALID. После изменения bidiLevel свойство firstInvalidLine имеет то же значение, что и firstLine, и в объекте TextBlock необходимо повторно разбивать все строки.

Связанные элементы API

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Хранит содержимое текстового блока. Так как ContentElement является базовым классом, назначьте для content экземпляр подкласса ContentElement: TextElement, GraphicElement или GroupElement. TextElement содержит объект String, GraphicElement содержит объект DisplayObject, а GroupElement содержит объект Vector, включающий один или несколько объектов TextElement, GraphicElement или других объектов GroupElement. Используйте TextElement для абзаца однородного текста, GraphicElement для графики, а GroupElement для комбинации текстовых и графических элементов или нескольких экземпляров этих элементов, а также для других объектов GroupElement.

По умолчанию используется null.

Модификация свойства content приводит к изменению валидности всех созданных ранее строк на TextLineValidity.INVALID. После изменения content свойство firstInvalidLine имеет то же значение, что и firstLine, и в объекте TextBlock необходимо повторно разбивать все строки.

Связанные элементы API

Указывает первую строку в текстовом блоке, в котором значение свойства TextLine.validity не равно TextLineValidity.VALID.

По умолчанию используется null.

Связанные элементы API

Первый объект TextLine в TextBlock, если такой имеется.

По умолчанию используется null.

Связанные элементы API

Последний объект TextLine в TextBlock, если такой имеется.

По умолчанию используется null.

Связанные элементы API

Поворачивает строки в текстовом блоке как единое целое. Вызовите метод createTextLine() после настройки lineRotation, иначе он не будет иметь силы. Значение по умолчанию равно TextRotation.ROTATE_0.

Конечный поворот любого глифа зависит от значений ElementFormat.textRotation, ContentElement.textRotation и TextBlock.lineRotation.

TextBlock.lineRotation обычно используется для восточно-азиатского текста. Чтобы создать абзац вертикального японского текста, выполните следующие действия.

1. Задайте свойству TextBlock.lineRotation значение TextRotation.ROTATE_90.
2. Оставьте для свойства ElementFormat.textRotation содержимого значение по умолчанию, TextRotation.AUTO.

Используйте следующие константы, определенные в классе TextRotation, чтобы задать значение для этого свойства.

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Задает позиции табуляции для текста в блоке в виде Vector объектов TabStop.

Значение по умолчанию — null, то есть, позиции табуляции не заданы. Когда позиции табуляции не заданы (или точка вставки находится за последней указанной позицией табуляции), среда выполнения по умолчанию создает табуляцию размером около 1 см.

Когда задается свойство tabStops, объект TextBlock создает копию вектора для внутреннего использования. Изменение исходного вектора или его содержимого не влияет на объект TextBlock. Когда запрашивается свойство tabStops, возвращается копия внутреннего вектора. И опять же, изменение этого возвращенного вектора или его содержимого не влияет на объект TextBlock.

Связанные элементы API

Задает TextJustifier для использования при создании строки.

Значением по умолчанию является объект TextJustifier, созданный по умолчанию.

Когда задается свойство textJustifier, объект TextBlock создает копию объекта для внутреннего использования. Изменение исходного объекта не влияет на объект TextBlock. Когда запрашивается свойство textJustifier, возвращается копия внутреннего объекта. И опять же, изменение этого возвращенного объекта не влияет на объект TextBlock.

Связанные элементы API

Показывает результат операции createTextLine(). Изменение содержимого в блоке приводит к тому, что сделанные ранее разрывы строк становятся недействительными, а значение свойства сбрасывается на null.

По умолчанию используется null.

Значениями этого свойства являются члены класса TextLineCreationResult

Связанные элементы API

Дает возможность приложению связать произвольные данные с блоком текста. Данные могут быть информацией, ссылающейся на содержимое, такое как дата редакции или имя автора, или могут быть кэшированными данными, используемыми при обработке.

Создает объект TextBlock

Связанные элементы API

Предписывает текстовому блоку создать строку текста из своего содержимого, которая бы начиналась в точке, заданной параметром previousLine, и заканчивалась в точке, заданной параметром width. Текстовая строка — это объект TextLine, который можно добавить к списку отображения.

Разрыв строк в диапазоне текста в блоке, который уже разорван, может привести к изменению валидности строк в диапазоне разрыва и после него. Состояние строк может меняться с VALID на INVALID или POSSIBLY_INVALID. Если заново разорванная строка выравнивается с ранее разорванной строкой с состоянием POSSIBLY_INVALID, ранее разорванная строка и все последующие с состоянием POSSIBLY_INVALID снова меняют состояние на VALID. Валидность строк, значения которых не являются членами класса TextLineValidity не изменяются на VALID, но могут измениться на INVALID. Проверьте свойство firstInvalidLine после внесения любых изменений в текстовый блок, чтобы увидеть, где начинается или возобновляется разрыв строк.

Можно создать искусственные разрывы слов, включив в текст нулевой пробел Unicode (ZWSP). Это может быть полезно для таких языков, как тайский, где для правильного разрыва строк требуется словарь. В среду выполнения Flash не встроен такой словарь.

Во избежание чрезмерного потребления памяти, когда созданы все необходимые строки и не предвидится необходимость повторной разбивки, например, в результате изменения размера контейнера, необходимо вызвать метод releaseLineCreationData(), который позволяет блоку текста очистить временные данные, связанные с разрывом строк.

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Выдает базовое содержимое TextBlock в виде строки XML. Это может пригодиться при автоматическом тестировании, так как включает сведения о тексте, форматировании и компоновке.

Следующий код описывает вывод.

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Сведения о выводе для каждой строки см. в описании метода TextLine.dump().

Примечание. Содержимое и формат вывода могут измениться в будущем. Adobe не гарантирует обратной совместимости данного метода.

Связанные элементы API

Находит индекс следующей границы атома для заданного индекса символа, исключая символ по заданному индексу. Символы между границами атомов вместе формируют один атом в TextLine, например, «e» и надстрочный значок ударения.

Параметры

Связанные элементы API

Находит индекс следующей границы слова от указанного индекса символа, исключая символ по заданному индексу. Границы слов определяются на основе свойств символов в кодировке Unicode.

Параметры

Находит индекс предыдущей границы атома для указанного индекса символа, исключая символ по указанному индексу. Символы между границами атомов вместе формируют один атом в TextLine, например, «e» и надстрочный значок ударения.

Параметры

Связанные элементы API

Находит индекс предыдущей границы слова для указанного индекса символа, исключая символ по указанному индексу. Границы слов определяются на основе свойств символов в кодировке Unicode.

Параметры

Возвращает элемент TextLine, содержащий символ, заданный параметром charIndex.

Параметры

Предписывает текстовому блоку повторно использовать существующую строку для создания строки текста из своего содержимого, которая бы начиналась в точке, заданной параметром previousLine, и заканчивалась в точке, заданной параметром width. Текстовая строка — это объект TextLine, который можно добавить к списку отображения. Повторное использования существующих текстовых строк позволяет повысить производительность, так как требуется создать меньше объектов.

Воссоздаваемый объект textLine освобождается из текстового блока, если он в него входит. Кроме того, все свойства, включая свойства, унаследованные от классов DisplayObjectContainer, InteractiveObject и DisplayObject сбрасываются до значений по умолчанию. В завершение, все дочерние элементы строки удаляются, включая графические элементы и другие украшения, после чего удаляются все прослушиватели событий строки. С целью улучшения производительности из операции полного сброса исключается сама строка, которая остается в родительском объекте.

Разрыв строк в диапазоне текста в блоке, который уже разорван, может привести к изменению валидности строк в диапазоне разрыва и после него. Состояние строк может меняться с VALID на INVALID или POSSIBLY_INVALID. Если заново разорванная строка выравнивается с ранее разорванной строкой с состоянием POSSIBLY_INVALID, ранее разорванная строка и все последующие с состоянием POSSIBLY_INVALID снова меняют состояние на VALID. Валидность строк, значения которых не являются членами класса TextLineValidity не изменяются на VALID, но могут измениться на INVALID. Проверьте свойство firstInvalidLine после внесения любых изменений в текстовый блок, чтобы увидеть, где начинается или возобновляется разрыв строк.

Можно создать искусственные разрывы слов, включив в текст нулевой пробел Unicode (ZWSP). Это может быть полезно для таких языков, как тайский, где для правильного разрыва строк требуется словарь. В среду выполнения Flash не встроен такой словарь.

Во избежание чрезмерного потребления памяти, когда созданы все необходимые строки и не предвидится необходимость повторной разбивки, например, в результате изменения размера контейнера, необходимо вызвать метод releaseLineCreationData(), который позволяет блоку текста очистить временные данные, связанные с разрывом строк.

Параметры

Связанные элементы API

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Дает текстовому блоку команду очистить все временные данные, связанные с созданием текстовых строк. Чтобы сократить объем памяти, используемый приложений, необходимо вызвать метод releaseLineCreationData() по завершении создания текстовых строк из блока текста. Тем не менее, если требуется увеличить производительность при повторной разбивке строк (например, при изменении размера контейнера), метод releaseLineCreationData() вызывать не следует. Таким образом, приложение самостоятельно регулирует использование памяти и производительность.

Если изменение текста не предвидится, рекомендуется следующий процесс: инициализируйте блок текста, вызывайте метод createTextLine() столько, сколько нужно для создания нужного ввода, а затем вызовите метод releaseLineCreationData().

Связанные элементы API

Удаляет диапазон текстовых строк из списка строк, поддерживаемых текстовым блоком TextBlock. Это позволяет очищать строки, если не существует других ссылок.

Задает значение членов textBlock, nextLine и previousLine удаленных строк как null. Задает значение validity удаленных строк и следующих за ними в блоке TextBlock TextLineValidity.INVALID.

Параметры

Связанные элементы API