Video  - AS3

Gibt den Typ des Filters an, der bei der Nachbearbeitung auf dekodierte Videos angewendet wird. Mit dem Standardwert 0 kann bei der Videokomprimierung gegebenenfalls ein Deblocking-Filter angewendet werden.

Die Komprimierung von Videos kann zu unerwünschten Artefakten führen. Mithilfe der deblocking-Eigenschaft können Sie Filter setzen, mit denen Blocking-Artefakte und (bei Videokomprimierungen mit dem On2-Codec) auch Ringing-Artefakte reduziert werden.

Blocking bezieht sich auf sichtbare Fehler zwischen den Begrenzungen der einzelnen Blocks, aus denen sich jedes Videobild zusammensetzt. Ringing bezieht sich auf verzerrte Kanten der Elemente in einem Videobild.

Es stehen zwei Deblocking-Filter zur Verfügung: einer im Sorenson-Codec und ein weiterer im On2 VP6-Codec. Bei Verwendung des On2 VP6-Codecs ist zudem ein Deringing-Filter verfügbar. Verwenden Sie zum Festlegen eines Filters einen der folgenden Werte:

• 0 – Der Deblocking-Filter wird bei der Videokomprimierung bei Bedarf angewendet.
• 1 – Es wird kein Deblocking-Filter verwendet.
• 2 – Es wird der Sorenson-Deblocking-Filter angewendet.
• 3 – Nur bei der On2-Videokomprimierung wird der Deblocking-Filter von On2, jedoch kein Deringing-Filter verwendet.
• 4 – Nur für On2-Video. Es wird der Deblocking-Filter und der Deringing-Filter von On2 verwendet.
• 5 – Nur bei der On2-Videokomprimierung wird der Deblocking-Filter und ein leistungsstärkerer Deringing-Filter von On2 verwendet.

Wenn bei Verwendung des Sorenson-Codecs ein Wert größer als 2 angegeben wurde, wird der Sorenson-Decoder automatisch auf 2 gesetzt.

Die Verwendung eines Deblocking-Filters hat Auswirkungen auf die Gesamtleistung bei der Wiedergabe und ist bei Videos mit hoher Bandbreite normalerweise nicht erforderlich. Wenn das System eines Benutzers nicht leistungsfähig genug ist, treten bei einem aktivierten Deblocking-Filter bei der Wiedergabe von Videos möglicherweise Probleme auf.

Gibt an, ob das Video beim Skalieren geglättet (interpoliert) werden soll. Die Funktion zum Glätten funktioniert nur, wenn sich die Laufzeitumgebung im Modus für hohe Qualität (Standardeinstellung) befindet. Der Standardwert ist false (ohne Glättung).

Setzen Sie für die Videowiedergabe mit Flash Player 9.0.115.0 und höheren Versionen diese Eigenschaft auf true, um die Bilder durch MIP-Mapping zu optimieren.

Eine Ganzzahl, die die Höhe des Videostreams in Pixeln angibt. Im Falle von Live-Streams ist der Wert mit dem der Eigenschaft Camera.height des Kamera-Objekts identisch, das den Videostream aufzeichnet. Bei aufgenommenen Videodateien ist dieser Wert die Höhe des Videos. Das NetStream.Video.DimensionChange-Ereignis wird bei aufgenommenen Videos abgesetzt, wenn dieser Wert geändert wird.

Sie können diese Eigenschaft beispielsweise verwenden, um sicherzustellen, dass der Benutzer das Video in der Größe sieht, in der es aufgenommen wurde (unabhängig von der eigentlichen Größe des Videoobjekts auf der Bühne).

Verwandte API-Elemente

Eine Ganzzahl, die die Breite des Videostreams in Pixeln angibt. Im Falle von Live-Streams ist der Wert mit dem der Eigenschaft Camera.width des Camera-Objekts identisch, das den Videostream aufzeichnet. Bei aufgenommenen Videodateien ist dieser Wert die Breite des Videos. Das NetStream.Video.DimensionChange-Ereignis wird bei aufgenommenen Videos abgesetzt, wenn dieser Wert geändert wird.

Sie können diese Eigenschaft beispielsweise verwenden, um sicherzustellen, dass der Benutzer das Video in der Größe sieht, in der es aufgenommen wurde (unabhängig von der eigentlichen Größe des Videoobjekts auf der Bühne).

Verwandte API-Elemente

Erstellt eine neue Video-Instanz. Wenn für die Parameter width und height keine Werte angegeben sind, werden die Standardwerte verwendet. Mithilfe von Video.width und Video.height können Sie die width- und height-Eigenschaften des Videoobjekts auch nach der Erstellung des Objekts festlegen. Beim Erstellen eines neuen Videoobjekts ist der Wert 0 für die Höhe und Breite nicht zulässig. Wenn Sie den Wert 0 übergeben, werden die Standardwerte verwendet.

Rufen Sie nach dem Erstellen des Videos die Methode DisplayObjectContainer.addChild() oder DisplayObjectContainer.addChildAt() auf, um das Videoobjekt einem übergeordneten DisplayObjectContainer-Objekt hinzuzufügen.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Gibt einen Videostream von einer Kamera an, der innerhalb des Videoobjekts in der Anwendung angezeigt werden soll.

Verwenden Sie diese Methode, um vom Benutzer erfasstes Live-Video an das Video-Objekt anzuhängen. Sie können das Live-Video lokal auf demselben Computer oder Gerät, auf dem es aufgezeichnet wurde, abspielen, oder es an Flash Media Server senden und es mithilfe des Servers an andere Benutzer streamen.

Hinweis: In einer iOS-AIR-Anwendung kann kein Kameravideo angezeigt werden, wenn die Anwendung den GPU-Renderingmodus verwendet.

Parameter

Verwandte API-Elemente

Gibt einen Videostream an, der innerhalb des Videoobjekts in der Anwendung angezeigt werden soll. Der Videostream ist entweder eine Videodatei, die mit NetStream.play() abgespielt wird, ein Camera-Objekt oder null. Wenn Sie eine Videodatei verwenden, kann sie im lokalen Dateisystem oder auf Flash Media Server gespeichert werden. Wenn der Wert des netStream-Arguments auf null gesetzt ist, wird das Video nicht mehr im Videoobjekt wiedergegeben.

Sie müssen diese Methode nicht verwenden, wenn eine Videodatei nur Audiodaten enthält. Die Audiodaten von Videodateien werden automatisch wiedergegeben, wenn Sie NetStream.play() aufrufen. Um die mit einer Videodatei verknüpften Audiodaten zu steuern, verwenden Sie die soundTransform-Eigenschaft des NetStream-Objekts, das die Videodatei wiedergibt.

Parameter

Verwandte API-Elemente

Löscht das Bild, das aktuell im Videoobjekt angezeigt wird (nicht im Videostream). Diese Methode ist für das Arbeiten mit dem aktuellen Bild nützlich. Sie können beispielsweise das letzte Bild löschen oder Standbyinformationen anzeigen, ohne das Videoobjekt auszublenden.

Verwandte API-Elemente

In diesem Fall wird der Code zur Erstellung des Video- und NetStream-Objekts und zum Aufrufen der Methoden Video.attachNetStream() und NetStream.play() in eine Prozedurfunktion eingefügt. Die Prozedur wird nur aufgerufen, wenn die Verbindung mit dem NetConnection-Objekt erfolgreich hergestellt werden kann, d. h. wenn das Ereignis netStatus ein info-Objekt mit einer code-Eigenschaft zurückgibt, die Erfolg angibt. Es wird empfohlen, die erfolgreiche Verbindungsherstellung abzuwarten, bevor Sie NetStream.play() aufrufen.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }