TextLine  - AS3

Указывает число пикселей от базовой линии до верхней точки самых высоких символов в строке. Для объекта TextLine, содержащего только графический элемент, ascent имеет значение 0.

Число атомов в строке, которое представляет число невидимых элементов, включая пробелы и графические элементы.

Указывает число пикселей от базовой линии до нижней точки символов с самыми низким выносным элементом в строке. Для объекта TextLine, содержащего только графический элемент, descent имеет значение 0.

Указывает, содержит ли текстовая строка графические элементы.

Связанные элементы API

Указывает, содержит ли текстовая строка табуляцию.

Объект Vector содержащий объекты TextLineMirrorRegion, связанные со строкой, или null, если таких не существует.

Связанные элементы API

Следующий объект TextLine в TextBlock или null, если текущая строка является последней в блоке или если строка имеет действительность TextLineValidity.STATIC.

Связанные элементы API

Предыдущий объект TextLine в TextBlock или null, если текущая строка является первой в блоке или если строка имеет действительность TextLineValidity.STATIC.

Связанные элементы API

Длина необработанного текста в блоке, который стал строкой, включая символы U+FDEF, представляющие графические элементы и концевые пробелы, которые являются частью строки, но не отображаются.

Связанные элементы API

Ширина, переданная методу TextBlock.createTextLine() при создании строки. Это значение помогает определить, требует ли внесенное изменения повторной разбивки строки.

Связанные элементы API

Объект TextBlock, содержащий эту строку текста, или 0, если для строки задана достоверность TextLineValidity.STATIC, то есть связь между строкой и TextBlock разорвана.

Связанные элементы API

Индекс первого символа в строка в необработанном тексте блока.

Связанные элементы API

Логическая высота текстовой строки, равная сумме значений ascent и descent. Чтобы получить фактическую высоту, используйте унаследованное свойство height.

Это значение рассчитывается по разнице между базовыми строками, окружающими строку, — идеографическими верхней и нижней, либо верхним выносным элементом и нижним выносным элементом в зависимости от того, является TextBlock.baselineZero идеографическим или нет. Графические элементы на учитываются при расчете этих базовых строк.

Связанные элементы API

Логическая ширина текстовой строки, то есть ширина, используемая текстовым процессором для раскладки строки. Используйте унаследованное свойство width, чтобы получить фактическую ширину ограничительного прямоугольника всех нарисованных пикселей.

Связанные элементы API

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Указывает число пикселов от базовой линии до верхней точки самых высоких символов или графики в строке.

Указывает число пикселов от базовой линии до нижней точки символов с самым низким выносным элементом или самой низкой графики в строке.

Общая логическая высота текстовой строки, которая равна сумме totalAscent + totalDescent.

Ширина строки, если она не выровнена. Для невыровненного текста это значение совпадает с textWidth. Для выровненного текста это значение представляет длину, которую бы строка имела без выравнивания, а textWidth представляет фактическую ширину строки. Например, когда следующая строка выравнивается и передается методу TextBlock.createTextLine() с шириной 500, ее фактическая ширина составляет 500, а ширина без выравнивания — 268,9921875.

Связанные элементы API

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Дает возможность приложению связать произвольные данные с текстовой строкой.

Указывает текущую действительность текстовой строки. Значения для этого свойства находятся в элементах класса TextLineValidity. Это свойство должно задаваться по следующим правилам.

Строке присваивается значение USER_INVALID, если действительность имеет строковое значение, не являющееся элементом класса TextLineValidity. USER_INVALID — это абстракция, используемая здесь для представления подобных значений.

При изменении содержимого объекта TextBlock среда выполнения Flash помечает затронутые текстовые строки, а также предшествующую и следующую строки как INVALID. Предшествующая строка должна помечаться как недействительная, когда изменение позволяет ей включить в себя часть содержимого, которая раньше находилась в первой затронутой строке.

Вновь разбитые строки всегда помечаются как VALID. Среда выполнения Flash может изменять следующие строки с VALID на POSSIBLY_INVALID или INVALID. Он может менять строки с POSSIBLY_INVALID на VALID, если разрывы строк совпадают, или на INVALID, если нет.

Код приложения может изменить строки с VALID на INVALID или USER_INVALID, а также с USER_INVALID на VALID. Код приложения не может помечать строки как POSSIBLY_INVALID.

Код приложения может пометить любую строку как STATIC. В результате этого элемент block получает значение null. Все графические элементы в текстовой строке с пометкой STATIC удаляются, и для них восстанавливаются родительские отношения, если они являются частью новой текстовой строки, оторванной от текстового блока, к которому сначала принадлежала исходная строка STATIC.

Связанные элементы API

Выдает базовое содержимое TextLine в виде строки XML. Это может пригодиться при автоматическом тестировании, так как включает сведения о тексте, форматировании и компоновке.

Следующий код описывает вывод.

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Примечание. Содержимое и формат выхода этого метода могут в будущем измениться. Adobe не гарантирует обратной совместимости данного метода.

Связанные элементы API

Этот метод не рекомендуется и не имеет никакого эффекта. Данные атома сжаты и не влияют на эффективность управления памятью.

Связанные элементы API

Определяет двусторонний уровень атома по заданному индексу. Определяется комбинацией TextBlock.bidiLevel и двунаправленных свойств Юникод для символов, образующих строку.

Например, если текстовый блок начинается с текста на иврите, необходимо задать для TextBlock.bidiLevel значение 1, установив по умолчанию направление справа налево. Если в тексте имеется цитата на английском (слева направо), для этого текста AtomBidiLevel имеет значение 2. Если в английском тексте включен фрагмент на арабском (справа налево), то для него AtomBidiLevel имеет значение 3. Если в арабском фрагменте встречается число (слева направо), AtomBidiLevel для числа имеет значение 4. Не имеет значения, в какой строке оказываются атомы. Атомы иврита имеют AtomBidiLevel 1, атомы английского — AtomBidiLevel 2, атомы арабского — AtomBidiLevel 3, а атомы чисел — AtomBidiLevel 4.

Параметры

Связанные элементы API

Определяет границы атома по указанному индексу, связанному с текстовой строкой. Границы заданного атома состоят из положения по горизонтали (x) в строке, положения по вертикали (y) в строке, ширины (w) и высоты (h). Все значения в пикселях.

Параметры

Определяет центр атома, согласно изменениями, вдоль опорной линии по заданному индексу.

Параметры

Определяет график атома по заданному индексу или null, если атом является символом.

Параметры

Возвращает индекс атома, содержащего символ, заданный параметром charIndex или -1, если символ не входит ни в один атом в строке. Параметр charIndex относится ко всему содержимому текстового блока, в который входит строка.

Параметры

Возвращает индекс атома в точке, заданной параметрами x и y или -1, если в этой точке нет атома.

Этот метод получает глобальные координаты, чтобы его можно было легко использовать со свойствами MouseEvent.stageX и MouseEvent.stageY.

Параметры

Определяет индекс начала текстового блока атома по заданному индексу.

Параметры

Определяет индекс конца текстового блока атома по заданному индексу.

Параметры

Определяет вращение атома по заданному индексу. Для этого свойства используются константы TextRotation. Поворот атома является суммой поворотов элемента и строки. Основным назначением является настройка ориентации каретки (курсора) при взаимодействии с объектом TextLine.

Параметры

Связанные элементы API

Указывает, лежит ли граница слова слева от атома по заданному индексу. Границы слова определяются на основе свойств Unicode символов, переданных строке.

Параметры

Получает положение заданной базовой линии относительно TextBlock.baselineZero.

Параметры

Связанные элементы API

Возвращает первый TextLineMirrorRegion в строке, чье свойство mirror совпадает с параметром mirror или null, если нет совпадений.

Даже один TextElement может произвести несколько объектов TextLineMirrorRegion на одной или более строках в зависимости от уровня двунаправленности и разрывов строк. Свойства nextRegion и previousRegion связывают все зеркальные области, генерируемые одним элементом текста.

Параметры

Связанные элементы API

Максимальная запрашиваемая ширина строки текста в пикселях. Метод TextBlock.createTextLine() использует эту константу в качестве значения по умолчанию для параметра width, если не задано другое значение.

Связанные элементы API

1. Добавьте компонент NumericStepper в библиотеку.
2. Сохраните этот код под именем TextLineExample.as в том же каталоге, где и FLA-файл.
3. В окне «Свойства» FLA-файла задайте класс TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}