SimpleButton  - AS3

Задает экранный объект, применяемый в качестве визуального объекта для отображения кнопки в состоянии Down (в котором она находится при щелчке объекта hitTestState).

Связанные элементы API

Логическое значение, которое определяет, включена ли кнопка. Когда кнопка отключена (свойство enabled имеет значение false), кнопка является видимой, но не может быть выбрана. По умолчанию используется значение true. Это свойство удобно использовать, когда требуется отключить часть элементов навигации. Например, может потребоваться отключить кнопку на отображаемой в данный момент странице, чтобы на нее нельзя было нажать и чтобы предотвратить перезагрузку страницы.

Примечание. Для предотвращения событий mouseClicks для кнопки установите оба свойства — enabled и mouseEnabled — на значение false.

Задает экранный объект, который служит кнопке в качестве объекта для тестирования нажатия. Для базовой кнопки нужно задать свойству hitTestState тот же экранный объект, что и свойствуoverState. Если не задать свойство hitTestState, объект SimpleButton будет неактивным: он не будет отвечать на события пользовательского ввода.

Связанные элементы API

Задает экранный объект, применяемый в качестве визуального объекта для отображения кнопки в состоянии Over (в котором находится кнопка, когда указатель располагается над ней).

Связанные элементы API

Объект SoundTransform, связанный с этой кнопкой. Объект SoundTransform включает свойства для настройки громкости, панорамы, назначения левого и правого динамиков. Данный объект SoundTransform применяется ко всем состояниям кнопки. Данный объект SoundTransform воздействует только на встроенные звуки.

Связанные элементы API

Определяет, могут ли другие экранные объекты, являющиеся объектами SimpleButton или MovieClip, получать события отпускания при пользовательском вводе. Свойство trackAsMenu позволяет создавать меню. Свойство trackAsMenu можно задать для любого объекта SimpleButton или MovieClip. Если свойство trackAsMenu не существует, по умолчанию используется значение false.

Свойство trackAsMenu можно изменить в любой момент; обновленный фрагмент ролика немедленно начинает использовать новое поведение курсора.

Задает экранный объект, применяемый в качестве визуального объекта для отображения кнопки в состоянии вверх (в котором находится кнопка, когда указатель не расположен над ней).

Связанные элементы API

Логическое значение. При значении true определяет, отображается ли курсор в виде руки при наведении указателя на кнопку. Если этому свойству задано значение false, используется курсор «стрелка». Значение по умолчанию — true.

Свойство useHandCursor можно изменить в любой момент; обновленный фрагмент ролика немедленно начинает использовать новое поведение курсора.

Создает новый экземпляр SimpleButton. Все и каждый из экранных объектов, представляющих разные состояния кнопки, можно задать в качестве параметров в конструкторе.

1. В конструкторе SimpleButtonExample() создается новый объект CustomSimpleButton типа SimpleButton с именем button при помощи конструктора CustomSimpleButton. Объект button добавляется в список отображения. Цвет и размер кнопки определяются в следующих шагах.
2. В классе CustomSimpleButton объявляются свойства экземпляра, которые в дальнейшем будут использоваться для управления размером и фоновым цветом объекта button в зависимости от его состояния (оранжевый в обычном состоянии, темно-желтый при наведении мыши и голубой при нажатии мыши). Во всех состояниях объекта button размер квадрата равен 80 пикселям, что определено свойством size.
3. Функция конструктора класса CustomSimpleButton задает свойства downState, overState, upState, hitTestState и useHandCursor для всех четырех экземпляров класса ButtonDisplayState.
4. В классе ButtonDisplayState конструктор задает значение размера и фонового цвета квадрата и вызывает метод draw().
5. Метод draw() перерисовывает квадрат, используя размер и цвет фона, заданный в конструкторе, в зависимости от состояния кнопки.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}