FocusEvent  - AS3

Gibt die Richtung des Fokus für ein focusIn-Ereignis an.

Verwandte API-Elemente

Wenn true, ist die relatedObject-Eigenschaft aus Gründen, die mit der Sicherheitssandbox zusammenhängen, auf null gesetzt. Ist der Nominalwert von relatedObject ein Verweis auf ein DisplayObject in einer anderen Sandbox, wird relatedObject auf null gesetzt, es sei denn, die Berechtigung gilt über die Sandboxgrenzen hinweg für beide Richtungen. Die Berechtigung wird eingerichtet, indem aus einer SWF-Datei Security.allowDomain() aufgerufen wird oder eine Richtliniendatei vom Server einer Bilddatei bereitgestellt und die LoaderContext.checkPolicyFile-Eigenschaft beim Laden des Bilds gesetzt wird.

Verwandte API-Elemente

Der Tastencodewert der Taste, die zum Auslösen eines keyFocusChange-Ereignisses gedrückt wird.

Ein Verweis auf die andere InteractiveObject-Instanz, die von dem Fokuswechsel betroffen ist. Wenn beispielsweise ein focusOut-Ereignis auftritt, stellt relatedObject die InteractiveObject-Instanz dar, die den Fokus erhalten hat.

Der Wert dieser Eigenschaft kann in zwei Fällen null sein: Wenn es kein verwandtes Objekt gibt oder wenn es eines gibt, dieses aber eine Sicherheitssandbox ist, auf die Sie keinen Zugriff haben. Verwenden Sie die isRelatedObjectInaccessible()-Eigenschaft, um festzustellen, welcher dieser Gründe zutrifft.

Verwandte API-Elemente

Gibt an, ob die Umschalttaste als Zusatztaste aktiviert ist. In diesem Fall lautet der Wert true. Andernfalls ist der Wert false. Diese Eigenschaft wird nur dann verwendet, wenn „FocusEvent“ den Typ keyFocusChange hat.

Erstellt ein Ereignisobjekt mit bestimmten Informationen, die für Fokus-Ereignisse wichtig sind. Ereignisobjekte werden Ereignis-Listenern als Parameter übergeben.

Verwandte API-Elemente

Erstellt eine Kopie des FocusEvent-Objekts und stellt den Wert jeder Eigenschaft so ein, dass er dem Wert des Originals entspricht.

Gibt eine Zeichenfolge zurück, die alle Eigenschaften des FocusEvent-Objekts enthält. Der String liegt im folgenden Format vor:

[FocusEvent type=Wert bubbles=Wert cancelable=Wert relatedObject=Wert shiftKey=Wert] keyCode=Wert]

Definiert den Wert der Eigenschaft type eines focusIn-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines focusOut-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines keyFocusChange-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseFocusChange-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

1. Die Eigenschaften child (vom Typ "Sprite") und childCount (vom Typ "uint") werden deklariert.
2. Mit einer for-Schleife werden am Punkt (0,0) fünf hellblaue Quadrate gezeichnet. Zuerst wird einer neuen CustomSprite-Instanz die Eigenschaft child zugewiesen. Jedes Mal, wenn ein CustomSprite-Objekt erstellt wird, passiert Folgendes:
   • Die Eigenschaft size vom Typ "uint" wird auf 50 Pixel gesetzt, und bgColor wird auf hellblau gesetzt.
   • Die Eigenschaften buttonMode und useHandCursor der Klasse "Sprite" werden innerhalb des Konstruktors auf true gesetzt.
   • Es wird ein Ereignis-Listener vom Typ click zusammen mit dem verknüpften Abonnenten clickHandler() instanziiert. Die Abonnentenmethode erstellt eine lokale target-Variable vom Typ „Sprite“ und weist sie dem Feld zu, auf das geklickt wurde. Anschließend wird der Fokus der Bühne der Variablen target zugewiesen.
   • Die Methode draw() wird aufgerufen. Hierdurch wird ein 50 x 50 Pixel großes Quadrat mit den Methoden beginFill(), drawRect() und endFill() der Graphics-Klasse und der Instanzeigenschaften erstellt.
3. In der „for“-Schleife wird die Methode configureListeners() aufgerufen, die drei Ereignis-Listener/-Abonnenten instanziiert:
   • focusIn/focusInHandler() wird ausgelöst, nachdem auf ein beliebiges Anzeigelistenobjekt (Feld) geklickt worden ist (click-Ereignis).
   • focusOut/focusOutHandler() wird ausgelöst, wenn auf ein anderes Feld geklickt wird oder die Bühne nicht mehr den Fokus besitzt (z. B., weil jemand außerhalb von Flash Player geklickt hat).
   • keyFocusChange/keyFocusChangeHandler() wird ausgelöst, wenn Sie mit der Tabulatortaste oder den Nach-links- und Nach-rechts-Pfeiltasten ein Anzeigelistenobjekt auswählen. Mit der keyFocusChangeHandler()-Methode werden die Aktionen der Nach-links- und Nach-rechts-Pfeiltasten überwacht. Außerdem wird die Methode preventDefault() zur Deaktivierung aufgerufen.
4. In der for-Schleife wird jedes Quadrat der Anzeigeliste hinzugefügt und angezeigt (im gleichen Bereich). Hierfür kommt die Methode addChild() zum Einsatz.
5. Der Konstruktor ruft anschließend die Methode refreshLayout() auf, mit der die orangefarbenen Quadrate mit jeweils 5 Pixel Abstand oben in der Anzeige (y = 0) verteilt werden.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}