NumericStepper  - AS3 Flash

Ruft einen Wert ab oder legt einen Wert fest, der angibt, ob die Komponente eine Benutzereingabe annehmen kann. Der Wert true gibt an, dass die Komponente Benutzereingaben annehmen kann, der Wert false, dass die Komponente keine Benutzereingaben annehmen kann.

Wenn Sie die Eigenschaft enabled auf false einstellen, wird die Farbe des Containers abgeblendet und Benutzereingaben werden blockiert (mit Ausnahme der Label- und ProgressBar-Komponenten).

Der Standardwert ist true.

Ruft den Modus des Eingabemethoden-Editors (IME) ab oder legt diesen fest. Mit dem IME können Benutzer über eine QWERTY-Tastatur Zeichen aus dem chinesischen, japanischen und koreanischen Zeichensatz eingeben.

Flash aktiviert den angegebenen Modus für den IME, wenn die Komponente eine Fokus erhält, und stellt den ursprünglichen Wert wieder her, wenn der Fokus entfernt wird.

Die flash.system.IMEConversionMode-Klasse definiert Konstanten für gültige Werte dieser Eigenschaft. Wenn Sie den IME nicht mit der Komponente verwenden möchten, setzen Sie diese Eigenschaft auf null.

Ruft den Höchstwert in einer Reihe numerischer Werte ab bzw. legt diesen fest.

Der Standardwert ist 10.

Ruft den Mindestwert in einer Reihe numerischer Werte ab bzw. legt diesen fest.

Der Standardwert ist 0.

Ruft den nächsten Wert in einer Wertereihe ab.

Ruft den vorherigen Wert in einer Wertereihe ab.

Ruft eine Zahl ungleich null ab, die den Änderungsbetrag zwischen Werten angibt, oder legt diese fest. Die Eigenschaft value ist ein Vielfaches dieser Zahl reduziert um den Mindestwert. Die NumericStepper-Komponente rundet den sich daraus ergebenden Wert auf die nächste Schrittgröße auf oder ab.

Der Standardwert ist 1.

Ruft einen Verweis auf die TextInput-Komponente ab, die die NumericStepper-Komponente enthält. Verwenden Sie diese Eigenschaft, um auf die untergeordnete TextInput-Komponente zuzugreifen und diese zu bearbeiten. Sie können mit dieser Eigenschaft beispielsweise die aktuelle Auswahl im Textfeld ändern oder die Zeichen beschränken, die in das Textfeld eingegeben werden können.

Ruft den aktuellen Wert der NumericStepper-Komponente ab bzw. legt diesen fest.

Der Standardwert ist 1.

Erstellt eine neue Instanz der NumericStepper-Komponente.

Blendet die Fokusanzeige auf dieser Komponente ein oder aus.

Mit der UIComponent-Klasse wird diese Methode implementiert, indem eine Instanz der vom Stil focusSkin definierten Klasse erstellt und positioniert wird.

Parameter

Ruft die Standardstilmatrix der aktuellen Komponente ab. Die Stilmatrix enthält den für die Komponente geeigneten Typ und hängt von dem Stil ab, der von der Komponente verwendet wird. Der Stil disabledTextFormat enthält beispielsweise den Wert null oder ein TextFormat-Objekt. Sie können diese Stile verwenden und setStyle() für die aktuelle Komponente aufrufen. Mit folgendem Code wird der Standardstil disabledTextFormat der angegebenen Komponente überschrieben:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Verwandte API-Elemente

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Legt den Fokus auf die Komponenteninstanz.

Wird ausgelöst, wenn der Benutzer den Wert der NumericStepper-Komponente ändert.

Hinweis: Dieses Ereignis wird nicht ausgelöst, wenn für die Änderung des Wertes der ActionScript-Code verwendet wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

1. Fügen Sie die NumericStepper-Komponente Ihrer Bibliothek hinzu.
2. Speichern Sie diesen Code unter „NumericStepperExample.as“ im gleichen Verzeichnis wie die FLA-Datei.
3. Legen Sie für „DocumentClass“ in der FLA-Datei „NumericStepperExample“ fest.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}