Geolocation

Paket	flash.sensors
Klasse	public class Geolocation
Vererbung	Geolocation EventDispatcher Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

Die Geolocation-Klasse setzt Ereignisse in Reaktion auf den Positionssensor des Geräts ab.

Wenn ein Gerät die Geolokalisierung unterstützt, können Sie diese Klasse verwenden, um die aktuelle geografische Position des Geräts abzurufen. Die geografische Position wird auf dem Gerät mit Breitengrad- und Längengrad-Koordinaten angegeben (im WGS-84-Standardformat). Wenn sich die Position des Geräts ändert, können Sie Aktualisierungen zu den Änderungen empfangen. Wenn das Gerät diese Funktion unterstützt, können Sie Informationen zu Höhe, Genauigkeit, Richtung und Geschwindigkeit sowie den Zeitstempel der letzten Positionsänderungen abrufen.

AIR-Profilunterstützung: Diese Funktion wird nur auf mobilen Geräten unterstützt. Auf Desktopgeräten oder Geräten mit AIR für TV wird sie nicht unterstützt. Mit der Geolocation.isSupported-Eigenschaft können Sie testen, ob zur Laufzeit Unterstützung gegeben ist. Weitere Informationen zum AIR-Support über mehrere Profile finden Sie unter Unterstützung von AIR-Profilen.

Hinweis: Um Geolokation in iOS zu aktivieren, müssen Sie ein Schlüsselwertpaar dem infoAdditions-Element in der Anwendung „XML-Datei“ hinzufügen. Sie finden unter iOS-Einstellungen weitere Informationen zum infoAdditions-Element.

Beispiele anzeigen

Weitere Informationen

Cristophe Coenraets: Multi-user Google Maps Collaboration

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		isSupported : Boolean [statisch] [schreibgeschützt] „true“, wenn im Gerät ein Positionssensor verfügbar ist, andernfalls „false“.	Geolocation
		locationAlwaysUsePermission : Boolean Diese Eigenschaft bestimmt die Verwendung des Zugangsberechtigungstyps für die Geolokalisierung.	Geolocation
		muted : Boolean [schreibgeschützt] Gibt an, ob der Benutzer den Zugriff auf den Positionssensor verweigert (true) oder gewährt hat (false).	Geolocation
		permissionStatus : String [statisch] [schreibgeschützt]	Geolocation

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		Geolocation() Erstellt eine neue Geolocation-Instanz.	Geolocation
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registriert ein Ereignis-Listener-Objekt bei einem EventDispatcher-Objekt, sodass der Listener über ein Ereignis benachrichtigt wird.	EventDispatcher
		dispatchEvent(event:Event):Boolean Sendet ein Ereignis in den Ereignisablauf.	EventDispatcher
		hasEventListener(type:String):Boolean Überprüft, ob das EventDispatcher-Objekt Listener für einen bestimmten Ereignistyp registriert hat.	EventDispatcher
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Entfernt einen Listener aus dem EventDispatcher-Objekt.	EventDispatcher
		requestPermission():void	Geolocation
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		setRequestedUpdateInterval(interval:Number):void Legt das Zeitintervall für Aktualisierungen in Millisekunden fest.	Geolocation
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object
		willTrigger(type:String):Boolean Überprüft, ob bei diesem EventDispatcher-Objekt oder bei einem seiner Vorgänger ein Ereignis-Listener für einen bestimmten Ereignistyp registriert ist.	EventDispatcher

Ereignisse

Klicken Sie, um weitere Informationen zu Ereignissen zu erhalten.

Vererbte Ereignisse ausblenden

Vererbte Ereignisse anzeigen

	Übersicht	Definiert von
activate	[broadcast event] Wird ausgelöst, wenn Flash Player oder eine AIR-Anwendung den Betriebssystemfokus erhält und aktiv wird.	EventDispatcher
deactivate	[broadcast event] Wird ausgelöst, wenn Flash Player- oder die AIR-Anwendung den Fokus verliert und inaktiv wird.	EventDispatcher
permissionStatus		Geolocation
status	Das Geolocation-Objekt setzt Statusereignisse ab, wenn der Benutzer den Zugriff auf den Lokalisierungssensor ändert.	Geolocation
update	Das update-Ereignis wird in Reaktion auf Updates vom Positionssensor abgesetzt.	Geolocation

Eigenschaftendetails

isSupported

Eigenschaft

isSupported:Boolean [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

true, wenn im Gerät ein Positionssensor verfügbar ist, andernfalls false.

Implementierung
public static function get isSupported():Boolean

locationAlwaysUsePermission

Eigenschaft

locationAlwaysUsePermission:Boolean

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 29

Diese Eigenschaft bestimmt die Verwendung des Zugangsberechtigungstyps für die Geolokalisierung. Der Berechtigungstyp kann „Always“ (Immer) oder „When In Use“ (Bei Verwendung) lauten. Wenn die Eigenschaft auf false gesetzt wird, fordert sie die Berechtigung „When In Use“ (Bei Verwendung) an. Andernfalls fordert sie die Berechtigung „Always“ (Immer) an. Legen Sie die Eigenschaft fest, bevor Sie requestPermission() aufrufen. Der Standardwert der Eigenschaft lautet false.

Implementierung
public function get locationAlwaysUsePermission():Boolean
public function set locationAlwaysUsePermission(value:Boolean):void

muted

Eigenschaft

muted:Boolean [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Gibt an, ob der Benutzer den Zugriff auf den Positionssensor verweigert (true) oder gewährt hat (false). Wenn sich dieser Wert ändert, wird ein status-Ereignis ausgelöst.

Implementierung
public function get muted():Boolean

Verwandte API-Elemente

status

permissionStatus

Eigenschaft

permissionStatus:String [schreibgeschützt]

Implementierung
public static function get permissionStatus():String

Konstruktordetails

()

Konstruktor

public function Geolocation()

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

Erstellt eine neue Geolocation-Instanz.

Methodendetails

requestPermission

()

Methode

public function requestPermission():void

setRequestedUpdateInterval

()

Methode

public function setRequestedUpdateInterval(interval:Number):void

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

Legt das Zeitintervall für Aktualisierungen in Millisekunden fest. Das Aktualisierungsintervall wird zur Schonung der Akkuenergie nur als Näherungswert verwendet. Die tatsächliche Zeitspanne zwischen Positionsaktualisierungen kann größer oder kleiner als dieser Wert sein. Änderungen am Aktualisierungsintervall mit dieser Methode betreffen alle registrierten update-Ereignis-Listener. Die Geolocation-Klasse kann ohne Aufruf der setRequestedUpdateInterval-Methode verwendet werden. In diesem Fall gibt die Plattform Aktualisierungen basierend auf ihrem Standardintervall zurück.

Hinweis: iPhones der ersten Generation, die kein GPS-Modul enthalten, setzen nur gelegentlich update-Ereignisse ab. Bei diesen Geräten setzt ein Geolocation-Objekt anfänglich ein oder zwei update-Ereignisse ab. Danach werden update-Ereignisse abgesetzt, wenn sich Informationen deutlich ändern.

Parameter

interval:Number — angefordertes Aktualisierungsintervall. Wenn interval kleiner oder gleich 0 ist, hat ein Aufruf dieser Methode keine Auswirkungen.

Auslöser

ArgumentError — Das angegebene interval ist kleiner als null.

Ereignisdetails

permissionStatus

Ereignis

Ereignisobjekttyp: flash.events.PermissionEvent

status

Ereignis

Ereignisobjekttyp: flash.events.StatusEvent
Eigenschaft StatusEvent.type = flash.events.StatusEvent.STATUS

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

Das Geolocation-Objekt setzt status-Ereignisse ab, wenn der Benutzer den Zugriff auf den Lokalisierungssensor ändert. Wenn zum Beispiel der Benutzer in Reaktion auf eine Geräteaufforderung verhindert, dass die Anwendung auf Standortdaten zugreift, setzt das Geolocation-Objekt ein status-Ereignis ab. Wenn sich der Status zu einem Zustand ändert, in dem der Standortsensor nicht verfügbar ist, wird die muted-Eigenschaft der Geolocation-Instanz auf true gesetzt.

Definiert den Wert der Eigenschaft type eines status-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`code`	Eine Beschreibung des Objektstatus.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`Ebene`	Die Kategorie der Meldung, z. B. `"status"`, `"warning"` oder `"error"`.
`target`	Das Objekt, dessen Status gemeldet wird.

Verwandte API-Elemente

muted

update

Ereignis

Ereignisobjekttyp: flash.events.GeolocationEvent
Eigenschaft GeolocationEvent.type = flash.events.GeolocationEvent.UPDATE

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2, Flash Lite 4

Das update-Ereignis wird in Reaktion auf Updates vom Positionssensor abgesetzt. Das Ereignis wird unter den folgenden Umständen abgesetzt:

Wenn eine neue Listener-Funktion mit addEventListener() hinzugefügt wird, wird dieses Ereignis einmalig allen registrierten Listenern zugestellt, um den aktuellen Wert des Beschleunigungssensors bereitzustellen. Hinweis: AIR setzt das erste Ereignis sofort ab, wenn es einen letzten bekannten Standort für das Gerät gibt; Ihr Code muss berücksichtigen, dass das zuerst abgesetzte Ereignis möglicherweise nicht den aktuellen Standort enthält.
Wenn Aktualisierungen der Position in vom Gerät bestimmten Intervallen von der Plattform empfangen werden.
Wenn die Anwendung eine Änderung der Position verpasst (zum Beispiel, wenn die Anwendung aus dem Standby reaktiviert wird).

Definiert den Wert der type-Eigenschaft eines GeolocationEvent-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Geolocation-Objekt, das Daten empfängt.

Beispiele Verwendung dieses Beispiels

GeolocationExample.as

Im folgenden Beispiel zeigt die Anwendung den Breitengrad, den Längengrad und die horizontale Genauigkeit von update-Geolokalisierungsereignissen an, wenn sie empfangen werden.

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.GeolocationEvent;
    import flash.events.MouseEvent;
    import flash.events.StatusEvent;
    import flash.sensors.Geolocation;
    import flash.text.TextField;
    import flash.text.TextFormat;
    
    public class GeolocationTest extends Sprite
    {
        
        private var geo:Geolocation; 
        private var log:TextField;
        
        public function GeolocationTest()
        {            
            super();
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            setUpTextField();
            
            if (Geolocation.isSupported) 
            { 
                geo = new Geolocation(); 
                if (!geo.muted) 
                { 
                    geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler); 
                } 
                geo.addEventListener(StatusEvent.STATUS, geoStatusHandler);
            } 
            else 
            { 
                log.text = "Geolocation not supported"; 
            } 
        }
        
        public function geoUpdateHandler(event:GeolocationEvent):void 
        { 
            log.text = "latitude : " + event.latitude.toString() + "\n"; 
            log.appendText("longitude : " + event.longitude.toString() + "\n");
        } 
        
        public function geoStatusHandler(event:StatusEvent):void 
        { 
            if (geo.muted)
                geo.removeEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
            else
                geo.addEventListener(GeolocationEvent.UPDATE, geoUpdateHandler);
        }
        
        private function setUpTextField():void
        {
            log = new TextField();
            var format:TextFormat = new TextFormat("_sans", 24);
            log.defaultTextFormat = format;
            log.border = true;
            log.wordWrap = true;
            log.multiline = true;
            log.x = 10;
            log.y = 10;
            log.height = stage.stageHeight - 20;
            log.width = stage.stageWidth - 20;
            log.addEventListener(MouseEvent.CLICK, clearLog);
            addChild(log);
        }
        private function clearLog(event:MouseEvent):void
        {
            log.text = "";
        }
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

Geolocation - AS3

Klassen x

isSupported

locationAlwaysUsePermission

muted

permissionStatus

Geolocation

requestPermission

setRequestedUpdateInterval

permissionStatus

status

update