Bitmap  - AS3

Объект BitmapData, указанный в ссылке.

Определяет, должен ли объект Bitmap быть привязанным к ближайшему пикселю. Класс PixelSnapping включает возможные значения:

• PixelSnapping.NEVER — Привязка к пикселям не выполняется.
• PixelSnapping.ALWAYS — Изображение всегда привязывается к ближайшему пикселю, независимо от преобразования.
• PixelSnapping.AUTO — Изображение привязывается к ближайшему пикселю, если не выполнялось вращение или наклон, а также если оно отображено в масштабе от 99,9% до 100,1%. Если эти условия удовлетворяются, растровое изображение отображается в масштабе 100% с привязкой к ближайшему пикселю. На внутреннем уровне это значение позволяет показывать изображение с максимальной быстротой с помощью векторного средства визуализации.

Определяет, следует ли сглаживать растровое изображение при масштабировании. При значении true растровое изображение смягчается при масштабировании. При значении false растровое изображение не смягчается при масштабировании.

Инициализирует объект Bitmap для ссылки на заданный объект BitmapData.

	bitmapData:BitmapData (default = null) — Объект BitmapData, указанный в ссылке.
	pixelSnapping:String (default = "auto") — Определяет, должен ли объект Bitmap быть привязанным к ближайшему пикселю.
	smoothing:Boolean (default = false) — Определяет, следует ли сглаживать растровое изображение при масштабировании. В следующих примерах показано то же растровое изображение, отмасштабированное с фактором 3, при smoothing в значении false (слева) и true (справа).

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. Создается свойство url, описывающее местоположение и имя файла изображения.
2. Конструктор класса вызывает метод configureAssets(), который в свою очередь вызывает метод completeHandler().
3. configureAssets() создает объект Loader, который затем создает экземпляр прослушивателя событий, отправляемых по завершении обработки изображения методом completeHandler().
4. Затем метод buildChild() создает новый экземпляр объекта URLRequest, request, и передает url, чтобы сообщить имя и местоположение файла.
5. Объект request передается методу loader.load(), который загружает изображение в память через экранный объект.
6. После этого изображение добавляется в список отображения, который почти сразу показывает изображение на экране в положении с координатами x = 0, y = 0.
7. Затем метод completeHandler() выполняет следующие задачи:
   1. Создает второй объект Loader и инициализированный вместе с ним объект Bitmap.
   2. Создает второй объект Bitmap, duplicate, который в свою очередь вызывает метод duplicateImage(), создающий дубликат исходного изображения.
   3. Создает объект BitmapData, который назначается объекту BitmapData объекта duplicate.
   4. Создает новый объект Rectangle, инициализированный с теми же координатами, шириной и высотой, что и исходное изображение.
   5. Создает новый объект Point с координатами по умолчанию: x = 0, y = 0.
   6. Создает следующие переменные:
      • operation: применяет новый цвет, когда пороговое значение больше исходного или равно ему.
      • threshold: значение, с которым сравнивается каждый пиксель, — светло-серый цвет с альфа-значением 0xCC.
      • color: цвет, который будет задан пикселям, проходящим пороговый тест, — в данном случае это сплошной желтый цвет.
      • mask: задается диаметрально противоположный цвет (прозрачный синий).
      • copySource: получает значение false, указывающее на то, что значения пикселей не копируются в том случае, если пороговое значение не проходит. Это значение не имеет смысла, потому что изображение продублировано и изменяются только пиксели, прошедшие пороговый тест.
   7. Вызывает метод threshold() с использованием предшествующих переменных. В результате мы получаем уравнение порога: if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Примечания.

• SWF-файл потребуется откомпилировать с установленным для параметра «Безопасность локального воспроизведения» режимом «Доступ только к локальным файлам».
• Данный пример требует, чтобы файл с именем Image.gif находился в том же каталоге, что и SWF-файл.
• Рекомендуем использовать изображение с шириной до 80 пикселей.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}